git.m6w6.name Git - m6w6/ext-psi/blob - config.m4

   1 PHP_ARG_ENABLE(psi, whether to enable PHP System Interface support,
   2 [  --enable-psi            Enable PHP System Interface support])
   3 PHP_ARG_WITH(psi-libjit, where to find libjit,
   4 [  --with-psi-libjit=DIR   PSI: path to libjit], [], no)
   5 PHP_ARG_WITH(psi-libffi, where to find libjit,
   6 [  --with-psi-libffi=DIR   PSI: path to libffi], [], no)
   7
   8 if test "$PHP_PSI" != "no"; then
   9         AC_ARG_VAR(LEMON, The lemon parser generator of the SQLite project)
  10         AC_PATH_PROG(LEMON, lemon, ./lemon)
  11         PHP_SUBST(LEMON)
  12
  13         if test -z "$PKG_CONFIG"
  14         then
  15                 AC_PATH_PROG(PKG_CONFIG, pkg-config, false)
  16         fi
  17
  18         export PKG_CONFIG_PATH="$PHP_PSI_LIBFFI/lib/pkgconfig:$PHP_PSI_LIBJIT/lib/pkgconfig:$PKG_CONFIG_PATH"
  19
  20         AC_CACHE_CHECK(for libffi through pkg-config, PSI_cv_LIBFFI, [
  21         if $PKG_CONFIG --exists libffi
  22         then
  23                 PSI_cv_LIBFFI=true
  24         else
  25                 PSI_cv_LIBFFI=false
  26         fi])
  27         if $PSI_cv_LIBFFI
  28         then
  29                 AC_MSG_CHECKING(for libffi)
  30                 PSI_cv_LIBFFI_DIR=`$PKG_CONFIG --variable=prefix libffi`
  31                 AC_MSG_RESULT($PSI_cv_LIBFFI_DIR)
  32                 PHP_EVAL_INCLINE(`$PKG_CONFIG --cflags libffi`)
  33                 PHP_EVAL_LIBLINE(`$PKG_CONFIG --libs libffi`, PSI_SHARED_LIBADD)
  34         else
  35                 AC_CACHE_CHECK(for libffi, PSI_cv_LIBFFI_DIR, [
  36                 for PSI_cv_LIBFFI_DIR in $PHP_PSI_LIBFFI {/usr{,/local},/opt}{,/libffi}
  37                 do
  38                         if test -e $PSI_cv_LIBFFI_DIR/include/ffi/ffi.h
  39                         then
  40                                 break
  41                         fi
  42                         PSI_cv_LIBFFI_DIR=
  43                 done])
  44                 if test -n "$PSI_cv_LIBFFI_DIR"
  45                 then
  46                         PHP_ADD_INCLUDE($PSI_cv_LIBFFI_DIR/include/ffi)
  47                         PHP_ADD_LIBRARY_WITH_PATH(ffi, $PSI_cv_LIBFFI_DIR/$PHP_LIBDIR, PSI_SHARED_LIBADD)
  48                 else
  49                         AC_MSG_WARN([Could not find libffi, please provide the base install path])
  50                 fi
  51         fi
  52         PHP_CHECK_LIBRARY(ffi, ffi_closure_alloc, [
  53                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure_loc, [
  54                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE_LOC, 1, [ ])
  55                 ], [], -L$PSI_cv_LIBFFI_DIR/$PHP_LIBDIR)
  56                 AC_DEFINE(PSI_HAVE_FFI_CLOSURE_ALLOC, 1, [ ])
  57         ], [
  58                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure, [
  59                         AC_CHECK_HEADERS(sys/mman.h)
  60                         PHP_CHECK_FUNC(mmap)
  61                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE, 1, [ ])
  62                 ], [
  63                 ], -L$PSI_cv_LIBFFI_DIR/$PHP_LIBDIR)
  64         ], -L$PSI_cv_LIBFFI_DIR/$PHP_LIBDIR)
  65
  66         AC_CACHE_CHECK(for libjit, PSI_cv_LIBJIT_DIR, [
  67         for PSI_cv_LIBJIT_DIR in $PHP_PSI_LIBJIT {/usr{,/local},/opt}{,/libjit}
  68         do
  69                 if test -e $PSI_cv_LIBJIT_DIR/include/jit/jit.h
  70                 then
  71                         break
  72                 fi
  73                 PSI_cv_LIBJIT_DIR=
  74         done])
  75         if test -n "$PSI_cv_LIBJIT_DIR"
  76         then
  77                 PHP_ADD_INCLUDE($PSI_cv_LIBJIT_DIR/include)
  78                 PHP_ADD_LIBRARY_WITH_PATH(jit, $PSI_cv_LIBJIT_DIR/$PHP_LIBDIR, PSI_SHARED_LIBADD)
  79         else
  80                 AC_MSG_WARN([Could not find libjit, please provide the base install path])
  81         fi
  82
  83         PHP_SUBST(PSI_SHARED_LIBADD)
  84
  85         PSI_TYPES=""
  86         dnl PSI_TYPE(type name, basic type, whether to check alignmnet)
  87         AC_DEFUN(PSI_TYPE, [
  88                 AC_CHECK_SIZEOF($1)
  89                 if test "$3" && test "$3" != "no"
  90                 then
  91                         AC_CHECK_ALIGNOF($1)
  92                 fi
  93                 if test "$2" && test "$ac_cv_sizeof_[]$1" -gt 0; then
  94                         psi_type_bits=`expr ${AS_TR_SH(ac_cv_sizeof_[]$1)} \* 8`
  95                         PSI_TYPES="{PSI_T_[]translit($2,a-z,A-Z)[]${psi_type_bits}, \""$2[]${psi_type_bits}[]_t"\", \""$1"\"}, $PSI_TYPES"
  96                 fi
  97         ])
  98
  99
 100         PSI_CONSTS=""
 101         dnl PSI_COMPUTE_STR(variable, string or expression, includes)
 102         AC_DEFUN(PSI_COMPUTE_STR, [
 103                 AC_TRY_RUN([
 104                         $3
 105                         int main() {
 106                                 return EOF == fputs($2, fopen("conftest.out", "w"));
 107                         }
 108                 ], [
 109                         eval $1=\\\"`cat conftest.out`\\\"
 110                 ])
 111         ])
 112
 113         dnl PSI_CONST(const name, type, headers to include)
 114         AC_DEFUN(PSI_CONST, [
 115                 AC_MSG_CHECKING(value of $1)
 116                 PSI_INCLUDES=
 117                 if test "$3"
 118                 then
 119                         for i in $3
 120                         do
 121                                 PSI_INCLUDES="$PSI_INCLUDES
 122 #include <$i>"
 123                         done
 124                 fi
 125                 case $2 in
 126                 str*|quoted_str*)
 127                         PSI_COMPUTE_STR(psi_const_val, $1, AC_INCLUDES_DEFAULT()$PSI_INCLUDES)
 128                         if test "$psi_const_val"; then
 129                                 PSI_CONSTS="{PSI_T_STRING, \"string\", \"$1\", $psi_const_val, PSI_T_QUOTED_STRING}, $PSI_CONSTS"
 130                         fi
 131                         ;;
 132                 *)
 133                         AC_COMPUTE_INT(psi_const_val, $1, AC_INCLUDES_DEFAULT()$PSI_INCLUDES)
 134                         if test "$psi_const_val"; then
 135                                 PSI_CONSTS="{PSI_T_INT, \"int\", \"$1\", \"$psi_const_val\", PSI_T_NUMBER}, $PSI_CONSTS"
 136                         fi
 137                         ;;
 138                 esac
 139
 140                 AC_MSG_RESULT($psi_const_val)
 141         ])
 142
 143         AC_DEFUN([AX_CHECK_SIGN], [
 144                 typename=`echo $1 | sed "s/@<:@^a-zA-Z0-9_@:>@/_/g"`
 145                 AC_CACHE_CHECK([whether $1 is signed], ax_cv_decl_${typename}_signed, [
 146                                 AC_TRY_COMPILE([$4],
 147                                                 [ int foo @<:@ 1 - 2 * !((($1) -1) < 0) @:>@ ],
 148                                                 [ eval "ax_cv_decl_${typename}_signed=\"yes\"" ],
 149                                                 [ eval "ax_cv_decl_${typename}_signed=\"no\"" ])])
 150                 symbolname=`echo $1 | sed "s/@<:@^a-zA-Z0-9_@:>@/_/g" | tr "a-z" "A-Z"`
 151                 if eval "test \"\${ax_cv_decl_${typename}_signed}\" = \"yes\""; then
 152                                 $2
 153                 elif eval "test \"\${ax_cv_decl_${typename}_signed}\" = \"no\""; then
 154                                 $3
 155                 fi
 156         ])
 157
 158         PSI_TYPE(char, int)
 159         PSI_TYPE(short, int)
 160         PSI_TYPE(int, int)
 161         PSI_TYPE(long, int)
 162         PSI_TYPE(float)
 163         PSI_TYPE(double)
 164         PSI_TYPE(void *)
 165
 166         dnl stddef.h
 167         PSI_TYPE(ptrdiff_t, int)
 168         PSI_TYPE(size_t, uint)
 169         AC_CHECK_TYPE(wchar_t, [
 170                 AX_CHECK_SIGN(wchar_t, psi_wchar_t=int, psi_wchar_t=uint)
 171                 PSI_TYPE(wchar_t, $psi_wchar_t)
 172         ])
 173
 174         dnl stdio.h
 175         PSI_CONST(BUFSIZ, int)
 176         PSI_CONST(_IOFBF, int)
 177         PSI_CONST(_IOLBF, int)
 178         PSI_CONST(_IONBF, int)
 179         PSI_CONST(SEEK_CUR, int)
 180         PSI_CONST(SEEK_END, int)
 181         PSI_CONST(SEEK_SET, int)
 182         PSI_CONST(FILENAME_MAX, int)
 183         PSI_CONST(FOPEN_MAX, int)
 184         PSI_CONST(TMP_MAX, int)
 185         PSI_CONST(EOF, int)
 186         PSI_CONST(P_tmpdir, string)
 187         PSI_CONST(L_ctermid, int)
 188         PSI_CONST(L_tmpnam, int)
 189         dnl stdlib.h
 190         PSI_CONST(EXIT_FAILURE, int)
 191         PSI_CONST(EXIT_SUCCESS, int)
 192         PSI_CONST(RAND_MAX, int)
 193         PSI_CONST(MB_CUR_MAX, int)
 194         dnl sys/time.h
 195         PSI_CONST(ITIMER_REAL, int, sys/time.h)
 196         PSI_CONST(ITIMER_VIRTUAL, int, sys/time.h)
 197         PSI_CONST(ITIMER_PROF, int, sys/time.h)
 198         dnl sys/types.h
 199         PSI_TYPE(blkcnt_t, int)
 200         PSI_TYPE(blksize_t, int)
 201         PSI_TYPE(clock_t, int)
 202         PSI_TYPE(clockid_t, int)
 203         PSI_TYPE(dev_t, int)
 204         PSI_TYPE(fsblkcnt_t, uint)
 205         PSI_TYPE(fsfilcnt_t, uint)
 206         PSI_TYPE(gid_t, int)
 207         PSI_TYPE(id_t, int)
 208         PSI_TYPE(ino_t, uint)
 209         PSI_TYPE(key_t, int)
 210         PSI_TYPE(mode_t, int)
 211         PSI_TYPE(nlink_t, int)
 212         PSI_TYPE(off_t, int)
 213         PSI_TYPE(pid_t, int)
 214         PSI_TYPE(ssize_t, int)
 215         PSI_TYPE(suseconds_t, int)
 216         PSI_TYPE(time_t, int)
 217         PSI_TYPE(timer_t, int)
 218         PSI_TYPE(uid_t)
 219
 220         AC_DEFINE_UNQUOTED(PHP_PSI_TYPES, $PSI_TYPES, Predefined types)
 221         AC_DEFINE_UNQUOTED(PHP_PSI_CONSTS, $PSI_CONSTS, Predefined constants)
 222
 223         PHP_PSI_SRCDIR=PHP_EXT_SRCDIR(psi)
 224         PHP_PSI_BUILDDIR=PHP_EXT_BUILDDIR(psi)
 225
 226         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src)
 227         PHP_ADD_BUILD_DIR($PHP_PSI_BUILDDIR/src)
 228
 229         PHP_PSI_HEADERS=`(cd $PHP_PSI_SRCDIR/src && echo *.h)`
 230         PHP_PSI_SOURCES="src/parser_proc.c src/parser.c src/validator.c src/module.c src/context.c"
 231         PHP_PSI_SOURCES="$PHP_PSI_SOURCES src/libjit.c src/libffi.c"
 232
 233         PHP_NEW_EXTENSION(psi, $PHP_PSI_SOURCES, $ext_shared)
 234         PHP_INSTALL_HEADERS(ext/psi, php_psi.h $PHP_PSI_HEADERS)
 235
 236         PHP_SUBST(PHP_PSI_HEADERS)
 237         PHP_SUBST(PHP_PSI_SOURCES)
 238
 239         PHP_SUBST(PHP_PSI_SRCDIR)
 240         PHP_SUBST(PHP_PSI_BUILDDIR)
 241
 242         PHP_ADD_MAKEFILE_FRAGMENT
 243 fi