git.m6w6.name Git - m6w6/ext-psi/blob - config.m4

   1 m4_foreach(incfile, [
   2         [ax/ax_check_sign.m4],
   3         [ax/ax_pthread.m4],
   4         [psi/psi.m4],
   5         [psi/psi_const.m4],
   6         [psi/psi_type.m4]], [
   7         dnl pecl build
   8         sinclude([m4/]incfile)
   9         dnl php-src build
  10         sinclude([ext/psi/m4/]incfile)
  11 ])
  12
  13 PHP_ARG_ENABLE(psi, whether to enable PHP System Interface support,
  14 [  --enable-psi            Enable PSI (PHP System Interface) support])
  15
  16 if test "$PHP_PSI" != no; then
  17
  18         PHP_ARG_ENABLE(psi-maintainer-mode, whether to enable maintainer mode,
  19         [  --enable-psi-maintainer-mode
  20                           PSI: enable maintainer mode
  21                            . make dependencies], [no], [no])
  22
  23         PHP_ARG_WITH(psi-libjit, where to find libjit,
  24         [  --with-psi-libjit=DIR   PSI: path to libjit], [ ], [ ])
  25
  26         PHP_ARG_WITH(psi-libffi, where to find libffi,
  27         [  --with-psi-libffi=DIR   PSI: path to libffi], [ ], [ ])
  28
  29         AC_HEADER_ASSERT dnl # adds --disable-assert to define NDEBUG
  30
  31         dnl we cannot use AC_USE_SYSTEM_EXTENSIONS here, because we're way too late
  32         dnl in the game, and we're currently only targeting _GNU_SOURCE for now
  33         AC_MSG_CHECKING([for _GNU_SOURCE])
  34         AC_EGREP_CPP([gnu_source_not_defined], [
  35                 #ifndef _GNU_SOURCE
  36                 gnu_source_not_defined
  37                 #endif
  38         ], [
  39                 AC_MSG_RESULT([needs define])
  40                 AC_DEFINE([_GNU_SOURCE], [1], [ ])
  41         ], [
  42                 AC_MSG_RESULT([already defined])
  43         ])
  44
  45         AC_MSG_CHECKING([psi source dir])
  46         PHP_PSI_SRCDIR=PHP_EXT_SRCDIR(psi)
  47         AC_MSG_RESULT([$PHP_PSI_SRCDIR])
  48
  49         AC_MSG_CHECKING([psi build dir])
  50         case "PHP_EXT_BUILDDIR(psi)" in
  51         ""|.) PHP_PSI_BUILDDIR=$PHP_PSI_SRCDIR
  52                 ;;
  53         *)    PHP_PSI_BUILDDIR=PHP_EXT_BUILDDIR(psi)
  54                 ;;
  55         esac
  56         AC_MSG_RESULT([$PHP_PSI_BUILDDIR])
  57
  58         PSI_CHECK_LIBJIT
  59         PSI_CHECK_LIBFFI
  60
  61         AC_FUNC_FNMATCH
  62         AC_FUNC_MMAP
  63         AC_CHECK_FUNCS([mknodat eaccess])
  64
  65         PSI_CONFIG_INIT
  66         PSI_CHECK_STD_TYPES
  67         PSI_CONFIG_DONE
  68
  69         PHP_SUBST(PSI_SHARED_LIBADD)
  70
  71         AC_DEFINE_UNQUOTED(PHP_PSI_SHLIB_SUFFIX, ["$SHLIB_SUFFIX_NAME"], DL suffix)
  72
  73         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR)
  74         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src)
  75         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src/calc)
  76         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src/types)
  77         PHP_ADD_INCLUDE($PHP_PSI_BUILDDIR)
  78         PHP_ADD_BUILD_DIR($PHP_PSI_BUILDDIR/src)
  79         PHP_ADD_BUILD_DIR($PHP_PSI_BUILDDIR/src/types)
  80
  81         PHP_PSI_HEADERS=" \
  82                 src/calc/basic.h src/calc/bin.h src/calc/bool.h src/calc/cast.h \
  83                 src/calc/unary.h src/calc/cmp.h src/calc/oper.h \
  84                 `(cd $PHP_PSI_SRCDIR/src && ls *.h types/*.h)` \
  85         "
  86         # parser_* should come first
  87         PHP_PSI_SOURCES=" \
  88                 src/parser_proc.c src/parser_scan.c \
  89                 `(cd $PHP_PSI_SRCDIR && ls src/*.c src/types/*.c \
  90                         | $EGREP -v '^src/parser_' \
  91                 )` \
  92         "
  93         PHP_PSI_GENERATED=" \
  94                 src/parser_proc.c src/parser_scan.c \
  95                 src/calc/basic.h src/calc/bin.h src/calc/bool.h src/calc/cast.h \
  96                 src/calc/unary.h src/calc/cmp.h src/calc/oper.h \
  97         "
  98
  99         PHP_NEW_EXTENSION(psi, $PHP_PSI_SOURCES, $ext_shared)
 100         PHP_INSTALL_HEADERS(ext/psi, php_psi.h $PHP_PSI_HEADERS)
 101
 102         PHP_SUBST(PHP_PSI_GENERATED)
 103         PHP_SUBST(PHP_PSI_HEADERS)
 104         PHP_SUBST(PHP_PSI_SOURCES)
 105
 106         PHP_SUBST(PHP_PSI_SRCDIR)
 107         PHP_SUBST(PHP_PSI_BUILDDIR)
 108
 109         PHP_ADD_MAKEFILE_FRAGMENT
 110         AC_MSG_RESULT()
 111 fi