git.m6w6.name Git - m6w6/ext-pq/blob - config9.m4

   1 PHP_ARG_WITH(pq, [whether to enable libpq (PostgreSQL) support],
   2 [  --with-pq[=DIR]           Include libpq support])
   3
   4 if test "$PHP_PQ" != "no"; then
   5         SEARCH_PATH="/usr/local /usr /opt"
   6         if test "$PHP_PQ" != "yes"; then
   7                 SEARCH_PATH="$PHP_PQ $SEARCH_PATH"
   8         fi
   9         for i in $SEARCH_PATH; do
  10                 dnl for Debian
  11                 AC_MSG_CHECKING(for $i/include/postgresql/libpq-events.h)
  12                 if test -f "$i/include/postgresql/libpq-events.h"; then
  13                         PQ_INCDIR=$i/include/postgresql
  14                         AC_MSG_RESULT(yep)
  15                         break
  16                 fi
  17                 AC_MSG_RESULT(nope)
  18
  19                 AC_MSG_CHECKING(for $i/include/libpq-events.h)
  20                 if test -f "$i/include/libpq-events.h"; then
  21                         PQ_INCDIR=$i/include
  22                         AC_MSG_RESULT(yep)
  23                         break
  24                 fi
  25                 AC_MSG_RESULT(nope)
  26         done
  27
  28         if test -z "$PQ_INCDIR"; then
  29                 AC_MSG_ERROR(could not find include/libpq-events.h)
  30         fi
  31
  32         for i in $SEARCH_PATH; do
  33                 AC_MSG_CHECKING(for $i/$PHP_LIBDIR/libpq.$SHLIB_SUFFIX_NAME)
  34                 if test -f "$i/$PHP_LIBDIR/libpq.$SHLIB_SUFFIX_NAME"; then
  35                         PQ_LIBDIR=$i/$PHP_LIBDIR
  36                         AC_MSG_RESULT(yep)
  37                         break
  38                 fi
  39                 dnl for Debian
  40                 AC_MSG_CHECKING(for $i/$PHP_LIBDIR/x86_64-linux-gnu/libpq.$SHLIB_SUFFIX_NAME)
  41                 if test -f "$i/$PHP_LIBDIR/x86_64-linux-gnu/libpq.$SHLIB_SUFFIX_NAME"; then
  42                         PQ_LIBDIR=$i/$PHP_LIBDIR/x86_64-linux-gnu
  43                         AC_MSG_RESULT(yep)
  44                         break
  45                 fi
  46                 AC_MSG_RESULT(nope)
  47         done
  48
  49         if test -z "$PQ_LIBDIR"; then
  50                 AC_MSG_ERROR(could not find libpq.$SHLIB_SUFFIX_NAME)
  51         fi
  52
  53         PHP_ADD_INCLUDE($PQ_INCDIR)
  54
  55         ifdef([AC_PROG_EGREP], [
  56                 AC_PROG_EGREP
  57         ], [
  58                 AC_CHECK_PROG(EGREP, egrep, egrep)
  59         ])
  60
  61         dnl
  62         dnl PQ_CHECK_CONST(name)
  63         dnl
  64         AC_DEFUN([PQ_CHECK_CONST], [
  65                 AC_MSG_CHECKING(for $1)
  66                 if $EGREP -q $1 $PQ_INCDIR/libpq-fe.h; then
  67                         AC_DEFINE(HAVE_$1, 1, [Have $1])
  68                         AC_MSG_RESULT(yep)
  69                 else
  70                         AC_MSG_RESULT(nope)
  71                 fi
  72         ])
  73
  74         PQ_CHECK_CONST(PGRES_SINGLE_TUPLE)
  75         PQ_CHECK_CONST(PGRES_COPY_BOTH)
  76
  77
  78         dnl
  79         dnl PQ_CHECK_FUNC(sym, fail-hard)
  80         dnl
  81         AC_DEFUN([PQ_CHECK_FUNC], [
  82                 FAIL_HARD=$2
  83
  84                 PHP_CHECK_LIBRARY(pq, $1, [
  85                         AC_DEFINE([HAVE_]translit($1,a-z,A-Z), 1, Have $1)
  86                 ], [
  87                         if test -n "$FAIL_HARD"; then
  88                                 if "$FAIL_HARD"; then
  89                                         AC_MSG_ERROR(could not find $PQ_SYM in -lpq)
  90                                 fi
  91                         fi
  92                 ], [
  93                         -L$PQ_LIBDIR
  94                 ])
  95         ])
  96
  97         PQ_CHECK_FUNC(PQregisterEventProc, true)
  98         PHP_ADD_LIBRARY_WITH_PATH(pq, $PQ_LIBDIR, PQ_SHARED_LIBADD)
  99         PHP_SUBST(PQ_SHARED_LIBADD)
 100
 101         PQ_CHECK_FUNC(PQlibVersion)
 102         PQ_CHECK_FUNC(PQconninfo)
 103         PQ_CHECK_FUNC(PQsetSingleRowMode)
 104
 105         dnl
 106         dnl PQ_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
 107         dnl
 108         AC_DEFUN([PQ_HAVE_PHP_EXT], [
 109                 extname=$1
 110                 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
 111                 AC_MSG_CHECKING([for ext/$extname support])
 112                 if test "$haveext" != "no" && test "x$haveext" != "x"; then
 113                         [PHP_PQ_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
 114                         AC_MSG_RESULT([yes])
 115                         $2
 116                 elif test -x "$PHP_EXECUTABLE"; then
 117                         grepext=`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`
 118                         if test "$grepext" = "$extname"; then
 119                                 [PHP_PQ_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
 120                                 AC_MSG_RESULT([yes])
 121                                 $2
 122                         else
 123                                 [PHP_PQ_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
 124                                 AC_MSG_RESULT([no])
 125                                 $3
 126                         fi
 127                 else
 128                         [PHP_PQ_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
 129                         AC_MSG_RESULT([no])
 130                         $3
 131                 fi
 132         ])
 133
 134         PQ_SRC="\
 135                 src/php_pq_module.c\
 136                 src/php_pq_misc.c\
 137                 src/php_pq_callback.c\
 138                 src/php_pq_object.c\
 139                 src/php_pq_params.c\
 140                 src/php_pqcancel.c\
 141                 src/php_pqconn.c\
 142                 src/php_pqconn_event.c\
 143                 src/php_pqcopy.c\
 144                 src/php_pqexc.c\
 145                 src/php_pqlob.c\
 146                 src/php_pqres.c\
 147                 src/php_pqstm.c\
 148                 src/php_pqtxn.c\
 149                 src/php_pqtypes.c\
 150                 src/php_pqcur.c\
 151         "
 152         PHP_NEW_EXTENSION(pq, $PQ_SRC, $ext_shared)
 153         PHP_ADD_BUILD_DIR($ext_builddir/src)
 154         PHP_ADD_INCLUDE($ext_srcdir/src)
 155
 156         PQ_HAVE_PHP_EXT([raphf], [
 157                 AC_MSG_CHECKING([for php_raphf.h])
 158                 PQ_EXT_RAPHF_INCDIR=
 159                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../raphf; do
 160                         if test -d $i; then
 161                                 if test -f $i/php_raphf.h; then
 162                                         PQ_EXT_RAPHF_INCDIR=$i
 163                                         break
 164                                 elif test -f $i/ext/raphf/php_raphf.h; then
 165                                         PQ_EXT_RAPHF_INCDIR=$i/ext/raphf
 166                                         break
 167                                 fi
 168                         fi
 169                 done
 170                 if test "x$PQ_EXT_RAPHF_INCDIR" = "x"; then
 171                         AC_MSG_ERROR([not found])
 172                 else
 173                         AC_MSG_RESULT([$PQ_EXT_RAPHF_INCDIR])
 174                         AC_DEFINE([PHP_PQ_HAVE_PHP_RAPHF_H], [1], [Have ext/raphf support])
 175                         PHP_ADD_INCLUDE([$PQ_EXT_RAPHF_INCDIR])
 176                 fi
 177         ], [
 178                 AC_MSG_ERROR([Please install pecl/raphf and activate extension=raphf.$SHLIB_DL_SUFFIX_NAME in your php.ini])
 179         ])
 180         PHP_ADD_EXTENSION_DEP(pq, raphf, true)
 181         PQ_HAVE_PHP_EXT([json], [
 182                 AC_MSG_CHECKING([for php_json.h])
 183                 PQ_EXT_JSON_INCDIR=
 184                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../json ../jsonc ../jsond; do
 185                         if test -d $i; then
 186                                 if test -f $i/php_json.h; then
 187                                         PQ_EXT_JSON_INCDIR=$i
 188                                         break
 189                                 elif test -f $i/ext/json/php_json.h; then
 190                                         PQ_EXT_JSON_INCDIR=$i/ext/json
 191                                         break
 192                                 fi
 193                         fi
 194                 done
 195                 if test "x$PQ_EXT_JSON_INCDIR" = "x"; then
 196                         AC_MSG_ERROR([not found])
 197                 else
 198                         AC_MSG_RESULT([$PQ_EXT_JSON_INCDIR])
 199                         AC_DEFINE([PHP_PQ_HAVE_PHP_JSON_H], [1], [Have ext/json support])
 200                         PHP_ADD_INCLUDE([$PQ_EXT_JSON_INCDIR])
 201                 fi
 202         ])
 203 fi