git.m6w6.name Git - m6w6/ext-pq/blob - config.m4

   1 PHP_ARG_WITH(pq, [whether to enable libpq (PostgreSQL) support],
   2 [  --with-pq[=DIR]           Include libpq support])
   3 PHP_ARG_WITH(pq-postgresql, [where to find PostgreSQL server headers],
   4 [  --with-pq-postgresql[=DIR]  PQ: Define some standard type OIDs from catalog/pg_type.h], $PHP_PQ)
   5
   6 if test "$PHP_PQ" != "no"; then
   7         SEARCH_PATH="/usr/local /usr /opt"
   8         if test "$PHP_PQ" != "yes"; then
   9                 SEARCH_PATH="$PHP_PQ $SEARCH_PATH"
  10         fi
  11         for i in $SEARCH_PATH; do
  12                 AC_MSG_CHECKING(for $i/include/libpq-events.h)
  13                 if test -f "$i/include/libpq-events.h"; then
  14                         PQ_DIR=$i
  15                         AC_MSG_RESULT(yep)
  16                         break
  17                 fi
  18                 AC_MSG_RESULT(nope)
  19         done
  20
  21         if test -z "$PQ_DIR"; then
  22                 AC_MSG_ERROR(could not find include/libpq-events.h)
  23         fi
  24         PHP_ADD_INCLUDE($PQ_DIR/include)
  25
  26         PQ_SYM=PQregisterEventProc
  27         PHP_CHECK_LIBRARY(pq, $PQ_SYM, [
  28                 PHP_ADD_LIBRARY_WITH_PATH(pq, $PQ_DIR/$PHP_LIBDIR, PQ_SHARED_LIBADD)
  29                 PHP_SUBST(PQ_SHARED_LIBADD)
  30         ],[
  31                 AC_MSG_ERROR(could not find $PQ_SYM in -lpq)
  32         ],[
  33                 -L$PQ_DIR/$PHP_LIBDIR
  34         ])
  35         PHP_CHECK_LIBRARY(pq, PQlibVersion, [AC_DEFINE(HAVE_PQLIBVERSION, 1, Have PQlibVersion)])
  36
  37         PQ_SRC="\
  38                 src/php_pq_module.c\
  39                 src/php_pq_misc.c\
  40                 src/php_pq_callback.c\
  41                 src/php_pq_object.c\
  42                 src/php_pq_params.c\
  43                 src/php_pqcancel.c\
  44                 src/php_pqconn.c\
  45                 src/php_pqconn_event.c\
  46                 src/php_pqcopy.c\
  47                 src/php_pqexc.c\
  48                 src/php_pqlob.c\
  49                 src/php_pqres.c\
  50                 src/php_pqstm.c\
  51                 src/php_pqtxn.c\
  52                 src/php_pqtypes.c\
  53                 src/php_pqcur.c\
  54         "
  55         PHP_NEW_EXTENSION(pq, $PQ_SRC, $ext_shared)
  56         PHP_ADD_BUILD_DIR($ext_builddir/src)
  57         PHP_ADD_INCLUDE($ext_srcdir/src)
  58         PHP_ADD_EXTENSION_DEP(pq, raphf)
  59
  60         if test "$PHP_PQ_POSTGRESQL" != "no"; then
  61                 if test "$PHP_PQ_POSTGRESQL" != "yes"; then
  62                         SEARCH_PATH="$PHP_PQ_POSTGRESQL $SEARCH_PATH"
  63                 fi
  64                 for i in $SEARCH_PATH; do
  65                         CATALOG="$i/include/postgresql/server/catalog/pg_type.h"
  66                         AC_MSG_CHECKING(for $CATALOG)
  67                         if test -f "$CATALOG"; then
  68                                 AC_MSG_RESULT(yep)
  69                                 AC_PROG_AWK()
  70                                 $AWK -f $ext_srcdir/php_pq_type.awk < "$CATALOG" > $ext_srcdir/php_pq_type.h
  71                                 AC_DEFINE(HAVE_PHP_PQ_TYPE_H, 1, Have PostgreSQL type OID defs)
  72                                 break
  73                         fi
  74                         AC_MSG_RESULT(nope)
  75                 done
  76         fi
  77 fi
  78