git.m6w6.name Git - m6w6/ext-http/blob - config9.m4

   1
   2 m4_foreach(dir, [., ext/http], [
   3         sinclude(dir/autoconf/pecl/pecl.m4)
   4         sinclude(dir/autoconf/pecl/zlib.m4)
   5         sinclude(dir/autoconf/pecl/libbrotli.m4)
   6         sinclude(dir/autoconf/pecl/libcurl.m4)
   7         sinclude(dir/autoconf/pecl/libevent.m4)
   8 ])
   9
  10 PECL_INIT([http])
  11
  12 PHP_ARG_WITH([http], [whether to enable extended HTTP support],
  13 [  --with-http             Enable extended HTTP support])
  14 if test "$PHP_HTTP" != "no"; then
  15         dnl STDC
  16         AC_TYPE_OFF_T
  17         AC_TYPE_MBSTATE_T
  18         dnl getdomainname() is declared in netdb.h on some platforms: AIX, OSF
  19         AC_CHECK_HEADERS([netdb.h unistd.h wchar.h wctype.h arpa/inet.h])
  20         AC_CHECK_FUNC(gethostname,,[
  21                 AC_CHECK_LIB(nsl, gethostname)
  22         ])
  23         AC_CHECK_FUNC(getdomainname,,[
  24                 AC_CHECK_LIB(nsl, getdomainname)
  25         ])
  26         AC_CHECK_FUNCS(mbrtowc mbtowc iswalnum inet_pton)
  27
  28         dnl ZLIB
  29         PHP_ARG_WITH([http-zlib-dir], [whether/where to check for zlib],
  30         [  --with-http-zlib-dir[=DIR]         HTTP: where to find zlib], $PHP_HTTP)
  31         PECL_CHECK_ZLIB([$PHP_HTTP_ZLIB_DIR], [1.2.0.4])
  32         PECL_CHECK_DONE(zlib, $PECL_VAR([HAVE_ZLIB]))
  33
  34         dnl BROTLI
  35         PHP_ARG_WITH([http-libbrotli-dir], [whether/where to check for libbrotli],
  36         [  --with-http-libbrotli-dir[=DIR]    HTTP: where to find libbrotli], $PHP_HTTP)
  37         PECL_CHECK_LIBBROTLI([$PHP_HTTP_LIBBROTLI_DIR], [1.0])
  38         PECL_CHECK_DONE(libbrotli, $PECL_VAR([HAVE_LIBBROTLI]))
  39
  40         dnl CURL
  41         PHP_ARG_WITH([http-libcurl-dir], [whether/where to check for libcurl],
  42         [  --with-http-libcurl-dir[=DIR]      HTTP: where to find libcurl], $PHP_HTTP)
  43         if test "$PHP_HTTP_LIBCURL_DIR" != "no"; then
  44                 PECL_CHECK_LIBCURL([$PHP_HTTP_LIBCURL_DIR], [7.18.2])
  45                 PECL_HAVE_LIBCURL_PROTOCOL([HTTP], [
  46                         PECL_HAVE_LIBCURL_FEATURE([HTTP2])
  47                         PECL_HAVE_LIBCURL_FEATURE([ALT-SVC])
  48                         PECL_HAVE_LIBCURL_FEATURE([HSTS])
  49                         PECL_HAVE_LIBCURL_ARES
  50                         PECL_HAVE_LIBCURL_SSL
  51                         PECL_HAVE_LIBCURL_CA
  52                         PECL_DEFINE([HAVE_CLIENT])
  53                 ])
  54                 PECL_CHECK_DONE(libcurl, [$PECL_VAR([HAVE_LIBCURL_PROTOCOL_HTTP])])
  55         fi
  56
  57         dnl EVENT
  58         PHP_ARG_WITH([http-libevent-dir], [whether/where to check for libevent],
  59         [  --with-http-libevent-dir[=DIR]     HTTP: where to find libevent], $PHP_HTTP_LIBCURL_DIR, no)
  60         if test "$PHP_HTTP_LIBEVENT_DIR" != "no"; then
  61                 PECL_CHECK_LIBEVENT([$PHP_HTTP_LIBEVENT_DIR])
  62                 PECL_CHECK_DONE(libevent, [$PECL_VAR([HAVE_LIBEVENT])])
  63         fi
  64
  65         dnl GNU IDNA
  66         PHP_ARG_WITH([http-libidn2-dir], [whether/where to check for libidn2],
  67         [  --with-http-libidn2-dir[=DIR]      HTTP: where to find libidn2], $PHP_HTTP_LIBCURL_DIR, no)
  68         if test "$PHP_HTTP_LIBIDN2_DIR" != "no"; then
  69                 PECL_CHECK_CUSTOM(libidn2, "$PHP_HTTP_LIBIDN2_DIR", idn2.h, idn2,
  70                         [$($EGREP "define IDN2_VERSION " "include/idn2.h" | $SED -e's/^.*VERSION //g' -e 's/@<:@^0-9\.@:>@//g')])
  71                 if $PECL_VAR([HAVE_LIBIDN2]); then
  72                         PECL_DEFINE([HAVE_IDNA2008])
  73                 fi
  74                 PECL_CHECK_DONE(libidn2, $PECL_VAR([HAVE_LIBIDN2]))
  75         fi
  76         PHP_ARG_WITH([http-libidn-dir], [whether/where to check for libidn],
  77         [  --with-http-libidn-dir[=DIR]       HTTP: where to find libidn], $PHP_HTTP_LIBCURL_DIR, no)
  78         if test "$PHP_HTTP_LIBIDN_DIR" != "no"; then
  79                 PECL_CHECK_PKGCONFIG(libidn, [$PHP_HTTP_LIBIDN_DIR])
  80                 if $PECL_VAR([HAVE_LIBIDN]); then
  81                         PECL_DEFINE([HAVE_IDNA2003])
  82                 fi
  83                 PECL_CHECK_DONE(libidn, $PECL_VAR([HAVE_LIBIDN]))
  84         fi
  85
  86         dnl ICU IDNA
  87         PHP_ARG_WITH([http-libicu-dir], [whether/where to check for libicu],
  88         [  --with-http-libicu-dir[=DIR]       HTTP: where to find libicu], $PHP_HTTP_LIBCURL_DIR, no)
  89         if test "$PHP_HTTP_LIBICU_DIR" != "no"; then
  90                 AC_PATH_PROG(ICU_CONFIG, icu-config, false, [$PHP_HTTP_LIBICU_DIR/bin:$PATH:/usr/local/bin])
  91
  92                 if $ICU_CONFIG --exists >/dev/null 2>/dev/null; then
  93                         PECL_CHECK_CONFIG(libicu, [$ICU_CONFIG], [--version], [--cppflags], [--ldflags-searchpath], [--ldflags-libsonly])
  94                 else
  95                         PECL_CHECK_PKGCONFIG(icu-i18n, [$PHP_HTTP_LIBICU_DIR])
  96                 fi
  97                 AC_CACHE_CHECK([for uidna_IDNToASCII], PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII]), [
  98                         if printf "%s" "$CFLAGS" | $EGREP -q "(^|\s)-Werror\b"; then
  99                                 if ! printf "%s" "$CFLAGS" | $EGREP -q "(^|\s)-Wno-error=deprecated-declarations\b"; then
 100                                         CFLAGS="$CFLAGS -Wno-error=deprecated-declarations"
 101                                 fi
 102                         fi
 103                         AC_TRY_LINK([
 104                                 #include <unicode/uidna.h>
 105                         ], [
 106                                 uidna_IDNToASCII(0, 0, 0, 0, 0, 0, 0);
 107                         ], [
 108                                 PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII])=yes
 109                         ], [
 110                                 PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII])=no
 111                         ])
 112                 ])
 113                 if $PECL_CACHE_VAR([HAVE_UIDNA_IDNTOASCII]); then
 114                         PECL_DEFINE([HAVE_IDNA2003])
 115                         PECL_DEFINE_FN([UIDNA_IDNTOASCII])
 116                 fi
 117
 118                 AC_CACHE_CHECK([for uidna_nameToASCII_UTF8], PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8]), [
 119                         AC_TRY_LINK([
 120                                 #include <unicode/uidna.h>
 121                         ], [
 122                                 uidna_nameToASCII_UTF8(0, 0, 0, 0, 0, 0, 0);
 123                         ], [
 124                                 PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8])=yes
 125                         ], [
 126                                 PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8])=no
 127                         ])
 128                 ])
 129                 if $PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8]); then
 130                         PECL_DEFINE([HAVE_IDNA2008])
 131                         PECL_DEFINE_FN([uidna_nameToASCII_UTF8])
 132                 fi
 133                 PECL_CHECK_DONE(libicu, [$PECL_VAR([HAVE_LIBICU])])
 134         fi
 135
 136         dnl IDNKIT2
 137         PHP_ARG_WITH([http-libidnkit2-dir], [whether/where to check for libidnkit2],
 138         [  --with-http-libidnkit2-dir[=DIR]   HTTP: where to find libidnkit2], $PHP_HTTP_LIBCURL_DIR, no)
 139         if test "$PHP_HTTP_LIBIDNKIT2_DIR" != "no"; then
 140                 PECL_CHECK_CUSTOM(libidnkit2, "$PHP_HTTP_LIBIDNKIT2_DIR", idn/api.h, idnkit,
 141                         [$($EGREP "define IDNKIT_VERSION_LIBIDN\b" "include/idn/version.h" | $SED -e's/^.*VERSION_LIBIDN//g' -e 's/@<:@^0-9\.@:>@//g')])
 142                 if $PECL_VAR([HAVE_LIBIDNKIT2]); then
 143                         PECL_DEFINE([HAVE_IDNA2008])
 144                 fi
 145                 PECL_CHECK_DONE(libidnkit2, [$PECL_VAR([HAVE_LIBIDNKIT2])])
 146         fi
 147         dnl IDNKIT1
 148         PHP_ARG_WITH([http-libidnkit-dir], [whether/where to check for libidnkit],
 149         [  --with-http-libidnkit-dir[=DIR]    HTTP: where to find libidnkit], $PHP_HTTP_LIBCURL_DIR, no)
 150         if test "$PHP_HTTP_LIBIDNKIT_DIR" != "no"; then
 151                 # libidnkit1 and libidnkit2 have the same API
 152                 if test "$PHP_HTTP_LIBIDNKIT2_DIR" != no && $PECL_VAR([HAVE_LIBIDNKIT2]); then
 153                         AC_MSG_WARN([libidnkit-$PECL_VAR([LIBIDNKIT2_VERSION]) already enabled, skipping libidnkit1])
 154                 else
 155                         PECL_CHECK_CUSTOM(libidnkit, "$PHP_HTTP_LIBIDNKIT_DIR", idn/api.h, idnkit,
 156                                 [$($EGREP "define IDNKIT_VERSION\b" "include/idn/version.h" | $SED -e's/^.*VERSION//g' -e 's/@<:@^0-9\.@:>@//g')])
 157                         if $PECL_VAR([HAVE_LIBIDNKIT]); then
 158                                 PECL_DEFINE([HAVE_IDNA2003])
 159                         fi
 160                         PECL_CHECK_DONE(libidnkit, [$PECL_VAR([HAVE_LIBIDNKIT])])
 161                 fi
 162         fi
 163
 164         dnl EXTENSIONS
 165         PECL_HAVE_PHP_EXT([raphf], [
 166                 PECL_HAVE_PHP_EXT_HEADER([raphf])
 167         ], [
 168                 AC_MSG_ERROR([please install and enable pecl/raphf])
 169         ])
 170         PECL_HAVE_PHP_EXT([iconv])
 171
 172         dnl DONE
 173         PHP_SUBST([HTTP_SHARED_LIBADD])
 174
 175         PECL_VAR([SRCDIR])=PHP_EXT_SRCDIR(http)
 176         PECL_VAR([BUILDDIR])=PHP_EXT_BUILDDIR(http)
 177
 178         PHP_ADD_INCLUDE([$PECL_VAR([SRCDIR])/src])
 179         PHP_ADD_BUILD_DIR([$PECL_VAR([BUILDDIR])/src])
 180
 181         PECL_VAR([HEADERS])=$(cd $PECL_VAR([SRCDIR])/src && echo *.h)
 182         PECL_VAR([SOURCES])=$(cd $PECL_VAR([SRCDIR]) && echo src/*.c)
 183
 184         PHP_NEW_EXTENSION(http, [$PECL_VAR([SOURCES])], [$ext_shared])
 185         PHP_INSTALL_HEADERS(ext/http, [php_http.h $PECL_VAR([HEADERS])])
 186
 187         PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
 188         [  --without-http-shared-deps       HTTP: do not depend on extensions like hash
 189                                          and iconv (when they are built shared)], yes, no)
 190         if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
 191                 if $PECL_VAR([HAVE_EXT_HASH]); then
 192                         PHP_ADD_EXTENSION_DEP([http], [hash], true)
 193                 fi
 194                 if $PECL_VAR([HAVE_EXT_ICONV]); then
 195                         PHP_ADD_EXTENSION_DEP([http], [iconv], true)
 196                 fi
 197         fi
 198         PHP_ADD_EXTENSION_DEP([http], [raphf], true)
 199
 200         PHP_SUBST(PECL_VAR([HEADERS]))
 201         PHP_SUBST(PECL_VAR([SOURCES]))
 202
 203         PHP_SUBST(PECL_VAR([SRCDIR]))
 204         PHP_SUBST(PECL_VAR([BUILDDIR]))
 205
 206         PHP_ADD_MAKEFILE_FRAGMENT
 207
 208         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 209 fi