projects / m6w6 / ext-http / blob
? search:
summary | shortlog | log | commit | commitdiff | tree | github
history | raw | HEAD
Merge branch 'master' into phpng
[m6w6/ext-http] / config9.m4
1 dnl config.m4 for pecl/http
2 dnl $Id: config9.m4 242664 2007-09-18 19:13:37Z mike $
3 dnl vim: noet ts=4 sw=4
4
5 PHP_ARG_WITH([http], [whether to enable extended HTTP support],
6 [ --with-http Enable extended HTTP support])
7 PHP_ARG_WITH([http-zlib-dir], [],
8 [ --with-http-zlib-dir[=DIR] HTTP: where to find zlib], $PHP_HTTP, $PHP_HTTP)
9 PHP_ARG_WITH([http-libcurl-dir], [],
10 [ --with-http-libcurl-dir[=DIR] HTTP: where to find libcurl], $PHP_HTTP, $PHP_HTTP)
11 PHP_ARG_WITH([http-libevent-dir], [],
12 [ --with-http-libevent-dir[=DIR] HTTP: where to find libevent], $PHP_HTTP_LIBCURL_DIR, "")
13 PHP_ARG_WITH([http-libidn-dir], [],
14 [ --with-http-libidn-dir[=DIR] HTTP: where to find libidn], $PHP_HTTP_LIBCURL_DIR, "")
15
16 if test "$PHP_HTTP" != "no"; then
17
18 HTTP_HAVE_A_REQUEST_LIB=false
19
20 ifdef([AC_PROG_EGREP], [
21 AC_PROG_EGREP
22 ], [
23 AC_CHECK_PROG(EGREP, egrep, egrep)
24 ])
25 ifdef([AC_PROG_SED], [
26 AC_PROG_SED
27 ], [
28 ifdef([LT_AC_PROG_SED], [
29 LT_AC_PROG_SED
30 ], [
31 AC_CHECK_PROG(SED, sed, sed)
32 ])
33 ])
34
35 AC_PROG_CPP
36
37 if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
38 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [1], [ ])
39 else
40 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [0], [ ])
41 fi
42
43 dnl
44 dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
45 dnl
46 AC_DEFUN([HTTP_SHARED_DEP], [
47 extname=$1
48 haveext=$[PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
49
50 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
51 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
52 AC_MSG_RESULT([no])
53 $3
54 elif test "$haveext"; then
55 AC_MSG_RESULT([yes])
56 AC_DEFINE([PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__), [1], [ ])
57 ifdef([PHP_ADD_EXTENSION_DEP], [
58 PHP_ADD_EXTENSION_DEP([http], $1, true)
59 ])
60 $2
61 else
62 AC_MSG_RESULT([no])
63 $3
64 fi
65 ])
66
67 dnl
68 dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
69 dnl
70 AC_DEFUN([HTTP_HAVE_PHP_EXT], [
71 extname=$1
72 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
73 AC_MSG_CHECKING([for ext/$extname support])
74 if test -x "$PHP_EXECUTABLE"; then
75 grepext=`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`
76 if test "$grepext" = "$extname"; then
77 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
78 AC_MSG_RESULT([yes])
79 $2
80 else
81 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
82 AC_MSG_RESULT([no])
83 $3
84 fi
85 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
86 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
87 AC_MSG_RESULT([yes])
88 $2
89 else
90 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
91 AC_MSG_RESULT([no])
92 $3
93 fi
94 ])
95
96
97 dnl ----
98 dnl STDC
99 dnl ----
100 AC_TYPE_OFF_T
101 AC_TYPE_MBSTATE_T
102 dnl getdomainname() is declared in netdb.h on some platforms: AIX, OSF
103 AC_CHECK_HEADERS([netdb.h unistd.h wchar.h wctype.h arpa/inet.h])
104 PHP_CHECK_FUNC(gethostname, nsl)
105 PHP_CHECK_FUNC(getdomainname, nsl)
106 PHP_CHECK_FUNC(mbrtowc)
107 PHP_CHECK_FUNC(mbtowc)
108 PHP_CHECK_FUNC(iswalnum)
109 PHP_CHECK_FUNC(inet_pton)
110
111 dnl ----
112 dnl IDN
113 dnl ----
114
115 AC_MSG_CHECKING([for idna.h])
116 IDNA_DIR=
117 for i in "$PHP_HTTP_LIBIDN_DIR" "$IDN_DIR" /usr/local /usr /opt; do
118 if test -f "$i/include/idna.h"; then
119 IDNA_DIR=$i
120 break;
121 fi
122 done
123 if test "x$IDNA_DIR" != "x"; then
124 AC_MSG_RESULT([found in $IDNA_DIR])
125 AC_DEFINE([PHP_HTTP_HAVE_IDN], [1], [Have libidn support])
126 PHP_ADD_INCLUDE($IDNA_DIR/include)
127 PHP_ADD_LIBRARY_WITH_PATH(idn, $IDNA_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
128 AC_MSG_CHECKING([for libidn version])
129 IDNA_VER=$(pkg-config --version libidn 2>/dev/null || echo unknown)
130 AC_MSG_RESULT([$IDNA_VER])
131 AC_DEFINE_UNQUOTED([PHP_HTTP_LIBIDN_VERSION], "$IDNA_VER", [ ])
132 else
133 AC_MSG_RESULT([not found])
134 AC_MSG_CHECKING([for idn2.h])
135 IDNA_DIR=
136 for i in "$PHP_HTTP_LIBIDN_DIR" "$IDN_DIR" /usr/local /usr /opt; do
137 if test -f "$i/include/idn2.h"; then
138 IDNA_DIR=$i
139 break;
140 fi
141 done
142 if test "x$IDNA_DIR" != "x"; then
143 AC_MSG_RESULT([found in $IDNA_DIR])
144 AC_DEFINE([PHP_HTTP_HAVE_IDN2], [1], [Have libidn2 support])
145 PHP_ADD_INCLUDE($IDNA_DIR/include)
146 PHP_ADD_LIBRARY_WITH_PATH(idn2, $IDNA_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
147 AC_MSG_CHECKING([for libidn2 version])
148 IDNA_VER=`$EGREP "define IDN2_VERSION " $IDNA_DIR/include/idn2.h | $SED -e's/^.*VERSION //g' -e 's/[[^0-9\.]]//g'`
149 AC_MSG_RESULT([$IDNA_VER])
150 AC_DEFINE_UNQUOTED([PHP_HTTP_LIBIDN2_VERSION], "$IDNA_VER", [ ])
151 else
152 AC_MSG_RESULT([not found])
153 AC_CHECK_HEADERS([unicode/uidna.h])
154 case $host_os in
155 darwin*)
156 PHP_CHECK_FUNC(uidna_IDNToASCII, icucore);;
157 *)
158 AC_PATH_PROG(ICU_CONFIG, icu-config, no, [$PATH:/usr/local/bin])
159 if test ! -x "$ICU_CONFIG"; then
160 ICU_CONFIG="icu-config"
161 fi
162 AC_MSG_CHECKING([for uidna_IDNToASCII])
163 if ! test -x "$ICU_CONFIG"; then
164 ICU_CONFIG=icu-config
165 fi
166 if $ICU_CONFIG --exists 2>/dev/null >&2; then
167 save_LIBS=$LIBS
168 LIBS=$($ICU_CONFIG --ldflags)
169 AC_TRY_RUN([
170 #include <unicode/uidna.h>
171 int main(int argc, char *argv[]) {
172 return uidna_IDNToASCII(0, 0, 0, 0, 0, 0, 0);
173 }
174 ], [
175 AC_MSG_RESULT([yes])
176 AC_DEFINE([HAVE_UIDNA_IDNTOASCII], [1], [ ])
177 LIBS=$save_LIBS
178 PHP_EVAL_LIBLINE(`$ICU_CONFIG --ldflags`, HTTP_SHARED_LIBADD)
179 ], [
180 LIBS=$save_LIBS
181 AC_MSG_RESULT([no])
182 ])
183 fi
184 ;;
185 esac
186 fi
187 fi
188
189 dnl ----
190 dnl ZLIB
191 dnl ----
192 AC_MSG_CHECKING([for zlib.h])
193 ZLIB_DIR=
194 for i in "$PHP_HTTP_ZLIB_DIR" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
195 if test -f "$i/include/zlib.h"; then
196 ZLIB_DIR=$i
197 break;
198 fi
199 done
200 if test "x$ZLIB_DIR" = "x"; then
201 AC_MSG_RESULT([not found])
202 AC_MSG_ERROR([could not find zlib.h])
203 else
204 AC_MSG_RESULT([found in $ZLIB_DIR])
205 AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
206 ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
207 AC_MSG_RESULT([$ZLIB_VERSION])
208 if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
209 AC_MSG_ERROR([zlib version greater or equal to 1.2.0.4 required])
210 else
211 PHP_ADD_INCLUDE($ZLIB_DIR/include)
212 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
213 fi
214 fi
215
216 dnl ----
217 dnl CURL
218 dnl ----
219
220 if test "$PHP_HTTP_LIBCURL_DIR" = "no"; then
221 AC_DEFINE([PHP_HTTP_HAVE_CURL], [0], [ ])
222 else
223 AC_MSG_CHECKING([for curl/curl.h])
224 CURL_DIR=
225 for i in "$PHP_HTTP_LIBCURL_DIR" /usr/local /usr /opt; do
226 if test -f "$i/include/curl/curl.h"; then
227 CURL_DIR=$i
228 break
229 fi
230 done
231 if test "x$CURL_DIR" = "x"; then
232 AC_MSG_RESULT([not found])
233 else
234 AC_MSG_RESULT([found in $CURL_DIR])
235
236 AC_MSG_CHECKING([for curl-config])
237 CURL_CONFIG=
238 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
239 if test -x "$i"; then
240 CURL_CONFIG=$i
241 break
242 fi
243 done
244 if test "x$CURL_CONFIG" = "x"; then
245 AC_MSG_RESULT([not found])
246 AC_MSG_ERROR([could not find curl-config])
247 else
248 AC_MSG_RESULT([found: $CURL_CONFIG])
249 fi
250
251 dnl RHEL6: 7.19.7
252 dnl SUSE11: 7.19.7
253 dnl Debian wheezy: 7.26.0
254 dnl Debian sqeeze: 7.21.0
255 dnl Debian ancient 7.18.2
256 AC_MSG_CHECKING([for curl version >= 7.18.2])
257 CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
258 AC_MSG_RESULT([$CURL_VERSION])
259 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71802; then
260 AC_MSG_ERROR([libcurl version greater or equal to 7.18.2 required])
261 fi
262
263 AC_MSG_CHECKING([for HTTP2 support in libcurl])
264 if $CURL_CONFIG --features | $EGREP -q HTTP2; then
265 AC_MSG_RESULT([yes])
266 AC_DEFINE([PHP_HTTP_HAVE_HTTP2], [1], [ ])
267 else
268 AC_MSG_RESULT([no])
269 fi
270
271 dnl
272 dnl compile tests
273 dnl
274
275 save_INCLUDES="$INCLUDES"
276 INCLUDES=
277 save_LIBS="$LIBS"
278 LIBS=-lcurl
279 save_CFLAGS="$CFLAGS"
280 CFLAGS="$CFLAGS `$CURL_CONFIG --cflags`"
281 save_LDFLAGS="$LDFLAGS"
282 LDFLAGS="$ld_runpath_switch$CURL_DIR/$PHP_LIBDIR"
283
284 AC_MSG_CHECKING([for SSL support in libcurl])
285 CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
286 CURL_SSL_LIBS=""
287 if test "$CURL_SSL" = "SSL"; then
288 AC_MSG_RESULT([yes])
289 AC_DEFINE([PHP_HTTP_HAVE_SSL], [1], [ ])
290
291 AC_MSG_CHECKING([for openssl support in libcurl])
292 AC_TRY_RUN([
293 #include <curl/curl.h>
294 int main(int argc, char *argv[]) {
295 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
296 if (data && data->ssl_version && *data->ssl_version) {
297 const char *ptr = data->ssl_version;
298 while(*ptr == ' ') ++ptr;
299 return strncasecmp(ptr, "OpenSSL", sizeof("OpenSSL")-1);
300 }
301 return 1;
302 }
303 ], [
304 AC_MSG_RESULT([yes])
305 AC_CHECK_HEADER([openssl/ssl.h], [
306 AC_CHECK_HEADER([openssl/crypto.h], [
307 AC_DEFINE([PHP_HTTP_HAVE_OPENSSL], [1], [ ])
308 CURL_SSL_LIBS="ssl crypto"
309 ])
310 ])
311 ], [
312 AC_MSG_RESULT([no])
313 ], [
314 AC_MSG_RESULT([no])
315 ])
316
317 AC_MSG_CHECKING([for gnutls support in libcurl])
318 AC_TRY_RUN([
319 #include <curl/curl.h>
320 int main(int argc, char *argv[]) {
321 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
322 if (data && data->ssl_version && *data->ssl_version) {
323 const char *ptr = data->ssl_version;
324 while(*ptr == ' ') ++ptr;
325 return strncasecmp(ptr, "GnuTLS", sizeof("GnuTLS")-1);
326 }
327 return 1;
328 }
329 ], [
330 AC_MSG_RESULT([yes])
331 AC_CHECK_HEADER([gnutls.h], [
332 AC_CHECK_HEADER([gcrypt.h], [
333 AC_DEFINE([PHP_HTTP_HAVE_GNUTLS], [1], [ ])
334 CURL_SSL_LIBS="gnutls gcrypt"
335 ])
336 ])
337 ], [
338 AC_MSG_RESULT([no])
339 ], [
340 AC_MSG_RESULT([no])
341 ])
342 else
343 AC_MSG_RESULT([no])
344 fi
345
346 AC_MSG_CHECKING([for ares support in libcurl])
347 AC_TRY_RUN([
348 #include <curl/curl.h>
349 int main(int argc, char *argv[]) {
350 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
351 if (data && data->ares && data->ares_num0) {
352 return 0;
353 }
354 return 1;
355 }
356 ], [
357 AC_MSG_RESULT([yes])
358 AC_DEFINE([PHP_HTTP_HAVE_ARES], [1], [ ])
359 ], [
360 AC_MSG_RESULT([no])
361 ], [
362 AC_MSG_RESULT([no])
363 ])
364
365 AC_MSG_CHECKING([whether CURLOPT_TLSAUTH_TYPE expects CURL_TLSAUTH_SRP or literal "SRP"])
366 AC_TRY_RUN([
367 #include <curl/curl.h>
368 int main(int argc, char *argv[]) {
369 CURL *ch = curl_easy_init();
370 return curl_easy_setopt(ch, CURLOPT_TLSAUTH_TYPE, CURL_TLSAUTH_SRP);
371 }
372 ], [
373 AC_MSG_RESULT([CURL_TLSAUTH_SRP])
374 AC_DEFINE([PHP_HTTP_CURL_TLSAUTH_SRP], [CURL_TLSAUTH_SRP], [ ])
375 AC_DEFINE([PHP_HTTP_CURL_TLSAUTH_DEF], [CURL_TLSAUTH_NONE], [ ])
376 ], [
377 AC_TRY_RUN([
378 #include <curl/curl.h>
379 int main(int argc, char *argv[]) {
380 CURL *ch = curl_easy_init();
381 return curl_easy_setopt(ch, CURLOPT_TLSAUTH_TYPE, "SRP");
382 }
383 ], [
384 AC_MSG_RESULT(["SRP"])
385 AC_DEFINE([PHP_HTTP_CURL_TLSAUTH_SRP], ["SRP"], [ ])
386 AC_DEFINE([PHP_HTTP_CURL_TLSAUTH_DEF], [""], [ ])
387 ], [
388 AC_MSG_RESULT([neither])
389 ], [
390 AC_MSG_RESULT([neither])
391 ])
392 ], [
393 AC_MSG_RESULT([neither])
394 ])
395
396 INCLUDES="$save_INCLUDES"
397 LIBS="$save_LIBS"
398 CFLAGS="$save_CFLAGS"
399 LDFLAGS="$save_LDFLAGS"
400
401 if test -n "$CURL_SSL_LIBS"; then
402 for CURL_SSL_LIB in $CURL_SSL_LIBS; do
403 PHP_ADD_LIBRARY_WITH_PATH([$CURL_SSL_LIB], $CURL_DIR/$PHP_LIBDIR, PHP_HTTP_SHARED_LIBADD)
404 done
405 fi
406
407 dnl end compile tests
408
409 AC_MSG_CHECKING([for bundled SSL CA info])
410 CURL_CAINFO=
411 for i in `$CURL_CONFIG --ca` "/etc/ssl/certs/ca-certificates.crt" "/etc/ssl/certs/ca-bundle.crt"; do
412 if test -f "$i"; then
413 CURL_CAINFO="$i"
414 break
415 fi
416 done
417 if test "x$CURL_CAINFO" = "x"; then
418 AC_MSG_RESULT([not found])
419 else
420 AC_MSG_RESULT([$CURL_CAINFO])
421 AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAINFO], ["$CURL_CAINFO"], [path to bundled SSL CA info])
422 fi
423
424 PHP_ADD_INCLUDE($CURL_DIR/include)
425 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
426 PHP_EVAL_LIBLINE(`$CURL_CONFIG --libs`, HTTP_SHARED_LIBADD)
427 AC_DEFINE([PHP_HTTP_HAVE_CURL], [1], [Have libcurl support])
428 HTTP_HAVE_A_REQUEST_LIB=true
429 fi
430 fi
431
432 dnl ----
433 dnl EVENT
434 dnl ----
435
436 if test "$PHP_HTTP_LIBEVENT_DIR" = "no"; then
437 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
438 else
439 AC_MSG_CHECKING([for event2/event.h])
440 EVENT_DIR=
441 for i in "$PHP_HTTP_LIBEVENT_DIR" /usr/local /usr /opt; do
442 if test -f "$i/include/event.h"; then
443 EVENT_DIR=$i
444 break
445 fi
446 done
447 if test "x$EVENT_DIR" = "x"; then
448 AC_MSG_RESULT([not found])
449 AC_MSG_WARN([continuing without libevent support])
450 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
451 else
452 AC_MSG_RESULT([found in $EVENT_DIR])
453
454 AC_MSG_CHECKING([for libevent version, roughly])
455
456 if test -f "$EVENT_DIR/include/event2/event.h"; then
457 EVENT_VER="`$AWK '/_EVENT_VERSION/ {gsub(/\"/,\"\",$3); print $3}' < $EVENT_DIR/include/event2/event-config.h`"
458 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [1], [ ])
459 else
460 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [0], [ ])
461 if test -f "$EVENT_DIR/include/evhttp.h" && test -f "$EVENT_DIR/include/evdns.h"; then
462 if test -f "$EVENT_DIR/include/evrpc.h"; then
463 EVENT_VER="1.4 or greater"
464 else
465 EVENT_VER="1.2 or greater"
466 fi
467 else
468 EVENT_VER="1.1b or lower"
469 fi
470 fi
471 AC_DEFINE_UNQUOTED([PHP_HTTP_EVENT_VERSION], ["$EVENT_VER"], [ ])
472 AC_MSG_RESULT([$EVENT_VER])
473
474 PHP_ADD_INCLUDE($EVENT_DIR/include)
475 PHP_ADD_LIBRARY_WITH_PATH(event, $EVENT_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
476 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [1], [Have libevent support for cURL])
477 fi
478 fi
479
480 dnl ----
481 dnl RAPHF
482 dnl ----
483 HTTP_HAVE_PHP_EXT([raphf], [
484 AC_MSG_CHECKING([for php_raphf.h])
485 HTTP_EXT_RAPHF_INCDIR=
486 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../raphf; do
487 if test -d $i; then
488 if test -f $i/php_raphf.h; then
489 HTTP_EXT_RAPHF_INCDIR=$i
490 break
491 elif test -f $i/ext/raphf/php_raphf.h; then
492 HTTP_EXT_RAPHF_INCDIR=$i/ext/raphf
493 break
494 fi
495 fi
496 done
497 if test "x$HTTP_EXT_RAPHF_INCDIR" = "x"; then
498 AC_MSG_ERROR([not found])
499 else
500 AC_MSG_RESULT([$HTTP_EXT_RAPHF_INCDIR])
501 AC_DEFINE([PHP_HTTP_HAVE_PHP_RAPHF_H], [1], [Have ext/raphf support])
502 PHP_ADD_INCLUDE([$HTTP_EXT_RAPHF_INCDIR])
503 fi
504 ], [
505 AC_MSG_ERROR([Please install pecl/raphf and activate extension=raphf.$SHLIB_DL_SUFFIX_NAME in your php.ini])
506 ])
507
508 dnl ----
509 dnl PROPRO
510 dnl ----
511 HTTP_HAVE_PHP_EXT([propro], [
512 AC_MSG_CHECKING([for php_propro.h])
513 HTTP_EXT_PROPRO_INCDIR=
514 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../propro; do
515 if test -d $i; then
516 if test -f $i/php_propro.h; then
517 HTTP_EXT_PROPRO_INCDIR=$i
518 break
519 elif test -f $i/ext/propro/php_propro.h; then
520 HTTP_EXT_PROPRO_INCDIR=$i/ext/propro
521 break
522 fi
523 fi
524 done
525 if test "x$HTTP_EXT_PROPRO_INCDIR" = "x"; then
526 AC_MSG_ERROR([not found])
527 else
528 AC_MSG_RESULT([$HTTP_EXT_PROPRO_INCDIR])
529 AC_DEFINE([PHP_HTTP_HAVE_PHP_PROPRO_H], [1], [Have ext/propro support])
530 PHP_ADD_INCLUDE([$HTTP_EXT_PROPRO_INCDIR])
531 fi
532 ], [
533 AC_MSG_ERROR([Please install pecl/propro and activate extension=propro.$SHLIB_DL_SUFFIX_NAME in your php.ini])
534 ])
535
536 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
537 [ --without-http-shared-deps HTTP: do not depend on extensions like hash
538 and iconv (when they are built shared)], $PHP_HTTP, $PHP_HTTP)
539 dnl ----
540 dnl HASH
541 dnl ----
542 HTTP_HAVE_PHP_EXT([hash], [
543 AC_MSG_CHECKING([for php_hash.h])
544 HTTP_EXT_HASH_INCDIR=
545 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
546 if test -d $i; then
547 if test -f $i/php_hash.h; then
548 HTTP_EXT_HASH_INCDIR=$i
549 break
550 elif test -f $i/ext/hash/php_hash.h; then
551 HTTP_EXT_HASH_INCDIR=$i/ext/hash
552 break
553 fi
554 fi
555 done
556 if test "x$HTTP_EXT_HASH_INCDIR" = "x"; then
557 AC_MSG_RESULT([not found])
558 else
559 AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
560 AC_DEFINE([PHP_HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
561 PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
562 fi
563 ])
564
565 dnl ----
566 dnl ICONV
567 dnl ----
568 HTTP_HAVE_PHP_EXT([iconv])
569
570 dnl ----
571 dnl DONE
572 dnl ----
573 PHP_HTTP_SOURCES="\
574 php_http_buffer.c \
575 php_http.c \
576 php_http_client.c \
577 php_http_client_curl.c \
578 php_http_client_request.c \
579 php_http_client_response.c \
580 php_http_cookie.c \
581 php_http_curl.c \
582 php_http_encoding.c \
583 php_http_env.c \
584 php_http_env_request.c \
585 php_http_env_response.c \
586 php_http_etag.c \
587 php_http_exception.c \
588 php_http_filter.c \
589 php_http_header_parser.c \
590 php_http_header.c \
591 php_http_info.c \
592 php_http_message_body.c \
593 php_http_message.c \
594 php_http_message_parser.c \
595 php_http_misc.c \
596 php_http_negotiate.c \
597 php_http_object.c \
598 php_http_options.c \
599 php_http_params.c \
600 php_http_querystring.c \
601 php_http_url.c \
602 php_http_version.c \
603 "
604 PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
605
606 dnl shared extension deps
607 HTTP_SHARED_DEP([hash])
608 HTTP_SHARED_DEP([iconv])
609
610 dnl extension deps
611 PHP_ADD_EXTENSION_DEP([http], [raphf], true)
612 PHP_ADD_EXTENSION_DEP([http], [propro], true)
613
614 PHP_SUBST([HTTP_SHARED_LIBADD])
615
616 PHP_HTTP_HEADERS="
617 php_http_api.h \
618 php_http_buffer.h \
619 php_http_curl_client.h \
620 php_http_curl_client_datashare.h \
621 php_http_client_datashare.h \
622 php_http_client_factory.h \
623 php_http_client.h \
624 php_http_client_interface.h \
625 php_http_curl_client_pool.h \
626 php_http_client_pool.h \
627 php_http_client_request.h \
628 php_http_client_response.h \
629 php_http_cookie.h \
630 php_http_curl.h \
631 php_http_encoding.h \
632 php_http_env.h \
633 php_http_env_request.h \
634 php_http_env_response.h \
635 php_http_etag.h \
636 php_http_exception.h \
637 php_http_filter.h \
638 php_http.h \
639 php_http_header_parser.h \
640 php_http_header.h \
641 php_http_info.h \
642 php_http_message_body.h \
643 php_http_message.h \
644 php_http_message_parser.h \
645 php_http_misc.h \
646 php_http_negotiate.h \
647 php_http_object.h \
648 php_http_options.h \
649 php_http_params.h \
650 php_http_querystring.h \
651 php_http_response_codes.h \
652 php_http_url.h \
653 php_http_utf8.h \
654 php_http_version.h \
655 "
656 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
657
658 AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
659 if $HTTP_HAVE_A_REQUEST_LIB; then
660 AC_DEFINE([PHP_HTTP_HAVE_CLIENT], [1], [Have HTTP client support])
661 fi
662 fi
Extended HTTP Support