projects / m6w6 / ext-http / blob
? search:


f84266f0666b4991f67ef42acfb96301bf4f16e0
[m6w6/ext-http] / config9.m4
1 dnl config.m4 for pecl/http
2 dnl $Id: config9.m4 242664 2007-09-18 19:13:37Z mike $
3 dnl vim: noet ts=4 sw=4
4
5 PHP_ARG_WITH([http], [whether to enable extended HTTP support],
6 [ --with-http Enable extended HTTP support])
7 PHP_ARG_WITH([http-zlib-dir], [],
8 [ --with-http-zlib-dir[=DIR] HTTP: where to find zlib], $PHP_HTTP, $PHP_HTTP)
9 PHP_ARG_WITH([http-libcurl-dir], [],
10 [ --with-http-libcurl-dir[=DIR] HTTP: where to find libcurl], $PHP_HTTP, $PHP_HTTP)
11 PHP_ARG_WITH([http-libevent-dir], [],
12 [ --with-http-libevent-dir[=DIR] HTTP: where to find libevent], $PHP_HTTP_LIBCURL_DIR, "")
13
14 if test "$PHP_HTTP" != "no"; then
15
16 HTTP_HAVE_A_REQUEST_LIB=false
17
18 ifdef([AC_PROG_EGREP], [
19 AC_PROG_EGREP
20 ], [
21 AC_CHECK_PROG(EGREP, egrep, egrep)
22 ])
23 ifdef([AC_PROG_SED], [
24 AC_PROG_SED
25 ], [
26 ifdef([LT_AC_PROG_SED], [
27 LT_AC_PROG_SED
28 ], [
29 AC_CHECK_PROG(SED, sed, sed)
30 ])
31 ])
32
33 AC_PROG_CPP
34
35 if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
36 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [1], [ ])
37 else
38 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [0], [ ])
39 fi
40
41 dnl
42 dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
43 dnl
44 AC_DEFUN([HTTP_SHARED_DEP], [
45 extname=$1
46 haveext=$[PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
47
48 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
49 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
50 AC_MSG_RESULT([no])
51 $3
52 elif test "$haveext"; then
53 AC_MSG_RESULT([yes])
54 AC_DEFINE([PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__), [1], [ ])
55 ifdef([PHP_ADD_EXTENSION_DEP], [
56 PHP_ADD_EXTENSION_DEP([http], $1, true)
57 ])
58 $2
59 else
60 AC_MSG_RESULT([no])
61 $3
62 fi
63 ])
64
65 dnl
66 dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
67 dnl
68 AC_DEFUN([HTTP_HAVE_PHP_EXT], [
69 extname=$1
70 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
71
72 AC_MSG_CHECKING([for ext/$extname support])
73 if test -x "$PHP_EXECUTABLE"; then
74 grepext=`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`
75 if test "$grepext" = "$extname"; then
76 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
77 AC_MSG_RESULT([yes])
78 $2
79 else
80 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
81 AC_MSG_RESULT([no])
82 $3
83 fi
84 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
85 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
86 AC_MSG_RESULT([yes])
87 $2
88 else
89 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
90 AC_MSG_RESULT([no])
91 $3
92 fi
93 ])
94
95
96 dnl ----
97 dnl STDC
98 dnl ----
99 AC_CHECK_HEADERS([netdb.h unistd.h])
100 PHP_CHECK_FUNC(gethostname, nsl)
101 PHP_CHECK_FUNC(getdomainname, nsl)
102 PHP_CHECK_FUNC(getservbyport, nsl)
103 PHP_CHECK_FUNC(getservbyname, nsl)
104
105 dnl ----
106 dnl ZLIB
107 dnl ----
108 AC_MSG_CHECKING([for zlib.h])
109 ZLIB_DIR=
110 for i in "$PHP_HTTP_ZLIB_DIR" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
111 if test -f "$i/include/zlib.h"; then
112 ZLIB_DIR=$i
113 break;
114 fi
115 done
116 if test "x$ZLIB_DIR" = "x"; then
117 AC_MSG_RESULT([not found])
118 AC_MSG_ERROR([could not find zlib.h])
119 else
120 AC_MSG_RESULT([found in $ZLIB_DIR])
121 AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
122 ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
123 AC_MSG_RESULT([$ZLIB_VERSION])
124 if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
125 AC_MSG_ERROR([zlib version greater or equal to 1.2.0.4 required])
126 else
127 PHP_ADD_INCLUDE($ZLIB_DIR/include)
128 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
129 fi
130 fi
131
132 dnl ----
133 dnl SERF
134 dnl ----
135 dnl
136 dnl if test "$PHP_HTTP_LIBSERF_DIR" = "no"; then
137 dnl AC_DEFINE([PHP_HTTP_HAVE_SERF], [0], [ ])
138 dnl else
139 dnl AC_MSG_CHECKING([for serf-?/serf.h])
140 dnl SERF_DIR=
141 dnl for i in "$PHP_HTTP_LIBSERF_DIR" /usr/local /usr /opt; do
142 dnl if test -f "$i/include/serf-0/serf.h"; then
143 dnl SERF_DIR=$i
144 dnl SERF_VER=0
145 dnl break
146 dnl elif test -f "$i/include/serf-1/serf.h"; then
147 dnl SERF_DIR=$i
148 dnl SERF_VER=1
149 dnl fi
150 dnl done
151
152 dnl if test "x$SERF_DIR" = "x"; then
153 dnl AC_MSG_RESULT([not found])
154 dnl AC_DEFINE([PHP_HTTP_HAVE_SERF], [0], [ ])
155 dnl else
156 dnl AC_MSG_RESULT([found in $SERF_DIR])
157
158 dnl PHP_ADD_INCLUDE($SERF_DIR/include/serf-$SERF_VER)
159 dnl PHP_ADD_LIBRARY_WITH_PATH(serf-$SERF_VER, $SERF_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
160 dnl AC_DEFINE([PHP_HTTP_HAVE_SERF], [1], [Have libserf support])
161 dnl HTTP_HAVE_A_REQUEST_LIB=true
162 dnl fi
163 dnl fi
164 dnl
165
166 dnl ----
167 dnl CURL
168 dnl ----
169
170 if test "$PHP_HTTP_LIBCURL_DIR" = "no"; then
171 AC_DEFINE([PHP_HTTP_HAVE_CURL], [0], [ ])
172 else
173 AC_MSG_CHECKING([for curl/curl.h])
174 CURL_DIR=
175 for i in "$PHP_HTTP_LIBCURL_DIR" /usr/local /usr /opt; do
176 if test -f "$i/include/curl/curl.h"; then
177 CURL_DIR=$i
178 break
179 fi
180 done
181 if test "x$CURL_DIR" = "x"; then
182 AC_MSG_RESULT([not found])
183 else
184 AC_MSG_RESULT([found in $CURL_DIR])
185
186 AC_MSG_CHECKING([for curl-config])
187 CURL_CONFIG=
188 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
189 if test -x "$i"; then
190 CURL_CONFIG=$i
191 break
192 fi
193 done
194 if test "x$CURL_CONFIG" = "x"; then
195 AC_MSG_RESULT([not found])
196 AC_MSG_ERROR([could not find curl-config])
197 else
198 AC_MSG_RESULT([found: $CURL_CONFIG])
199 fi
200
201 dnl Debian stable has currently 7.18.2
202 AC_MSG_CHECKING([for curl version >= 7.18.2])
203 CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
204 AC_MSG_RESULT([$CURL_VERSION])
205 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71802; then
206 AC_MSG_ERROR([libcurl version greater or equal to 7.18.2 required])
207 fi
208
209 dnl
210 dnl compile tests
211 dnl
212
213 save_INCLUDES="$INCLUDES"
214 INCLUDES=
215 save_LIBS="$LIBS"
216 LIBS=
217 save_CFLAGS="$CFLAGS"
218 CFLAGS=`$CURL_CONFIG --cflags`
219 save_LDFLAGS="$LDFLAGS"
220 LDFLAGS=`$CURL_CONFIG --libs`
221 LDFLAGS="$LDFLAGS $ld_runpath_switch$CURL_DIR/$PHP_LIBDIR"
222
223 AC_MSG_CHECKING([for SSL support in libcurl])
224 CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
225 if test "$CURL_SSL" = "SSL"; then
226 AC_MSG_RESULT([yes])
227 AC_DEFINE([PHP_HTTP_HAVE_SSL], [1], [ ])
228
229 AC_MSG_CHECKING([for openssl support in libcurl])
230 AC_TRY_RUN([
231 #include <curl/curl.h>
232 int main(int argc, char *argv[]) {
233 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
234 if (data && data->ssl_version && *data->ssl_version) {
235 const char *ptr = data->ssl_version;
236 while(*ptr == ' ') ++ptr;
237 return strncasecmp(ptr, "OpenSSL", sizeof("OpenSSL")-1);
238 }
239 return 1;
240 }
241 ], [
242 AC_MSG_RESULT([yes])
243 AC_CHECK_HEADER([openssl/crypto.h], [
244 AC_DEFINE([PHP_HTTP_HAVE_OPENSSL], [1], [ ])
245 CURL_SSL="crypto"
246 ])
247 ], [
248 AC_MSG_RESULT([no])
249 ], [
250 AC_MSG_RESULT([no])
251 ])
252
253 AC_MSG_CHECKING([for gnutls support in libcurl])
254 AC_TRY_RUN([
255 #include <curl/curl.h>
256 int main(int argc, char *argv[]) {
257 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
258 if (data && data->ssl_version && *data->ssl_version) {
259 const char *ptr = data->ssl_version;
260 while(*ptr == ' ') ++ptr;
261 return strncasecmp(ptr, "GnuTLS", sizeof("GnuTLS")-1);
262 }
263 return 1;
264 }
265 ], [
266 AC_MSG_RESULT([yes])
267 AC_CHECK_HEADER([gcrypt.h], [
268 AC_DEFINE([PHP_HTTP_HAVE_GNUTLS], [1], [ ])
269 CURL_SSL="gcrypt"
270 ])
271 ], [
272 AC_MSG_RESULT([no])
273 ], [
274 AC_MSG_RESULT([no])
275 ])
276 else
277 AC_MSG_RESULT([no])
278 fi
279
280 INCLUDES="$save_INCLUDES"
281 LIBS="$save_LIBS"
282 CFLAGS="$save_CFLAGS"
283 LDFLAGS="$save_LDFLAGS"
284
285 dnl end compile tests
286
287 AC_MSG_CHECKING([for bundled SSL CA info])
288 CURL_CAINFO=
289 for i in `$CURL_CONFIG --ca` "/etc/ssl/certs/ca-certificates.crt"; do
290 if test -f "$i"; then
291 CURL_CAINFO="$i"
292 break
293 fi
294 done
295 if test "x$CURL_CAINFO" = "x"; then
296 AC_MSG_RESULT([not found])
297 else
298 AC_MSG_RESULT([$CURL_CAINFO])
299 AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAINFO], ["$CURL_CAINFO"], [path to bundled SSL CA info])
300 fi
301
302 PHP_ADD_INCLUDE($CURL_DIR/include)
303 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
304 PHP_EVAL_LIBLINE(`$CURL_CONFIG --libs`, HTTP_SHARED_LIBADD)
305 if test "x$CURL_SSL" != "x"; then
306 PHP_ADD_LIBRARY_WITH_PATH([$CURL_SSL], $CURL_DIR/$PHP_LIBDIR, PHP_HTTP_SHARED_LIBADD)
307 fi
308 AC_DEFINE([PHP_HTTP_HAVE_CURL], [1], [Have libcurl support])
309 HTTP_HAVE_A_REQUEST_LIB=true
310 fi
311 fi
312
313 dnl ----
314 dnl EVENT
315 dnl ----
316
317 if test "$PHP_HTTP_LIBEVENT_DIR" = "no"; then
318 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
319 else
320 HTTP_HAVE_PHP_EXT([event], [
321 AC_MSG_WARN([event support is incompatible with pecl/event; continuing without libevent support])
322 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
323 ], [
324 AC_MSG_CHECKING([for event2/event.h])
325 EVENT_DIR=
326 for i in "$PHP_HTTP_LIBEVENT_DIR" /usr/local /usr /opt; do
327 if test -f "$i/include/event.h"; then
328 EVENT_DIR=$i
329 break
330 fi
331 done
332 if test "x$EVENT_DIR" = "x"; then
333 AC_MSG_RESULT([not found])
334 AC_MSG_WARN([continuing without libevent support])
335 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
336 else
337 AC_MSG_RESULT([found in $EVENT_DIR])
338
339 AC_MSG_CHECKING([for libevent version, roughly])
340
341 if test -f "$EVENT_DIR/include/event2/event.h"; then
342 EVENT_VER="`$EGREP _EVENT_VERSION $EVENT_DIR/include/event2/event.h | $AWK '{print $3}'`"
343 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [1], [ ])
344 else
345 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [0], [ ])
346 if test -f "$EVENT_DIR/include/evhttp.h" && test -f "$EVENT_DIR/include/evdns.h"; then
347 if test -f "$EVENT_DIR/include/evrpc.h"; then
348 EVENT_VER="1.4 or greater"
349 else
350 EVENT_VER="1.2 or greater"
351 fi
352 else
353 EVENT_VER="1.1b or lower"
354 fi
355 fi
356 AC_DEFINE_UNQUOTED([PHP_HTTP_EVENT_VERSION], ["$EVENT_VER"], [ ])
357 AC_MSG_RESULT([$EVENT_VER])
358
359 PHP_ADD_INCLUDE($EVENT_DIR/include)
360 PHP_ADD_LIBRARY_WITH_PATH(event, $EVENT_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
361 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [1], [Have libevent support for cURL])
362 fi
363 ])
364 fi
365
366 dnl ----
367 dnl RAPHF
368 dnl ----
369 HTTP_HAVE_PHP_EXT([raphf], [
370 AC_MSG_CHECKING([for php_raphf.h])
371 HTTP_EXT_RAPHF_INCDIR=
372 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../raphf; do
373 if test -d $i; then
374 if test -f $i/php_raphf.h; then
375 HTTP_EXT_RAPHF_INCDIR=$i
376 break
377 elif test -f $i/ext/raphf/php_raphf.h; then
378 HTTP_EXT_RAPHF_INCDIR=$i/ext/raphf
379 break
380 fi
381 fi
382 done
383 if test "x$HTTP_EXT_RAPHF_INCDIR" = "x"; then
384 AC_MSG_ERROR([not found])
385 else
386 AC_MSG_RESULT([$HTTP_EXT_RAPHF_INCDIR])
387 AC_DEFINE([PHP_HTTP_HAVE_PHP_RAPHF_H], [1], [Have ext/raphf support])
388 PHP_ADD_INCLUDE([$HTTP_EXT_RAPHF_INCDIR])
389 fi
390 ])
391
392 dnl ----
393 dnl PROPRO
394 dnl ----
395 HTTP_HAVE_PHP_EXT([propro], [
396 AC_MSG_CHECKING([for php_propro.h])
397 HTTP_EXT_PROPRO_INCDIR=
398 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../propro; do
399 if test -d $i; then
400 if test -f $i/php_propro.h; then
401 HTTP_EXT_PROPRO_INCDIR=$i
402 break
403 elif test -f $i/ext/propro/php_propro.h; then
404 HTTP_EXT_PROPRO_INCDIR=$i/ext/propro
405 break
406 fi
407 fi
408 done
409 if test "x$HTTP_EXT_PROPRO_INCDIR" = "x"; then
410 AC_MSG_ERROR([not found])
411 else
412 AC_MSG_RESULT([$HTTP_EXT_PROPRO_INCDIR])
413 AC_DEFINE([PHP_HTTP_HAVE_PHP_PROPRO_H], [1], [Have ext/propro support])
414 PHP_ADD_INCLUDE([$HTTP_EXT_PROPRO_INCDIR])
415 fi
416 ])
417
418 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
419 [ --without-http-shared-deps HTTP: do not depend on extensions like hash
420 and iconv (when they are built shared)], $PHP_HTTP, $PHP_HTTP)
421 dnl ----
422 dnl HASH
423 dnl ----
424 HTTP_HAVE_PHP_EXT([hash], [
425 AC_MSG_CHECKING([for php_hash.h])
426 HTTP_EXT_HASH_INCDIR=
427 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
428 if test -d $i; then
429 if test -f $i/php_hash.h; then
430 HTTP_EXT_HASH_INCDIR=$i
431 break
432 elif test -f $i/ext/hash/php_hash.h; then
433 HTTP_EXT_HASH_INCDIR=$i/ext/hash
434 break
435 fi
436 fi
437 done
438 if test "x$HTTP_EXT_HASH_INCDIR" = "x"; then
439 AC_MSG_RESULT([not found])
440 else
441 AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
442 AC_DEFINE([PHP_HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
443 PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
444 fi
445 ])
446
447 dnl ----
448 dnl JSON
449 dnl ----
450 HTTP_HAVE_PHP_EXT([json])
451
452
453 dnl ----
454 dnl ICONV
455 dnl ----
456 HTTP_HAVE_PHP_EXT([iconv])
457
458 dnl ----
459 dnl DONE
460 dnl ----
461 PHP_HTTP_SOURCES="\
462 php_http_buffer.c \
463 php_http.c \
464 php_http_client.c \
465 php_http_curl_client.c \
466 php_http_client_datashare.c \
467 php_http_curl_client_datashare.c \
468 php_http_client_factory.c \
469 php_http_client_interface.c \
470 php_http_client_pool.c \
471 php_http_curl_client_pool.c \
472 php_http_client_request.c \
473 php_http_client_response.c \
474 php_http_cookie.c \
475 php_http_curl.c \
476 php_http_encoding.c \
477 php_http_env.c \
478 php_http_env_request.c \
479 php_http_env_response.c \
480 php_http_etag.c \
481 php_http_exception.c \
482 php_http_filter.c \
483 php_http_header_parser.c \
484 php_http_headers.c \
485 php_http_info.c \
486 php_http_message_body.c \
487 php_http_message.c \
488 php_http_message_parser.c \
489 php_http_misc.c \
490 php_http_negotiate.c \
491 php_http_object.c \
492 php_http_options.c \
493 php_http_params.c \
494 php_http_querystring.c \
495 php_http_strlist.c \
496 php_http_url.c \
497 php_http_version.c \
498 "
499 PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
500
501 dnl shared extension deps
502 HTTP_SHARED_DEP([hash])
503 HTTP_SHARED_DEP([iconv])
504 HTTP_SHARED_DEP([json])
505
506 PHP_SUBST([HTTP_SHARED_LIBADD])
507
508 PHP_HTTP_HEADERS="
509 php_http_api.h \
510 php_http_buffer.h \
511 php_http_curl_client.h \
512 php_http_curl_client_datashare.h \
513 php_http_client_datashare.h \
514 php_http_client_factory.h \
515 php_http_client.h \
516 php_http_client_interface.h \
517 php_http_curl_client_pool.h \
518 php_http_client_pool.h \
519 php_http_client_request.h \
520 php_http_client_response.h \
521 php_http_cookie.h \
522 php_http_curl.h \
523 php_http_encoding.h \
524 php_http_env.h \
525 php_http_env_request.h \
526 php_http_env_response.h \
527 php_http_etag.h \
528 php_http_exception.h \
529 php_http_filter.h \
530 php_http.h \
531 php_http_header_parser.h \
532 php_http_headers.h \
533 php_http_info.h \
534 php_http_message_body.h \
535 php_http_message.h \
536 php_http_message_parser.h \
537 php_http_misc.h \
538 php_http_negotiate.h \
539 php_http_object.h \
540 php_http_options.h \
541 php_http_params.h \
542 php_http_querystring.h \
543 php_http_strlist.h \
544 php_http_url.h \
545 php_http_version.h \
546 "
547 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
548
549 AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
550 fi
Extended HTTP Support