git.m6w6.name Git - m6w6/ext-http/blob - config9.m4

   1 dnl config.m4 for pecl/http
   2 dnl $Id$
   3 dnl vim: noet ts=1 sw=1
   4
   5 PHP_ARG_ENABLE([http], [whether to enable extended HTTP support],
   6 [  --enable-http           Enable extended HTTP support])
   7 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
   8 [  --with-http-shared-deps
   9                            HTTP: disable to not depend on extensions like hash,
  10                                  iconv and session (when built shared)], $PHP_HTTP, $PHP_HTTP)
  11 PHP_ARG_WITH([http-curl-requests], [whether to enable cURL HTTP request support],
  12 [  --with-http-curl-requests[=LIBCURLDIR]
  13                            HTTP: with cURL request support], $PHP_HTTP, $PHP_HTTP)
  14 PHP_ARG_WITH([http-curl-libevent], [whether to enable libevent support fur cURL],
  15 [  --with-http-curl-libevent[=LIBEVENTDIR]
  16                            HTTP: libevent install directory], $PHP_HTTP_CURL_REQUESTS, "")
  17 PHP_ARG_WITH([http-zlib-compression], [whether to enable zlib encodings support],
  18 [  --with-http-zlib-compression[=LIBZDIR]
  19                            HTTP: with zlib encodings support], $PHP_HTTP, $PHP_HTTP)
  20 PHP_ARG_WITH([http-magic-mime], [whether to enable response content type guessing],
  21 [  --with-http-magic-mime[=LIBMAGICDIR]
  22                            HTTP: with magic mime response content type guessing], "no", "no")
  23
  24 if test "$PHP_HTTP" != "no"; then
  25
  26         ifdef([AC_PROG_EGREP], [
  27                 AC_PROG_EGREP
  28         ], [
  29                 AC_CHECK_PROG(EGREP, egrep, egrep)
  30         ])
  31         ifdef([AC_PROG_SED], [
  32                 AC_PROG_SED
  33         ], [
  34                 ifdef([LT_AC_PROG_SED], [
  35                         LT_AC_PROG_SED
  36                 ], [
  37                         AC_CHECK_PROG(SED, sed, sed)
  38                 ])
  39         ])
  40
  41         AC_PROG_CPP
  42
  43         if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
  44                 AC_DEFINE([HTTP_SHARED_DEPS], [1], [ ])
  45         else
  46                 AC_DEFINE([HTTP_SHARED_DEPS], [0], [ ])
  47         fi
  48
  49         dnl
  50         dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
  51         dnl
  52         AC_DEFUN([HTTP_SHARED_DEP], [
  53                 extname=$1
  54                 haveext=$[HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
  55
  56                 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
  57                 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
  58                         AC_MSG_RESULT([no])
  59                         $3
  60                 elif test "$haveext"; then
  61                         AC_MSG_RESULT([yes])
  62                         ifdef([PHP_ADD_EXTENSION_DEP], [
  63                                 PHP_ADD_EXTENSION_DEP([http], $1, true)
  64                         ])
  65                         $2
  66                 else
  67                         AC_MSG_RESULT([no])
  68                         $3
  69                 fi
  70         ])
  71
  72         dnl
  73         dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
  74         dnl
  75         AC_DEFUN([HTTP_HAVE_PHP_EXT], [
  76                 extname=$1
  77                 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
  78                 ishared=$[PHP_]translit($1,a-z_-,A-Z__)_SHARED
  79
  80                 AC_MSG_CHECKING([for ext/$extname support])
  81                 if test -x "$PHP_EXECUTABLE"; then
  82                         if test "`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`" = "$extname"; then
  83                                 [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  84                                 AC_MSG_RESULT([yes])
  85                                 $2
  86                         else
  87                                 [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  88                                 AC_MSG_RESULT([no])
  89                                 $3
  90                         fi
  91                 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
  92                         [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  93                         AC_MSG_RESULT([yes])
  94                         $2
  95                 else
  96                         [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  97                         AC_MSG_RESULT([no])
  98                         $3
  99                 fi
 100         ])
 101
 102 dnl ----
 103 dnl STDC
 104 dnl ----
 105         AC_CHECK_HEADERS([netdb.h unistd.h])
 106         PHP_CHECK_FUNC(gethostname, nsl)
 107         PHP_CHECK_FUNC(getdomainname, nsl)
 108         PHP_CHECK_FUNC(getservbyport, nsl)
 109         PHP_CHECK_FUNC(getservbyname, nsl)
 110
 111 dnl ----
 112 dnl ZLIB
 113 dnl ----
 114         if test "$PHP_HTTP_ZLIB_COMPRESSION" != "no"; then
 115                 AC_MSG_CHECKING([for zlib.h])
 116                 ZLIB_DIR=
 117                 for i in "$PHP_HTTP_ZLIB_COMPRESSION" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
 118                         if test -f "$i/include/zlib.h"; then
 119                                 ZLIB_DIR=$i
 120                                 break;
 121                         fi
 122                 done
 123                 if test -z "$ZLIB_DIR"; then
 124                         AC_MSG_RESULT([not found])
 125                         AC_MSG_ERROR([could not find zlib.h])
 126                 else
 127                         AC_MSG_RESULT([found in $ZLIB_DIR])
 128                         AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
 129                         ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
 130                         AC_MSG_RESULT([$ZLIB_VERSION])
 131                         if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
 132                                 AC_MSG_ERROR([libz version greater or equal to 1.2.0.4 required])
 133                         else
 134                                 PHP_ADD_INCLUDE($ZLIB_DIR/include)
 135                                 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 136                                 AC_DEFINE([HTTP_HAVE_ZLIB], [1], [Have zlib support])
 137                         fi
 138                 fi
 139         fi
 140
 141 dnl ----
 142 dnl CURL
 143 dnl ----
 144         if test "$PHP_HTTP_CURL_REQUESTS" != "no"; then
 145                 AC_MSG_CHECKING([for curl/curl.h])
 146                 CURL_DIR=
 147                 for i in "$PHP_HTTP_CURL_REQUESTS" /usr/local /usr /opt; do
 148                         if test -f "$i/include/curl/curl.h"; then
 149                                 CURL_DIR=$i
 150                                 break
 151                         fi
 152                 done
 153                 if test -z "$CURL_DIR"; then
 154                         AC_MSG_RESULT([not found])
 155                         AC_MSG_ERROR([could not find curl/curl.h])
 156                 else
 157                         AC_MSG_RESULT([found in $CURL_DIR])
 158                 fi
 159
 160                 AC_MSG_CHECKING([for curl-config])
 161                 CURL_CONFIG=
 162                 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
 163                         if test -x "$i"; then
 164                                 CURL_CONFIG=$i
 165                                 break
 166                         fi
 167                 done
 168                 if test -z "$CURL_CONFIG"; then
 169                         AC_MSG_RESULT([not found])
 170                         AC_MSG_ERROR([could not find curl-config])
 171                 else
 172                         AC_MSG_RESULT([found: $CURL_CONFIG])
 173                 fi
 174
 175                 dnl Debian stable has currently 7.13.2 (this is not a typo)
 176                 AC_MSG_CHECKING([for curl version >= 7.12.3])
 177                 CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
 178                 AC_MSG_RESULT([$CURL_VERSION])
 179                 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71203; then
 180                         AC_MSG_ERROR([libcurl version greater or equal to 7.12.3 required])
 181                 fi
 182
 183                 dnl
 184                 dnl compile tests
 185                 dnl
 186
 187                 save_CFLAGS="$CFLAGS"
 188                 CFLAGS="`$CURL_CONFIG --cflags`"
 189                 save_LDFLAGS="$LDFLAGS"
 190                 LDFLAGS="`$CURL_CONFIG --libs` $ld_runpath_switch$CURL_DIR/$PHP_LIBDIR"
 191
 192                 AC_MSG_CHECKING([for SSL support in libcurl])
 193                 CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
 194                 if test "$CURL_SSL" = "SSL"; then
 195                         AC_MSG_RESULT([yes])
 196                         AC_DEFINE([HTTP_HAVE_SSL], [1], [ ])
 197
 198                         AC_MSG_CHECKING([for openssl support in libcurl])
 199                         AC_TRY_RUN([
 200                                 #include <curl/curl.h>
 201                                 int main(int argc, char *argv[]) {
 202                                         curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
 203                                         if (data && data->ssl_version && *data->ssl_version) {
 204                                                 const char *ptr = data->ssl_version;
 205                                                 while(*ptr == ' ') ++ptr;
 206                                                 return strncasecmp(ptr, "OpenSSL", sizeof("OpenSSL")-1);
 207                                         }
 208                                         return 1;
 209                                 }
 210                         ], [
 211                                 AC_MSG_RESULT([yes])
 212                                 AC_CHECK_HEADER([openssl/crypto.h], [
 213                                         AC_DEFINE([HTTP_HAVE_OPENSSL], [1], [ ])
 214                                 ])
 215                         ], [
 216                                 AC_MSG_RESULT([no])
 217                         ], [
 218                                 AC_MSG_RESULT([no])
 219                         ])
 220
 221                         AC_MSG_CHECKING([for gnutls support in libcurl])
 222                         AC_TRY_RUN([
 223                                 #include <curl/curl.h>
 224                                 int main(int argc, char *argv[]) {
 225                                         curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
 226                                         if (data && data->ssl_version && *data->ssl_version) {
 227                                                 const char *ptr = data->ssl_version;
 228                                                 while(*ptr == ' ') ++ptr;
 229                                                 return strncasecmp(ptr, "GnuTLS", sizeof("GnuTLS")-1);
 230                                         }
 231                                         return 1;
 232                                 }
 233                         ], [
 234                                 AC_MSG_RESULT([yes])
 235                                 AC_CHECK_HEADER([gcrypt.h], [
 236                                         AC_DEFINE([HTTP_HAVE_GNUTLS], [1], [ ])
 237                                 ])
 238                         ], [
 239                                 AC_MSG_RESULT([no])
 240                         ], [
 241                                 AC_MSG_RESULT([no])
 242                         ])
 243                 else
 244                         AC_MSG_RESULT([no])
 245                 fi
 246
 247                 CFLAGS="$save_CFLAGS"
 248                 LDFLAGS="$save_LDFLAGS"
 249
 250                 dnl end compile tests
 251
 252                 AC_MSG_CHECKING([for bundled SSL CA info])
 253                 CURL_CAINFO=
 254                 for i in `$CURL_CONFIG --ca` "/etc/ssl/certs/ca-certificates.crt"; do
 255                         if test -f "$i"; then
 256                                 CURL_CAINFO="$i"
 257                                 break
 258                         fi
 259                 done
 260                 if test -z "$CURL_CAINFO"; then
 261                         AC_MSG_RESULT([not found])
 262                 else
 263                         AC_MSG_RESULT([$CURL_CAINFO])
 264                         AC_DEFINE_UNQUOTED([HTTP_CURL_CAINFO], ["$CURL_CAINFO"], [path to bundled SSL CA info])
 265                 fi
 266
 267                 PHP_ADD_INCLUDE($CURL_DIR/include)
 268                 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 269                 PHP_EVAL_LIBLINE($CURL_LIBS, HTTP_SHARED_LIBADD)
 270                 AC_DEFINE([HTTP_HAVE_CURL], [1], [Have cURL support])
 271
 272                 PHP_CHECK_LIBRARY(curl, curl_share_strerror,
 273                         [AC_DEFINE([HAVE_CURL_SHARE_STRERROR], [1], [ ])], [ ],
 274                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 275                 )
 276                 PHP_CHECK_LIBRARY(curl, curl_multi_strerror,
 277                         [AC_DEFINE([HAVE_CURL_MULTI_STRERROR], [1], [ ])], [ ],
 278                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 279                 )
 280                 PHP_CHECK_LIBRARY(curl, curl_easy_strerror,
 281                         [AC_DEFINE([HAVE_CURL_EASY_STRERROR], [1], [ ])], [ ],
 282                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 283                 )
 284                 PHP_CHECK_LIBRARY(curl, curl_easy_reset,
 285                         [AC_DEFINE([HAVE_CURL_EASY_RESET], [1], [ ])], [ ],
 286                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 287                 )
 288                 PHP_CHECK_LIBRARY(curl, curl_formget,
 289                         [AC_DEFINE([HAVE_CURL_FORMGET], [1], [ ])], [ ],
 290                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 291                 )
 292                 PHP_CHECK_LIBRARY(curl, curl_multi_setopt,
 293                         [AC_DEFINE([HAVE_CURL_MULTI_SETOPT], [1], [ ])], [ ],
 294                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 295                 )
 296                 PHP_CHECK_LIBRARY(curl, curl_multi_timeout,
 297                         [AC_DEFINE([HAVE_CURL_MULTI_TIMEOUT], [1], [ ])], [ ],
 298                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 299                 )
 300
 301                 dnl ----
 302                 dnl EVENT
 303                 dnl ----
 304
 305                 if test "$PHP_HTTP_CURL_LIBEVENT" != "no"; then
 306                         AC_MSG_CHECKING([for event.h])
 307                         EVENT_DIR=
 308                         for i in "$PHP_HTTP_CURL_LIBEVENT" /usr/local /usr /opt; do
 309                                 if test -f "$i/include/event.h"; then
 310                                         EVENT_DIR=$i
 311                                         break
 312                                 fi
 313                         done
 314                         if test -z "$EVENT_DIR"; then
 315                                 AC_MSG_RESULT([not found])
 316                                 AC_MSG_WARN([continuing without libevent support])
 317                         else
 318                                 AC_MSG_RESULT([found in $EVENT_DIR])
 319
 320                                 AC_MSG_CHECKING([for libevent version, roughly])
 321                                 EVENT_VER="1.1b or lower"
 322                                 if test -f "$EVENT_DIR/include/evhttp.h" && test -f "$EVENT_DIR/include/evdns.h"; then
 323                                         if test -f "$EVENT_DIR/include/evrpc.h"; then
 324                                                 EVENT_VER="1.4 or greater"
 325                                         else
 326                                                 EVENT_VER="1.2 or greater"
 327                                         fi
 328                                 fi
 329                                 AC_DEFINE_UNQUOTED([HTTP_EVENT_VERSION], ["$EVENT_VER"], [ ])
 330                                 AC_MSG_RESULT([$EVENT_VER])
 331
 332                                 AC_MSG_CHECKING([for libcurl version >= 7.16.0])
 333                                 AC_MSG_RESULT([$CURL_VERSION])
 334                                 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71600; then
 335                                         AC_MSG_WARN([libcurl version greater or equal to 7.16.0 required; continuing without libevent support])
 336                                 else
 337                                         PHP_ADD_INCLUDE($EVENT_DIR/include)
 338                                         PHP_ADD_LIBRARY_WITH_PATH(event, $EVENT_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 339                                         AC_DEFINE([HTTP_HAVE_EVENT], [1], [Have libevent support for cURL])
 340                                         PHP_CHECK_LIBRARY(curl, curl_multi_socket_action,
 341                                                 [AC_DEFINE([HAVE_CURL_MULTI_SOCKET_ACTION], [1], [ ])], [ ],
 342                                                 [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 343                                         )
 344                                 fi
 345                         fi
 346                 fi
 347         fi
 348
 349 dnl ----
 350 dnl MAGIC
 351 dnl ----
 352         if test "$PHP_HTTP_MAGIC_MIME" != "no"; then
 353                 AC_MSG_CHECKING([for magic.h])
 354                 MAGIC_DIR=
 355                 for i in "$PHP_HTTP_MAGIC_MIME" /usr/local /usr /opt; do
 356                         if test -f "$i/include/magic.h"; then
 357                                 MAGIC_DIR=$i
 358                                 break
 359                         fi
 360                 done
 361                 if test -z "$MAGIC_DIR"; then
 362                         AC_MSG_RESULT([not found])
 363                         AC_MSG_ERROR([could not find magic.h])
 364                 else
 365                         AC_MSG_RESULT([found in $MAGIC_DIR])
 366                 fi
 367
 368                 PHP_ADD_INCLUDE($MAGIC_DIR/include)
 369                 PHP_ADD_LIBRARY_WITH_PATH(magic, $MAGIC_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 370                 AC_DEFINE([HTTP_HAVE_MAGIC], [1], [Have magic mime support])
 371         fi
 372
 373 dnl ----
 374 dnl HASH
 375 dnl ----
 376         HTTP_HAVE_PHP_EXT([hash], [
 377                 AC_MSG_CHECKING([for php_hash.h])
 378                 HTTP_EXT_HASH_INCDIR=
 379                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
 380                         if test -d $i; then
 381                                 if test -f $i/php_hash.h; then
 382                                         HTTP_EXT_HASH_INCDIR=$i
 383                                         break
 384                                 elif test -f $i/ext/hash/php_hash.h; then
 385                                         HTTP_EXT_HASH_INCDIR=$i/ext/hash
 386                                         break
 387                                 fi
 388                         fi
 389                 done
 390                 if test -z "$HTTP_EXT_HASH_INCDIR"; then
 391                         AC_MSG_RESULT([not found])
 392                 else
 393                         AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
 394                         AC_DEFINE([HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
 395                         PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
 396                 fi
 397         ])
 398
 399 dnl ----
 400 dnl ICONV
 401 dnl ----
 402         HTTP_HAVE_PHP_EXT([iconv])
 403
 404 dnl ----
 405 dnl SESSION
 406 dnl ----
 407         HTTP_HAVE_PHP_EXT([session])
 408
 409 dnl ----
 410 dnl DONE
 411 dnl ----
 412         PHP_HTTP_SOURCES="missing.c http.c http_functions.c phpstr/phpstr.c \
 413                 http_util_object.c http_message_object.c http_request_object.c http_request_pool_api.c \
 414                 http_response_object.c http_exception_object.c http_requestpool_object.c \
 415                 http_api.c http_cache_api.c http_request_api.c http_request_info.c http_date_api.c \
 416                 http_headers_api.c http_message_api.c http_send_api.c http_url_api.c \
 417                 http_info_api.c http_request_method_api.c http_encoding_api.c \
 418                 http_filter_api.c http_request_body_api.c http_querystring_object.c \
 419                 http_deflatestream_object.c http_inflatestream_object.c http_cookie_api.c \
 420                 http_querystring_api.c http_request_datashare_api.c http_requestdatashare_object.c \
 421                 http_persistent_handle_api.c"
 422
 423         PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
 424
 425         dnl shared extension deps
 426         HTTP_SHARED_DEP([hash])
 427         HTTP_SHARED_DEP([iconv])
 428         HTTP_SHARED_DEP([session])
 429
 430         PHP_ADD_BUILD_DIR($ext_builddir/phpstr, 1)
 431         PHP_SUBST([HTTP_SHARED_LIBADD])
 432
 433         PHP_HTTP_HEADERS="php_http_std_defs.h php_http.h php_http_api.h php_http_cache_api.h \
 434                 php_http_date_api.h php_http_headers_api.h php_http_info_api.h php_http_message_api.h \
 435                 php_http_request_api.h php_http_request_method_api.h php_http_send_api.h php_http_url_api.h \
 436                 php_http_encoding_api.h phpstr/phpstr.h missing.h php_http_request_body_api.h \
 437                 php_http_exception_object.h php_http_message_object.h php_http_request_object.h \
 438                 php_http_requestpool_object.h php_http_response_object.h php_http_util_object.h \
 439                 php_http_querystring_object.h php_http_deflatestream_object.h php_http_inflatestream_object.h \
 440                 php_http_cookie_api.h php_http_querystring_api.h php_http_request_datashare_api.h php_http_requestdatashare_object.h \
 441                 php_http_persistent_handle_api.h"
 442         ifdef([PHP_INSTALL_HEADERS], [
 443                 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
 444         ], [
 445                 PHP_SUBST([PHP_HTTP_HEADERS])
 446                 PHP_ADD_MAKEFILE_FRAGMENT
 447         ])
 448
 449         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 450 fi