git.m6w6.name Git - m6w6/ext-http/blob - config9.m4

   1
   2 m4_foreach(dir, [., ext/http], [
   3         sinclude(dir/autoconf/pecl/pecl.m4)
   4         sinclude(dir/autoconf/pecl/zlib.m4)
   5         sinclude(dir/autoconf/pecl/libcurl.m4)
   6         sinclude(dir/autoconf/pecl/libevent.m4)
   7 ])
   8
   9 PECL_INIT([http])
  10
  11 PHP_ARG_WITH([http], [whether to enable extended HTTP support],
  12 [  --with-http             Enable extended HTTP support])
  13 if test "$PHP_HTTP" != "no"; then
  14         dnl STDC
  15         AC_TYPE_OFF_T
  16         AC_TYPE_MBSTATE_T
  17         dnl getdomainname() is declared in netdb.h on some platforms: AIX, OSF
  18         AC_CHECK_HEADERS([netdb.h unistd.h wchar.h wctype.h arpa/inet.h])
  19         AC_CHECK_FUNC(gethostname,,[
  20                 AC_CHECK_LIB(nsl, gethostname)
  21         ])
  22         AC_CHECK_FUNC(getdomainname,,[
  23                 AC_CHECK_LIB(nsl, getdomainname)
  24         ])
  25         AC_CHECK_FUNCS(mbrtowc mbtowc iswalnum inet_pton)
  26
  27         dnl ZLIB
  28         PHP_ARG_WITH([http-zlib-dir], [whether/where to check for zlib],
  29         [  --with-http-zlib-dir[=DIR]         HTTP: where to find zlib], $PHP_HTTP, no)
  30         PECL_CHECK_ZLIB([$PHP_HTTP_ZLIB_DIR], [1.2.0.4])
  31         PECL_CHECK_DONE(zlib, $PECL_VAR([HAVE_ZLIB]))
  32
  33         dnl CURL
  34         PHP_ARG_WITH([http-libcurl-dir], [whether/where to check for libcurl],
  35         [  --with-http-libcurl-dir[=DIR]      HTTP: where to find libcurl], $PHP_HTTP, no)
  36         if test "$PHP_HTTP_LIBCURL_DIR" != "no"; then
  37                 PECL_CHECK_LIBCURL([$PHP_HTTP_LIBCURL_DIR], [7.18.2])
  38                 PECL_HAVE_LIBCURL_PROTOCOL([HTTP], [
  39                         PECL_HAVE_LIBCURL_FEATURE([HTTP2])
  40                         PECL_HAVE_LIBCURL_ARES
  41                         PECL_HAVE_LIBCURL_SSL
  42                         PECL_HAVE_LIBCURL_CA
  43                         PECL_DEFINE([HAVE_CLIENT])
  44                 ])
  45                 PECL_CHECK_DONE(libcurl, [$PECL_VAR([HAVE_LIBCURL_PROTOCOL_HTTP])])
  46         fi
  47
  48         dnl EVENT
  49         PHP_ARG_WITH([http-libevent-dir], [whether/where to check for libevent],
  50         [  --with-http-libevent-dir[=DIR]     HTTP: where to find libevent], $PHP_HTTP_LIBCURL_DIR, no)
  51         if test "$PHP_HTTP_LIBEVENT_DIR" != "no"; then
  52                 PECL_CHECK_LIBEVENT([$PHP_HTTP_LIBEVENT_DIR])
  53                 PECL_CHECK_DONE(libevent, [$PECL_VAR([HAVE_LIBEVENT])])
  54         fi
  55
  56         dnl GNU IDNA
  57         PHP_ARG_WITH([http-libidn2-dir], [whether/where to check for libidn2],
  58         [  --with-http-libidn2-dir[=DIR]      HTTP: where to find libidn2], $PHP_HTTP_LIBCURL_DIR, no)
  59         if test "$PHP_HTTP_LIBIDN2_DIR" != "no"; then
  60                 PECL_CHECK_CUSTOM(libidn2, "$PHP_HTTP_LIBIDN2_DIR", idn2.h, idn2,
  61                         [$($EGREP "define IDN2_VERSION " "include/idn2.h" | $SED -e's/^.*VERSION //g' -e 's/@<:@^0-9\.@:>@//g')])
  62                 if $PECL_VAR([HAVE_LIBIDN2]); then
  63                         PECL_DEFINE([HAVE_IDNA2008])
  64                 fi
  65                 PECL_CHECK_DONE(libidn2, $PECL_VAR([HAVE_LIBIDN2]))
  66         fi
  67         PHP_ARG_WITH([http-libidn-dir], [whether/where to check for libidn],
  68         [  --with-http-libidn-dir[=DIR]       HTTP: where to find libidn], $PHP_HTTP_LIBCURL_DIR, no)
  69         if test "$PHP_HTTP_LIBIDN_DIR" != "no"; then
  70                 PECL_CHECK_PKGCONFIG(libidn, [$PHP_HTTP_LIBIDN_DIR])
  71                 if $PECL_VAR([HAVE_LIBIDN]); then
  72                         PECL_DEFINE([HAVE_IDNA2003])
  73                 fi
  74                 PECL_CHECK_DONE(libidn, $PECL_VAR([HAVE_LIBIDN]))
  75         fi
  76
  77         dnl ICU IDNA
  78         PHP_ARG_WITH([http-libicu-dir], [whether/where to check for libicu],
  79         [  --with-http-libicu-dir[=DIR]       HTTP: where to find libicu], $PHP_HTTP_LIBCURL_DIR, no)
  80         if test "$PHP_HTTP_LIBICU_DIR" != "no"; then
  81                 AC_PATH_PROG(ICU_CONFIG, icu-config, false, [$PHP_HTTP_LIBICU_DIR/bin:$PATH:/usr/local/bin])
  82
  83                 PECL_CHECK_CONFIG(libicu, [$ICU_CONFIG], [--version], [--cppflags], [--ldflags-searchpath], [--ldflags-libsonly])
  84                 AC_CACHE_CHECK([for uidna_IDNToASCII], PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII]), [
  85                         if printf "%s" "$CFLAGS" | $EGREP -q "(^|\s)-Werror\b"; then
  86                                 if ! printf "%s" "$CFLAGS" | $EGREP -q "(^|\s)-Wno-error=deprecated-declarations\b"; then
  87                                         CFLAGS="$CFLAGS -Wno-error=deprecated-declarations"
  88                                 fi
  89                         fi
  90                         AC_TRY_LINK([
  91                                 #include <unicode/uidna.h>
  92                         ], [
  93                                 uidna_IDNToASCII(0, 0, 0, 0, 0, 0, 0);
  94                         ], [
  95                                 PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII])=yes
  96                         ], [
  97                                 PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII])=no
  98                         ])
  99                 ])
 100                 if $PECL_CACHE_VAR([HAVE_UIDNA_IDNTOASCII]); then
 101                         PECL_DEFINE([HAVE_IDNA2003])
 102                         PECL_DEFINE_FN([UIDNA_IDNTOASCII])
 103                 fi
 104
 105                 AC_CACHE_CHECK([for uidna_nameToASCII_UTF8], PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8]), [
 106                         AC_TRY_LINK([
 107                                 #include <unicode/uidna.h>
 108                         ], [
 109                                 uidna_nameToASCII_UTF8(0, 0, 0, 0, 0, 0, 0);
 110                         ], [
 111                                 PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8])=yes
 112                         ], [
 113                                 PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8])=no
 114                         ])
 115                 ])
 116                 if $PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8]); then
 117                         PECL_DEFINE([HAVE_IDNA2008])
 118                         PECL_DEFINE_FN([uidna_nameToASCII_UTF8])
 119                 fi
 120                 PECL_CHECK_DONE(libicu, [$PECL_VAR([HAVE_LIBICU])])
 121         fi
 122
 123         dnl IDNKIT2
 124         PHP_ARG_WITH([http-libidnkit2-dir], [whether/where to check for libidnkit2],
 125         [  --with-http-libidnkit2-dir[=DIR]   HTTP: where to find libidnkit2], $PHP_HTTP_LIBCURL_DIR, no)
 126         if test "$PHP_HTTP_LIBIDNKIT2_DIR" != "no"; then
 127                 PECL_CHECK_CUSTOM(libidnkit2, "$PHP_HTTP_LIBIDNKIT2_DIR", idn/api.h, idnkit,
 128                         [$($EGREP "define IDNKIT_VERSION_LIBIDN\b" "include/idn/version.h" | $SED -e's/^.*VERSION_LIBIDN//g' -e 's/@<:@^0-9\.@:>@//g')])
 129                 if $PECL_VAR([HAVE_LIBIDNKIT2]); then
 130                         PECL_DEFINE([HAVE_IDNA2008])
 131                 fi
 132                 PECL_CHECK_DONE(libidnkit2, [$PECL_VAR([HAVE_LIBIDNKIT2])])
 133         fi
 134         dnl IDNKIT1
 135         PHP_ARG_WITH([http-libidnkit-dir], [whether/where to check for libidnkit],
 136         [  --with-http-libidnkit-dir[=DIR]    HTTP: where to find libidnkit], $PHP_HTTP_LIBCURL_DIR, no)
 137         if test "$PHP_HTTP_LIBIDNKIT_DIR" != "no"; then
 138                 # libidnkit1 and libidnkit2 have the same API
 139                 if test "$PHP_HTTP_LIBIDNKIT2_DIR" != no && $PECL_VAR([HAVE_LIBIDNKIT2]); then
 140                         AC_MSG_WARN([libidnkit-$PECL_VAR([LIBIDNKIT2_VERSION]) already enabled, skipping libidnkit1])
 141                 else
 142                         PECL_CHECK_CUSTOM(libidnkit, "$PHP_HTTP_LIBIDNKIT_DIR", idn/api.h, idnkit,
 143                                 [$($EGREP "define IDNKIT_VERSION\b" "include/idn/version.h" | $SED -e's/^.*VERSION//g' -e 's/@<:@^0-9\.@:>@//g')])
 144                         if $PECL_VAR([HAVE_LIBIDNKIT]); then
 145                                 PECL_DEFINE([HAVE_IDNA2003])
 146                         fi
 147                         PECL_CHECK_DONE(libidnkit, [$PECL_VAR([HAVE_LIBIDNKIT])])
 148                 fi
 149         fi
 150
 151         dnl EXTENSIONS
 152         PECL_HAVE_PHP_EXT([raphf], [
 153                 PECL_HAVE_PHP_EXT_HEADER([raphf])
 154         ], [
 155                 AC_MSG_ERROR([please install and enable pecl/raphf])
 156         ])
 157         PECL_HAVE_PHP_EXT([propro], [
 158                 PECL_HAVE_PHP_EXT_HEADER([propro])
 159         ], [
 160                 AC_MSG_ERROR([please install and enable pecl/propro])
 161         ])
 162         PECL_HAVE_PHP_EXT([hash])
 163         PECL_HAVE_PHP_EXT([iconv])
 164
 165         dnl DONE
 166         PHP_SUBST([HTTP_SHARED_LIBADD])
 167
 168         PECL_VAR([SRCDIR])=PHP_EXT_SRCDIR(http)
 169         PECL_VAR([BUILDDIR])=PHP_EXT_BUILDDIR(http)
 170
 171         PHP_ADD_INCLUDE([$PECL_VAR([SRCDIR])/src])
 172         PHP_ADD_BUILD_DIR([$PECL_VAR([BUILDDIR])/src])
 173
 174         PECL_VAR([HEADERS])=$(cd $PECL_VAR([SRCDIR])/src && echo *.h)
 175         PECL_VAR([SOURCES])=$(cd $PECL_VAR([SRCDIR]) && echo src/*.c)
 176
 177         PHP_NEW_EXTENSION(http, [$PECL_VAR([SOURCES])], [$ext_shared])
 178         PHP_INSTALL_HEADERS(ext/http, [php_http.h $PECL_VAR([HEADERS])])
 179
 180         PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
 181         [  --without-http-shared-deps       HTTP: do not depend on extensions like hash
 182                                          and iconv (when they are built shared)], yes, no)
 183         if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
 184                 if $PECL_VAR([HAVE_EXT_HASH]); then
 185                         PHP_ADD_EXTENSION_DEP([http], [hash], true)
 186                 fi
 187                 if $PECL_VAR([HAVE_EXT_ICONV]); then
 188                         PHP_ADD_EXTENSION_DEP([http], [iconv], true)
 189                 fi
 190         fi
 191         PHP_ADD_EXTENSION_DEP([http], [raphf], true)
 192         PHP_ADD_EXTENSION_DEP([http], [propro], true)
 193
 194         PHP_SUBST(PECL_VAR([HEADERS]))
 195         PHP_SUBST(PECL_VAR([SOURCES]))
 196
 197         PHP_SUBST(PECL_VAR([SRCDIR]))
 198         PHP_SUBST(PECL_VAR([BUILDDIR]))
 199
 200         PHP_ADD_MAKEFILE_FRAGMENT
 201
 202         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 203 fi