git.m6w6.name Git - m6w6/ext-http/blob - config9.m4

   1 dnl config.m4 for pecl/http
   2 dnl $Id: config9.m4 242664 2007-09-18 19:13:37Z mike $
   3 dnl vim: noet ts=4 sw=4
   4
   5 PHP_ARG_WITH([http], [whether to enable extended HTTP support],
   6 [  --with-http             Enable extended HTTP support])
   7 PHP_ARG_WITH([http-zlib-dir], [],
   8 [  --with-http-zlib-dir[=DIR]     HTTP: where to find zlib], $PHP_HTTP, $PHP_HTTP)
   9 PHP_ARG_WITH([http-libcurl-dir], [],
  10 [  --with-http-libcurl-dir[=DIR]  HTTP: where to find libcurl], $PHP_HTTP, $PHP_HTTP)
  11 PHP_ARG_WITH([http-libevent-dir], [],
  12 [  --with-http-libevent-dir[=DIR] HTTP: where to find libevent], $PHP_HTTP_LIBCURL_DIR, "")
  13
  14 if test "$PHP_HTTP" != "no"; then
  15
  16         HTTP_HAVE_A_REQUEST_LIB=false
  17
  18         ifdef([AC_PROG_EGREP], [
  19                 AC_PROG_EGREP
  20         ], [
  21                 AC_CHECK_PROG(EGREP, egrep, egrep)
  22         ])
  23         ifdef([AC_PROG_SED], [
  24                 AC_PROG_SED
  25         ], [
  26                 ifdef([LT_AC_PROG_SED], [
  27                         LT_AC_PROG_SED
  28                 ], [
  29                         AC_CHECK_PROG(SED, sed, sed)
  30                 ])
  31         ])
  32
  33         AC_PROG_CPP
  34
  35         if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
  36                 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [1], [ ])
  37         else
  38                 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [0], [ ])
  39         fi
  40
  41         dnl
  42         dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
  43         dnl
  44         AC_DEFUN([HTTP_SHARED_DEP], [
  45                 extname=$1
  46                 haveext=$[PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
  47
  48                 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
  49                 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
  50                         AC_MSG_RESULT([no])
  51                         $3
  52                 elif test "$haveext"; then
  53                         AC_MSG_RESULT([yes])
  54                         AC_DEFINE([PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__), [1], [ ])
  55                         ifdef([PHP_ADD_EXTENSION_DEP], [
  56                                 PHP_ADD_EXTENSION_DEP([http], $1, true)
  57                         ])
  58                         $2
  59                 else
  60                         AC_MSG_RESULT([no])
  61                         $3
  62                 fi
  63         ])
  64
  65         dnl
  66         dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
  67         dnl
  68         AC_DEFUN([HTTP_HAVE_PHP_EXT], [
  69                 extname=$1
  70                 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
  71
  72                 AC_MSG_CHECKING([for ext/$extname support])
  73                 if test -x "$PHP_EXECUTABLE"; then
  74                         grepext=`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`
  75                         if test "$grepext" = "$extname"; then
  76                                 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  77                                 AC_MSG_RESULT([yes])
  78                                 $2
  79                         else
  80                                 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  81                                 AC_MSG_RESULT([no])
  82                                 $3
  83                         fi
  84                 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
  85                         [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  86                         AC_MSG_RESULT([yes])
  87                         $2
  88                 else
  89                         [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  90                         AC_MSG_RESULT([no])
  91                         $3
  92                 fi
  93         ])
  94
  95
  96 dnl ----
  97 dnl STDC
  98 dnl ----
  99         AC_CHECK_HEADERS([netdb.h unistd.h])
 100         PHP_CHECK_FUNC(gethostname, nsl)
 101         PHP_CHECK_FUNC(getdomainname, nsl)
 102         PHP_CHECK_FUNC(getservbyport, nsl)
 103         PHP_CHECK_FUNC(getservbyport_r, nsl)
 104         PHP_CHECK_FUNC(getservbyname, nsl)
 105         PHP_CHECK_FUNC(getservbyname_r, nsl)
 106
 107 dnl ----
 108 dnl ZLIB
 109 dnl ----
 110         AC_MSG_CHECKING([for zlib.h])
 111         ZLIB_DIR=
 112         for i in "$PHP_HTTP_ZLIB_DIR" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
 113                 if test -f "$i/include/zlib.h"; then
 114                         ZLIB_DIR=$i
 115                         break;
 116                 fi
 117         done
 118         if test "x$ZLIB_DIR" = "x"; then
 119                 AC_MSG_RESULT([not found])
 120                 AC_MSG_ERROR([could not find zlib.h])
 121         else
 122                 AC_MSG_RESULT([found in $ZLIB_DIR])
 123                 AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
 124                 ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
 125                 AC_MSG_RESULT([$ZLIB_VERSION])
 126                 if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
 127                         AC_MSG_ERROR([zlib version greater or equal to 1.2.0.4 required])
 128                 else
 129                         PHP_ADD_INCLUDE($ZLIB_DIR/include)
 130                         PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 131                 fi
 132         fi
 133
 134 dnl ----
 135 dnl CURL
 136 dnl ----
 137
 138         if test "$PHP_HTTP_LIBCURL_DIR" = "no"; then
 139                 AC_DEFINE([PHP_HTTP_HAVE_CURL], [0], [ ])
 140         else
 141                 AC_MSG_CHECKING([for curl/curl.h])
 142                 CURL_DIR=
 143                 for i in "$PHP_HTTP_LIBCURL_DIR" /usr/local /usr /opt; do
 144                         if test -f "$i/include/curl/curl.h"; then
 145                                 CURL_DIR=$i
 146                                 break
 147                         fi
 148                 done
 149                 if test "x$CURL_DIR" = "x"; then
 150                         AC_MSG_RESULT([not found])
 151                 else
 152                         AC_MSG_RESULT([found in $CURL_DIR])
 153
 154                         AC_MSG_CHECKING([for curl-config])
 155                         CURL_CONFIG=
 156                         for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
 157                                 if test -x "$i"; then
 158                                         CURL_CONFIG=$i
 159                                         break
 160                                 fi
 161                         done
 162                         if test "x$CURL_CONFIG" = "x"; then
 163                                 AC_MSG_RESULT([not found])
 164                                 AC_MSG_ERROR([could not find curl-config])
 165                         else
 166                                 AC_MSG_RESULT([found: $CURL_CONFIG])
 167                         fi
 168
 169                         dnl RHEL6:         7.19.7
 170                         dnl SUSE11:        7.19.7
 171                         dnl Debian wheezy: 7.26.0
 172                         dnl Debian sqeeze: 7.21.0
 173                         dnl Debian ancient 7.18.2
 174                         AC_MSG_CHECKING([for curl version >= 7.18.2])
 175                         CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
 176                         AC_MSG_RESULT([$CURL_VERSION])
 177                         if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71802; then
 178                                 AC_MSG_ERROR([libcurl version greater or equal to 7.18.2 required])
 179                         fi
 180
 181                         dnl
 182                         dnl compile tests
 183                         dnl
 184
 185                         save_INCLUDES="$INCLUDES"
 186                         INCLUDES=
 187                         save_LIBS="$LIBS"
 188                         LIBS=
 189                         save_CFLAGS="$CFLAGS"
 190                         CFLAGS="$CFLAGS `$CURL_CONFIG --cflags`"
 191                         save_LDFLAGS="$LDFLAGS"
 192                         LDFLAGS="$LDFLAGS `$CURL_CONFIG --libs` $ld_runpath_switch$CURL_DIR/$PHP_LIBDIR"
 193
 194                         AC_MSG_CHECKING([for SSL support in libcurl])
 195                         CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
 196                         if test "$CURL_SSL" = "SSL"; then
 197                                 AC_MSG_RESULT([yes])
 198                                 AC_DEFINE([PHP_HTTP_HAVE_SSL], [1], [ ])
 199
 200                                 AC_MSG_CHECKING([for openssl support in libcurl])
 201                                 AC_TRY_RUN([
 202                                         #include <curl/curl.h>
 203                                         int main(int argc, char *argv[]) {
 204                                                 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
 205                                                 if (data && data->ssl_version && *data->ssl_version) {
 206                                                         const char *ptr = data->ssl_version;
 207                                                         while(*ptr == ' ') ++ptr;
 208                                                         return strncasecmp(ptr, "OpenSSL", sizeof("OpenSSL")-1);
 209                                                 }
 210                                                 return 1;
 211                                         }
 212                                 ], [
 213                                         AC_MSG_RESULT([yes])
 214                                         AC_CHECK_HEADER([openssl/crypto.h], [
 215                                                 AC_DEFINE([PHP_HTTP_HAVE_OPENSSL], [1], [ ])
 216                                                 CURL_SSL="crypto"
 217                                         ])
 218                                 ], [
 219                                         AC_MSG_RESULT([no])
 220                                 ], [
 221                                         AC_MSG_RESULT([no])
 222                                 ])
 223
 224                                 AC_MSG_CHECKING([for gnutls support in libcurl])
 225                                 AC_TRY_RUN([
 226                                         #include <curl/curl.h>
 227                                         int main(int argc, char *argv[]) {
 228                                                 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
 229                                                 if (data && data->ssl_version && *data->ssl_version) {
 230                                                         const char *ptr = data->ssl_version;
 231                                                         while(*ptr == ' ') ++ptr;
 232                                                         return strncasecmp(ptr, "GnuTLS", sizeof("GnuTLS")-1);
 233                                                 }
 234                                                 return 1;
 235                                         }
 236                                 ], [
 237                                         AC_MSG_RESULT([yes])
 238                                         AC_CHECK_HEADER([gcrypt.h], [
 239                                                 AC_DEFINE([PHP_HTTP_HAVE_GNUTLS], [1], [ ])
 240                                                 CURL_SSL="gcrypt"
 241                                         ])
 242                                 ], [
 243                                         AC_MSG_RESULT([no])
 244                                 ], [
 245                                         AC_MSG_RESULT([no])
 246                                 ])
 247                         else
 248                                 AC_MSG_RESULT([no])
 249                         fi
 250
 251                         INCLUDES="$save_INCLUDES"
 252                         LIBS="$save_LIBS"
 253                         CFLAGS="$save_CFLAGS"
 254                         LDFLAGS="$save_LDFLAGS"
 255
 256                         dnl end compile tests
 257
 258                         AC_MSG_CHECKING([for bundled SSL CA info])
 259                         CURL_CAINFO=
 260                         for i in `$CURL_CONFIG --ca` "/etc/ssl/certs/ca-certificates.crt"; do
 261                                 if test -f "$i"; then
 262                                         CURL_CAINFO="$i"
 263                                         break
 264                                 fi
 265                         done
 266                         if test "x$CURL_CAINFO" = "x"; then
 267                                 AC_MSG_RESULT([not found])
 268                         else
 269                                 AC_MSG_RESULT([$CURL_CAINFO])
 270                                 AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAINFO], ["$CURL_CAINFO"], [path to bundled SSL CA info])
 271                         fi
 272
 273                         PHP_ADD_INCLUDE($CURL_DIR/include)
 274                         PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 275                         PHP_EVAL_LIBLINE(`$CURL_CONFIG --libs`, HTTP_SHARED_LIBADD)
 276                         if test "x$CURL_SSL" != "x"; then
 277                                 PHP_ADD_LIBRARY_WITH_PATH([$CURL_SSL], $CURL_DIR/$PHP_LIBDIR, PHP_HTTP_SHARED_LIBADD)
 278                         fi
 279                         AC_DEFINE([PHP_HTTP_HAVE_CURL], [1], [Have libcurl support])
 280                         HTTP_HAVE_A_REQUEST_LIB=true
 281                 fi
 282         fi
 283
 284 dnl ----
 285 dnl EVENT
 286 dnl ----
 287
 288         if test "$PHP_HTTP_LIBEVENT_DIR" = "no"; then
 289                 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
 290         else
 291                 AC_MSG_CHECKING([for event2/event.h])
 292                 EVENT_DIR=
 293                 for i in "$PHP_HTTP_LIBEVENT_DIR" /usr/local /usr /opt; do
 294                         if test -f "$i/include/event.h"; then
 295                                 EVENT_DIR=$i
 296                                 break
 297                         fi
 298                 done
 299                 if test "x$EVENT_DIR" = "x"; then
 300                         AC_MSG_RESULT([not found])
 301                         AC_MSG_WARN([continuing without libevent support])
 302                         AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
 303                 else
 304                         AC_MSG_RESULT([found in $EVENT_DIR])
 305
 306                         AC_MSG_CHECKING([for libevent version, roughly])
 307
 308                         if test -f "$EVENT_DIR/include/event2/event.h"; then
 309                                 EVENT_VER="`$EGREP _EVENT_VERSION $EVENT_DIR/include/event2/event-config.h | $AWK '{print $3}'`"
 310                                 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [1], [ ])
 311                         else
 312                                 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [0], [ ])
 313                                 if test -f "$EVENT_DIR/include/evhttp.h" && test -f "$EVENT_DIR/include/evdns.h"; then
 314                                         if test -f "$EVENT_DIR/include/evrpc.h"; then
 315                                                 EVENT_VER="1.4 or greater"
 316                                         else
 317                                                 EVENT_VER="1.2 or greater"
 318                                         fi
 319                                 else
 320                                         EVENT_VER="1.1b or lower"
 321                                 fi
 322                         fi
 323                         AC_DEFINE_UNQUOTED([PHP_HTTP_EVENT_VERSION], ["$EVENT_VER"], [ ])
 324                         AC_MSG_RESULT([$EVENT_VER])
 325
 326                         PHP_ADD_INCLUDE($EVENT_DIR/include)
 327                         PHP_ADD_LIBRARY_WITH_PATH(event, $EVENT_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 328                         AC_DEFINE([PHP_HTTP_HAVE_EVENT], [1], [Have libevent support for cURL])
 329                 fi
 330         fi
 331
 332 dnl ----
 333 dnl RAPHF
 334 dnl ----
 335         HTTP_HAVE_PHP_EXT([raphf], [
 336                 AC_MSG_CHECKING([for php_raphf.h])
 337                 HTTP_EXT_RAPHF_INCDIR=
 338                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../raphf; do
 339                         if test -d $i; then
 340                                 if test -f $i/php_raphf.h; then
 341                                         HTTP_EXT_RAPHF_INCDIR=$i
 342                                         break
 343                                 elif test -f $i/ext/raphf/php_raphf.h; then
 344                                         HTTP_EXT_RAPHF_INCDIR=$i/ext/raphf
 345                                         break
 346                                 fi
 347                         fi
 348                 done
 349                 if test "x$HTTP_EXT_RAPHF_INCDIR" = "x"; then
 350                         AC_MSG_ERROR([not found])
 351                 else
 352                         AC_MSG_RESULT([$HTTP_EXT_RAPHF_INCDIR])
 353                         AC_DEFINE([PHP_HTTP_HAVE_PHP_RAPHF_H], [1], [Have ext/raphf support])
 354                         PHP_ADD_INCLUDE([$HTTP_EXT_RAPHF_INCDIR])
 355                 fi
 356         ])
 357
 358 dnl ----
 359 dnl PROPRO
 360 dnl ----
 361         HTTP_HAVE_PHP_EXT([propro], [
 362                 AC_MSG_CHECKING([for php_propro.h])
 363                 HTTP_EXT_PROPRO_INCDIR=
 364                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../propro; do
 365                         if test -d $i; then
 366                                 if test -f $i/php_propro.h; then
 367                                         HTTP_EXT_PROPRO_INCDIR=$i
 368                                         break
 369                                 elif test -f $i/ext/propro/php_propro.h; then
 370                                         HTTP_EXT_PROPRO_INCDIR=$i/ext/propro
 371                                         break
 372                                 fi
 373                         fi
 374                 done
 375                 if test "x$HTTP_EXT_PROPRO_INCDIR" = "x"; then
 376                         AC_MSG_ERROR([not found])
 377                 else
 378                         AC_MSG_RESULT([$HTTP_EXT_PROPRO_INCDIR])
 379                         AC_DEFINE([PHP_HTTP_HAVE_PHP_PROPRO_H], [1], [Have ext/propro support])
 380                         PHP_ADD_INCLUDE([$HTTP_EXT_PROPRO_INCDIR])
 381                 fi
 382         ])
 383
 384 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
 385 [  --without-http-shared-deps   HTTP: do not depend on extensions like hash
 386                                      and iconv (when they are built shared)], $PHP_HTTP, $PHP_HTTP)
 387 dnl ----
 388 dnl HASH
 389 dnl ----
 390         HTTP_HAVE_PHP_EXT([hash], [
 391                 AC_MSG_CHECKING([for php_hash.h])
 392                 HTTP_EXT_HASH_INCDIR=
 393                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
 394                         if test -d $i; then
 395                                 if test -f $i/php_hash.h; then
 396                                         HTTP_EXT_HASH_INCDIR=$i
 397                                         break
 398                                 elif test -f $i/ext/hash/php_hash.h; then
 399                                         HTTP_EXT_HASH_INCDIR=$i/ext/hash
 400                                         break
 401                                 fi
 402                         fi
 403                 done
 404                 if test "x$HTTP_EXT_HASH_INCDIR" = "x"; then
 405                         AC_MSG_RESULT([not found])
 406                 else
 407                         AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
 408                         AC_DEFINE([PHP_HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
 409                         PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
 410                 fi
 411         ])
 412
 413 dnl ----
 414 dnl JSON
 415 dnl ----
 416         HTTP_HAVE_PHP_EXT([json])
 417
 418
 419 dnl ----
 420 dnl ICONV
 421 dnl ----
 422         HTTP_HAVE_PHP_EXT([iconv])
 423
 424 dnl ----
 425 dnl DONE
 426 dnl ----
 427         PHP_HTTP_SOURCES="\
 428                 php_http_buffer.c \
 429                 php_http.c \
 430                 php_http_client.c \
 431                 php_http_client_curl.c \
 432                 php_http_client_request.c \
 433                 php_http_client_response.c \
 434                 php_http_cookie.c \
 435                 php_http_curl.c \
 436                 php_http_encoding.c \
 437                 php_http_env.c \
 438                 php_http_env_request.c \
 439                 php_http_env_response.c \
 440                 php_http_etag.c \
 441                 php_http_exception.c \
 442                 php_http_filter.c \
 443                 php_http_header_parser.c \
 444                 php_http_header.c \
 445                 php_http_info.c \
 446                 php_http_message_body.c \
 447                 php_http_message.c \
 448                 php_http_message_parser.c \
 449                 php_http_misc.c \
 450                 php_http_negotiate.c \
 451                 php_http_object.c \
 452                 php_http_options.c \
 453                 php_http_params.c \
 454                 php_http_querystring.c \
 455                 php_http_strlist.c \
 456                 php_http_url.c \
 457                 php_http_version.c \
 458         "
 459         PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
 460
 461         dnl shared extension deps
 462         HTTP_SHARED_DEP([hash])
 463         HTTP_SHARED_DEP([iconv])
 464         HTTP_SHARED_DEP([json])
 465
 466         dnl extension deps
 467         PHP_ADD_EXTENSION_DEP([http], [raphf], true)
 468         PHP_ADD_EXTENSION_DEP([http], [propo], true)
 469
 470         PHP_SUBST([HTTP_SHARED_LIBADD])
 471
 472         PHP_HTTP_HEADERS="
 473                 php_http_api.h \
 474                 php_http_buffer.h \
 475                 php_http_curl_client.h \
 476                 php_http_curl_client_datashare.h \
 477                 php_http_client_datashare.h \
 478                 php_http_client_factory.h \
 479                 php_http_client.h \
 480                 php_http_client_interface.h \
 481                 php_http_curl_client_pool.h \
 482                 php_http_client_pool.h \
 483                 php_http_client_request.h \
 484                 php_http_client_response.h \
 485                 php_http_cookie.h \
 486                 php_http_curl.h \
 487                 php_http_encoding.h \
 488                 php_http_env.h \
 489                 php_http_env_request.h \
 490                 php_http_env_response.h \
 491                 php_http_etag.h \
 492                 php_http_exception.h \
 493                 php_http_filter.h \
 494                 php_http.h \
 495                 php_http_header_parser.h \
 496                 php_http_header.h \
 497                 php_http_info.h \
 498                 php_http_message_body.h \
 499                 php_http_message.h \
 500                 php_http_message_parser.h \
 501                 php_http_misc.h \
 502                 php_http_negotiate.h \
 503                 php_http_object.h \
 504                 php_http_options.h \
 505                 php_http_params.h \
 506                 php_http_querystring.h \
 507                 php_http_strlist.h \
 508                 php_http_url.h \
 509                 php_http_version.h \
 510         "
 511         PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
 512
 513         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 514 fi