git.m6w6.name Git - m6w6/ext-http/blob - config9.m4

   1 dnl config.m4 for pecl/http
   2 dnl $Id$
   3 dnl vim: noet ts=1 sw=1
   4
   5 PHP_ARG_ENABLE([http], [whether to enable extended HTTP support],
   6 [  --enable-http           Enable extended HTTP support])
   7 PHP_ARG_WITH([http-curl-requests], [whether to enable cURL HTTP request support],
   8 [  --with-http-curl-requests[=LIBCURLDIR]
   9                            HTTP: with cURL request support], $PHP_HTTP, $PHP_HTTP)
  10 PHP_ARG_WITH([http-zlib-compression], [whether to enable zlib encodings support],
  11 [  --with-http-zlib-compression[=LIBZDIR]
  12                            HTTP: with zlib encodings support], $PHP_HTTP, $PHP_HTTP)
  13 PHP_ARG_WITH([http-magic-mime], [whether to enable response content type guessing],
  14 [  --with-http-magic-mime[=LIBMAGICDIR]
  15                            HTTP: with magic mime response content type guessing], "no", "no")
  16 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
  17 [  --with-http-shared-deps  HTTP: disable to not depend on extensions like hash,
  18                                  iconv and session (when built shared)], $PHP_HTTP, $PHP_HTTP)
  19
  20 if test "$PHP_HTTP" != "no"; then
  21
  22         ifdef([AC_PROG_EGREP], [
  23                 AC_PROG_EGREP
  24         ], [
  25                 AC_CHECK_PROG(EGREP, egrep, egrep)
  26         ])
  27         ifdef([AC_PROG_SED], [
  28                 AC_PROG_SED
  29         ], [
  30                 ifdef([LT_AC_PROG_SED], [
  31                         LT_AC_PROG_SED
  32                 ], [
  33                         AC_CHECK_PROG(SED, sed, sed)
  34                 ])
  35         ])
  36
  37         if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
  38                 AC_DEFINE([HTTP_SHARED_DEPS], [1], [ ])
  39         else
  40                 AC_DEFINE([HTTP_SHARED_DEPS], [0], [ ])
  41         fi
  42
  43         dnl
  44         dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
  45         dnl
  46         AC_DEFUN([HTTP_SHARED_DEP], [
  47                 extname=$1
  48                 haveext=$[HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
  49
  50                 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
  51                 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
  52                         AC_MSG_RESULT([no])
  53                         $3
  54                 elif test "$haveext"; then
  55                         AC_MSG_RESULT([yes])
  56                         ifdef([PHP_ADD_EXTENSION_DEP], [
  57                                 PHP_ADD_EXTENSION_DEP([http], $1, true)
  58                         ])
  59                         $2
  60                 else
  61                         AC_MSG_RESULT([no])
  62                         $3
  63                 fi
  64         ])
  65
  66         dnl
  67         dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
  68         dnl
  69         AC_DEFUN([HTTP_HAVE_PHP_EXT], [
  70                 extname=$1
  71                 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
  72                 ishared=$[PHP_]translit($1,a-z_-,A-Z__)_SHARED
  73
  74                 AC_MSG_CHECKING([for ext/$extname support])
  75                 if test -x "$PHP_EXECUTABLE"; then
  76                         if test "`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`" = "$extname"; then
  77                                 [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  78                                 AC_MSG_RESULT([yes])
  79                                 $2
  80                         else
  81                                 [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  82                                 AC_MSG_RESULT([no])
  83                                 $3
  84                         fi
  85                 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
  86                         [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  87                         AC_MSG_RESULT([yes])
  88                         $2
  89                 else
  90                         [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  91                         AC_MSG_RESULT([no])
  92                         $3
  93                 fi
  94         ])
  95
  96 dnl ----
  97 dnl STDC
  98 dnl ----
  99         AC_CHECK_HEADERS([netdb.h unistd.h])
 100         PHP_CHECK_FUNC(gethostname, nsl)
 101         PHP_CHECK_FUNC(getdomainname, nsl)
 102         PHP_CHECK_FUNC(getservbyport, nsl)
 103         PHP_CHECK_FUNC(getservbyname, nsl)
 104
 105 dnl ----
 106 dnl ZLIB
 107 dnl ----
 108         if test "$PHP_HTTP_ZLIB_COMPRESSION" != "no"; then
 109                 AC_MSG_CHECKING([for zlib.h])
 110                 ZLIB_DIR=
 111                 for i in "$PHP_HTTP_ZLIB_COMPRESSION" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
 112                         if test -f "$i/include/zlib.h"; then
 113                                 ZLIB_DIR=$i
 114                                 break;
 115                         fi
 116                 done
 117                 if test -z "$ZLIB_DIR"; then
 118                         AC_MSG_RESULT([not found])
 119                         AC_MSG_ERROR([could not find zlib.h])
 120                 else
 121                         AC_MSG_RESULT([found in $ZLIB_DIR])
 122                         AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
 123                         ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
 124                         AC_MSG_RESULT([$ZLIB_VERSION])
 125                         if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
 126                                 AC_MSG_ERROR([libz version greater or equal to 1.2.0.4 required])
 127                         else
 128                                 PHP_ADD_INCLUDE($ZLIB_DIR/include)
 129                                 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 130                                 AC_DEFINE([HTTP_HAVE_ZLIB], [1], [Have zlib support])
 131                         fi
 132                 fi
 133         fi
 134
 135 dnl ----
 136 dnl CURL
 137 dnl ----
 138         if test "$PHP_HTTP_CURL_REQUESTS" != "no"; then
 139                 AC_MSG_CHECKING([for curl/curl.h])
 140                 CURL_DIR=
 141                 for i in "$PHP_HTTP_CURL_REQUESTS" /usr/local /usr /opt; do
 142                         if test -f "$i/include/curl/curl.h"; then
 143                                 CURL_DIR=$i
 144                                 break
 145                         fi
 146                 done
 147                 if test -z "$CURL_DIR"; then
 148                         AC_MSG_RESULT([not found])
 149                         AC_MSG_ERROR([could not find curl/curl.h])
 150                 else
 151                         AC_MSG_RESULT([found in $CURL_DIR])
 152                 fi
 153
 154                 AC_MSG_CHECKING([for curl-config])
 155                 CURL_CONFIG=
 156                 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
 157                         if test -x "$i"; then
 158                                 CURL_CONFIG=$i
 159                                 break
 160                         fi
 161                 done
 162                 if test -z "$CURL_CONFIG"; then
 163                         AC_MSG_RESULT([not found])
 164                         AC_MSG_ERROR([could not find curl-config])
 165                 else
 166                         AC_MSG_RESULT([found: $CURL_CONFIG])
 167                 fi
 168
 169                 dnl Debian stable has currently 7.13.2 (this is not a typo)
 170                 AC_MSG_CHECKING([for curl version >= 7.12.3])
 171                 CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
 172                 AC_MSG_RESULT([$CURL_VERSION])
 173                 if test `echo $CURL_VERSION | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71203; then
 174                         AC_MSG_ERROR([libcurl version greater or equal to 7.12.3 required])
 175                 fi
 176
 177                 CURL_LIBS=`$CURL_CONFIG --libs`
 178
 179                 AC_MSG_CHECKING([for SSL support in libcurl])
 180                 CURL_SSL=`$CURL_CONFIG --features | $EGREP SSL`
 181                 if test "$CURL_SSL" = "SSL"; then
 182                         AC_MSG_RESULT([yes])
 183                         AC_DEFINE([HTTP_HAVE_SSL], [1], [ ])
 184
 185                         AC_MSG_CHECKING([for SSL library used])
 186                         CURL_SSL_FLAVOUR=
 187                         for i in $CURL_LIBS; do
 188                                 case $i in
 189                                         -lssl* | -lyassl*)
 190                                                 CURL_SSL_FLAVOUR="openssl"
 191                                                 AC_MSG_RESULT([openssl])
 192                                                 AC_DEFINE([HTTP_HAVE_OPENSSL], [1], [ ])
 193                                                 AC_CHECK_HEADERS([openssl/crypto.h])
 194                                                 break
 195                                         ;;
 196                                         -lgnutls*)
 197                                                 CURL_SSL_FLAVOUR="gnutls"
 198                                                 AC_MSG_RESULT([gnutls])
 199                                                 AC_DEFINE([HTTP_HAVE_GNUTLS], [1], [ ])
 200                                                 AC_CHECK_HEADERS([gcrypt.h])
 201                                                 break
 202                                         ;;
 203                                 esac
 204                         done
 205                         if test -z "$CURL_SSL_FLAVOUR"; then
 206                                 AC_MSG_RESULT([unknown!])
 207                                 AC_MSG_WARN([Could not determine the type of SSL library used!])
 208                                 AC_MSG_WARN([Building will fail in ZTS mode!])
 209                         fi
 210                 else
 211                         AC_MSG_RESULT([no])
 212                 fi
 213
 214                 PHP_ADD_INCLUDE($CURL_DIR/include)
 215                 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 216                 PHP_EVAL_LIBLINE($CURL_LIBS, HTTP_SHARED_LIBADD)
 217                 AC_DEFINE([HTTP_HAVE_CURL], [1], [Have cURL support])
 218
 219                 PHP_CHECK_LIBRARY(curl, curl_multi_strerror,
 220                         [AC_DEFINE([HAVE_CURL_MULTI_STRERROR], [1], [ ])], [ ],
 221                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 222                 )
 223                 PHP_CHECK_LIBRARY(curl, curl_easy_strerror,
 224                         [AC_DEFINE([HAVE_CURL_EASY_STRERROR], [1], [ ])], [ ],
 225                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 226                 )
 227                 PHP_CHECK_LIBRARY(curl, curl_easy_reset,
 228                         [AC_DEFINE([HAVE_CURL_EASY_RESET], [1], [ ])], [ ],
 229                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 230                 )
 231                 dnl Debian suddenly (>=7.14.1-2) hides all symbols not starting with "curl"
 232                 PHP_CHECK_LIBRARY(curl, Curl_getFormData,
 233                         [AC_DEFINE([HAVE_CURL_GETFORMDATA], [1], [ ])], [ ],
 234                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 235                 )
 236                 dnl New API function which obsoletes use of Curl_getFormData (>=7.15.5)
 237                 PHP_CHECK_LIBRARY(curl, curl_formget,
 238                         [AC_DEFINE([HAVE_CURL_FORMGET], [1], [ ])], [ ],
 239                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 240                 )
 241                 PHP_CHECK_LIBRARY(curl, curl_multi_setopt,
 242                         [AC_DEFINE([HAVE_CURL_MULTI_SETOPT], [1], [ ])], [ ],
 243                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 244                 )
 245                 PHP_CHECK_LIBRARY(curl, curl_multi_timeout,
 246                         [AC_DEFINE([HAVE_CURL_MULTI_TIMEOUT], [1], [ ])], [ ],
 247                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 248                 )
 249         fi
 250
 251 dnl ----
 252 dnl MAGIC
 253 dnl ----
 254         if test "$PHP_HTTP_MAGIC_MIME" != "no"; then
 255                 AC_MSG_CHECKING([for magic.h])
 256                 MAGIC_DIR=
 257                 for i in "$PHP_HTTP_MAGIC_MIME" /usr/local /usr /opt; do
 258                         if test -f "$i/include/magic.h"; then
 259                                 MAGIC_DIR=$i
 260                                 break
 261                         fi
 262                 done
 263                 if test -z "$MAGIC_DIR"; then
 264                         AC_MSG_RESULT([not found])
 265                         AC_MSG_ERROR([could not find magic.h])
 266                 else
 267                         AC_MSG_RESULT([found in $MAGIC_DIR])
 268                 fi
 269
 270                 PHP_ADD_INCLUDE($MAGIC_DIR/include)
 271                 PHP_ADD_LIBRARY_WITH_PATH(magic, $MAGIC_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 272                 AC_DEFINE([HTTP_HAVE_MAGIC], [1], [Have magic mime support])
 273         fi
 274
 275 dnl ----
 276 dnl HASH
 277 dnl ----
 278         HTTP_HAVE_PHP_EXT([hash], [
 279                 AC_MSG_CHECKING([for php_hash.h])
 280                 HTTP_EXT_HASH_INCDIR=
 281                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
 282                         if test -d $i; then
 283                                 if test -f $i/php_hash.h; then
 284                                         HTTP_EXT_HASH_INCDIR=$i
 285                                         break
 286                                 elif test -f $i/ext/hash/php_hash.h; then
 287                                         HTTP_EXT_HASH_INCDIR=$i/ext/hash
 288                                         break
 289                                 fi
 290                         fi
 291                 done
 292                 if test -z "$HTTP_EXT_HASH_INCDIR"; then
 293                         AC_MSG_RESULT([not found])
 294                 else
 295                         AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
 296                         AC_DEFINE([HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
 297                         PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
 298                 fi
 299         ])
 300
 301 dnl ----
 302 dnl ICONV
 303 dnl ----
 304         HTTP_HAVE_PHP_EXT([iconv])
 305
 306 dnl ----
 307 dnl SESSION
 308 dnl ----
 309         HTTP_HAVE_PHP_EXT([session])
 310
 311 dnl ----
 312 dnl DONE
 313 dnl ----
 314         PHP_HTTP_SOURCES="missing.c http.c http_functions.c phpstr/phpstr.c \
 315                 http_util_object.c http_message_object.c http_request_object.c http_request_pool_api.c \
 316                 http_response_object.c http_exception_object.c http_requestpool_object.c \
 317                 http_api.c http_cache_api.c http_request_api.c http_date_api.c \
 318                 http_headers_api.c http_message_api.c http_send_api.c http_url_api.c \
 319                 http_info_api.c http_request_method_api.c http_encoding_api.c \
 320                 http_filter_api.c http_request_body_api.c http_querystring_object.c \
 321                 http_deflatestream_object.c http_inflatestream_object.c http_cookie_api.c \
 322                 http_querystring_api.c"
 323
 324         PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
 325
 326         dnl shared extension deps
 327         HTTP_SHARED_DEP([hash])
 328         HTTP_SHARED_DEP([iconv])
 329         HTTP_SHARED_DEP([session])
 330
 331         PHP_ADD_BUILD_DIR($ext_builddir/phpstr, 1)
 332         PHP_SUBST([HTTP_SHARED_LIBADD])
 333
 334         PHP_HTTP_HEADERS="php_http_std_defs.h php_http.h php_http_api.h php_http_cache_api.h \
 335                 php_http_date_api.h php_http_headers_api.h php_http_info_api.h php_http_message_api.h \
 336                 php_http_request_api.h php_http_request_method_api.h php_http_send_api.h php_http_url_api.h \
 337                 php_http_encoding_api.h phpstr/phpstr.h missing.h php_http_request_body_api.h \
 338                 php_http_exception_object.h php_http_message_object.h php_http_request_object.h \
 339                 php_http_requestpool_object.h php_http_response_object.h php_http_util_object.h \
 340                 php_http_querystring_object.h php_http_deflatestream_object.h php_http_inflatestream_object.h \
 341                 php_http_cookie_api.h php_http_querystring_api.h"
 342         ifdef([PHP_INSTALL_HEADERS], [
 343                 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
 344         ], [
 345                 PHP_SUBST([PHP_HTTP_HEADERS])
 346                 PHP_ADD_MAKEFILE_FRAGMENT
 347         ])
 348
 349         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 350 fi