git.m6w6.name Git - m6w6/ext-http/blob - config9.m4

   1 dnl config.m4 for pecl/http
   2 dnl $Id$
   3 dnl vim: noet ts=1 sw=1
   4
   5 PHP_ARG_ENABLE([http], [whether to enable extended HTTP support],
   6 [  --enable-http           Enable extended HTTP support])
   7 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
   8 [  --with-http-shared-deps
   9                            HTTP: disable to not depend on extensions like hash,
  10                                  iconv and session (when built shared)], $PHP_HTTP, $PHP_HTTP)
  11 PHP_ARG_WITH([http-curl-requests], [whether to enable cURL HTTP request support],
  12 [  --with-http-curl-requests[=LIBCURLDIR]
  13                            HTTP: with cURL request support], $PHP_HTTP, $PHP_HTTP)
  14 PHP_ARG_WITH([http-curl-libevent], [whether to enable libevent support fur cURL],
  15 [  --with-http-curl-libevent[=LIBEVENTDIR]
  16                            HTTP: libevent install directory], $PHP_HTTP_CURL_REQUESTS, "")
  17 PHP_ARG_WITH([http-zlib-compression], [whether to enable zlib encodings support],
  18 [  --with-http-zlib-compression[=LIBZDIR]
  19                            HTTP: with zlib encodings support], $PHP_HTTP, $PHP_HTTP)
  20 PHP_ARG_WITH([http-magic-mime], [whether to enable response content type guessing],
  21 [  --with-http-magic-mime[=LIBMAGICDIR]
  22                            HTTP: with magic mime response content type guessing], "no", "no")
  23
  24 if test "$PHP_HTTP" != "no"; then
  25
  26         ifdef([AC_PROG_EGREP], [
  27                 AC_PROG_EGREP
  28         ], [
  29                 AC_CHECK_PROG(EGREP, egrep, egrep)
  30         ])
  31         ifdef([AC_PROG_SED], [
  32                 AC_PROG_SED
  33         ], [
  34                 ifdef([LT_AC_PROG_SED], [
  35                         LT_AC_PROG_SED
  36                 ], [
  37                         AC_CHECK_PROG(SED, sed, sed)
  38                 ])
  39         ])
  40
  41         if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
  42                 AC_DEFINE([HTTP_SHARED_DEPS], [1], [ ])
  43         else
  44                 AC_DEFINE([HTTP_SHARED_DEPS], [0], [ ])
  45         fi
  46
  47         dnl
  48         dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
  49         dnl
  50         AC_DEFUN([HTTP_SHARED_DEP], [
  51                 extname=$1
  52                 haveext=$[HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
  53
  54                 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
  55                 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
  56                         AC_MSG_RESULT([no])
  57                         $3
  58                 elif test "$haveext"; then
  59                         AC_MSG_RESULT([yes])
  60                         ifdef([PHP_ADD_EXTENSION_DEP], [
  61                                 PHP_ADD_EXTENSION_DEP([http], $1, true)
  62                         ])
  63                         $2
  64                 else
  65                         AC_MSG_RESULT([no])
  66                         $3
  67                 fi
  68         ])
  69
  70         dnl
  71         dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
  72         dnl
  73         AC_DEFUN([HTTP_HAVE_PHP_EXT], [
  74                 extname=$1
  75                 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
  76                 ishared=$[PHP_]translit($1,a-z_-,A-Z__)_SHARED
  77
  78                 AC_MSG_CHECKING([for ext/$extname support])
  79                 if test -x "$PHP_EXECUTABLE"; then
  80                         if test "`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`" = "$extname"; then
  81                                 [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  82                                 AC_MSG_RESULT([yes])
  83                                 $2
  84                         else
  85                                 [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  86                                 AC_MSG_RESULT([no])
  87                                 $3
  88                         fi
  89                 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
  90                         [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  91                         AC_MSG_RESULT([yes])
  92                         $2
  93                 else
  94                         [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  95                         AC_MSG_RESULT([no])
  96                         $3
  97                 fi
  98         ])
  99
 100 dnl ----
 101 dnl STDC
 102 dnl ----
 103         AC_CHECK_HEADERS([netdb.h unistd.h])
 104         PHP_CHECK_FUNC(gethostname, nsl)
 105         PHP_CHECK_FUNC(getdomainname, nsl)
 106         PHP_CHECK_FUNC(getservbyport, nsl)
 107         PHP_CHECK_FUNC(getservbyname, nsl)
 108
 109 dnl ----
 110 dnl ZLIB
 111 dnl ----
 112         if test "$PHP_HTTP_ZLIB_COMPRESSION" != "no"; then
 113                 AC_MSG_CHECKING([for zlib.h])
 114                 ZLIB_DIR=
 115                 for i in "$PHP_HTTP_ZLIB_COMPRESSION" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
 116                         if test -f "$i/include/zlib.h"; then
 117                                 ZLIB_DIR=$i
 118                                 break;
 119                         fi
 120                 done
 121                 if test -z "$ZLIB_DIR"; then
 122                         AC_MSG_RESULT([not found])
 123                         AC_MSG_ERROR([could not find zlib.h])
 124                 else
 125                         AC_MSG_RESULT([found in $ZLIB_DIR])
 126                         AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
 127                         ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
 128                         AC_MSG_RESULT([$ZLIB_VERSION])
 129                         if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
 130                                 AC_MSG_ERROR([libz version greater or equal to 1.2.0.4 required])
 131                         else
 132                                 PHP_ADD_INCLUDE($ZLIB_DIR/include)
 133                                 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 134                                 AC_DEFINE([HTTP_HAVE_ZLIB], [1], [Have zlib support])
 135                         fi
 136                 fi
 137         fi
 138
 139 dnl ----
 140 dnl CURL
 141 dnl ----
 142         if test "$PHP_HTTP_CURL_REQUESTS" != "no"; then
 143                 AC_MSG_CHECKING([for curl/curl.h])
 144                 CURL_DIR=
 145                 for i in "$PHP_HTTP_CURL_REQUESTS" /usr/local /usr /opt; do
 146                         if test -f "$i/include/curl/curl.h"; then
 147                                 CURL_DIR=$i
 148                                 break
 149                         fi
 150                 done
 151                 if test -z "$CURL_DIR"; then
 152                         AC_MSG_RESULT([not found])
 153                         AC_MSG_ERROR([could not find curl/curl.h])
 154                 else
 155                         AC_MSG_RESULT([found in $CURL_DIR])
 156                 fi
 157
 158                 AC_MSG_CHECKING([for curl-config])
 159                 CURL_CONFIG=
 160                 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
 161                         if test -x "$i"; then
 162                                 CURL_CONFIG=$i
 163                                 break
 164                         fi
 165                 done
 166                 if test -z "$CURL_CONFIG"; then
 167                         AC_MSG_RESULT([not found])
 168                         AC_MSG_ERROR([could not find curl-config])
 169                 else
 170                         AC_MSG_RESULT([found: $CURL_CONFIG])
 171                 fi
 172
 173                 dnl Debian stable has currently 7.13.2 (this is not a typo)
 174                 AC_MSG_CHECKING([for curl version >= 7.12.3])
 175                 CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
 176                 AC_MSG_RESULT([$CURL_VERSION])
 177                 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71203; then
 178                         AC_MSG_ERROR([libcurl version greater or equal to 7.12.3 required])
 179                 fi
 180
 181                 CURL_LIBS=`$CURL_CONFIG --libs`
 182
 183                 AC_MSG_CHECKING([for SSL support in libcurl])
 184                 CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
 185                 if test "$CURL_SSL" = "SSL"; then
 186                         AC_MSG_RESULT([yes])
 187                         AC_DEFINE([HTTP_HAVE_SSL], [1], [ ])
 188
 189                         AC_MSG_CHECKING([for SSL library used])
 190                         CURL_SSL_FLAVOUR=
 191                         for i in $CURL_LIBS; do
 192                                 case $i in
 193                                         -lssl* | -lyassl*)
 194                                                 CURL_SSL_FLAVOUR="openssl"
 195                                                 AC_MSG_RESULT([openssl])
 196                                                 AC_DEFINE([HTTP_HAVE_OPENSSL], [1], [ ])
 197                                                 AC_CHECK_HEADERS([openssl/crypto.h])
 198                                                 break
 199                                         ;;
 200                                         -lgnutls*)
 201                                                 CURL_SSL_FLAVOUR="gnutls"
 202                                                 AC_MSG_RESULT([gnutls])
 203                                                 AC_DEFINE([HTTP_HAVE_GNUTLS], [1], [ ])
 204                                                 AC_CHECK_HEADERS([gcrypt.h])
 205                                                 break
 206                                         ;;
 207                                 esac
 208                         done
 209                         if test -z "$CURL_SSL_FLAVOUR"; then
 210                                 AC_MSG_RESULT([unknown!])
 211                                 AC_MSG_WARN([Could not determine the type of SSL library used!])
 212                                 AC_MSG_WARN([Building will fail in ZTS mode!])
 213                         fi
 214                 else
 215                         AC_MSG_RESULT([no])
 216                 fi
 217
 218                 AC_MSG_CHECKING([for bundled SSL CA info])
 219                 CURL_CAINFO=
 220                 for i in `$CURL_CONFIG --ca` "/etc/ssl/certs/ca-certificates.crt"; do
 221                         if test -f "$i"; then
 222                                 CURL_CAINFO="$i"
 223                                 break
 224                         fi
 225                 done
 226                 if test -z "$CURL_CAINFO"; then
 227                         AC_MSG_RESULT([not found])
 228                 else
 229                         AC_MSG_RESULT([$CURL_CAINFO])
 230                         AC_DEFINE_UNQUOTED([HTTP_CURL_CAINFO], ["$CURL_CAINFO"], [path to bundled SSL CA info])
 231                 fi
 232
 233                 PHP_ADD_INCLUDE($CURL_DIR/include)
 234                 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 235                 PHP_EVAL_LIBLINE($CURL_LIBS, HTTP_SHARED_LIBADD)
 236                 AC_DEFINE([HTTP_HAVE_CURL], [1], [Have cURL support])
 237
 238                 PHP_CHECK_LIBRARY(curl, curl_share_strerror,
 239                         [AC_DEFINE([HAVE_CURL_SHARE_STRERROR], [1], [ ])], [ ],
 240                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 241                 )
 242                 PHP_CHECK_LIBRARY(curl, curl_multi_strerror,
 243                         [AC_DEFINE([HAVE_CURL_MULTI_STRERROR], [1], [ ])], [ ],
 244                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 245                 )
 246                 PHP_CHECK_LIBRARY(curl, curl_easy_strerror,
 247                         [AC_DEFINE([HAVE_CURL_EASY_STRERROR], [1], [ ])], [ ],
 248                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 249                 )
 250                 PHP_CHECK_LIBRARY(curl, curl_easy_reset,
 251                         [AC_DEFINE([HAVE_CURL_EASY_RESET], [1], [ ])], [ ],
 252                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 253                 )
 254                 dnl Debian suddenly (>=7.14.1-2) hides all symbols not starting with "curl"
 255                 PHP_CHECK_LIBRARY(curl, Curl_getFormData,
 256                         [AC_DEFINE([HAVE_CURL_GETFORMDATA], [1], [ ])], [ ],
 257                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 258                 )
 259                 dnl New API function which obsoletes use of Curl_getFormData (>=7.15.5)
 260                 PHP_CHECK_LIBRARY(curl, curl_formget,
 261                         [AC_DEFINE([HAVE_CURL_FORMGET], [1], [ ])], [ ],
 262                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 263                 )
 264                 PHP_CHECK_LIBRARY(curl, curl_multi_setopt,
 265                         [AC_DEFINE([HAVE_CURL_MULTI_SETOPT], [1], [ ])], [ ],
 266                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 267                 )
 268                 PHP_CHECK_LIBRARY(curl, curl_multi_timeout,
 269                         [AC_DEFINE([HAVE_CURL_MULTI_TIMEOUT], [1], [ ])], [ ],
 270                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 271                 )
 272
 273                 dnl ----
 274                 dnl EVENT
 275                 dnl ----
 276
 277                 if test "$PHP_HTTP_CURL_LIBEVENT" != "no"; then
 278                         AC_MSG_CHECKING([for event.h])
 279                         EVENT_DIR=
 280                         for i in "$PHP_HTTP_CURL_LIBEVENT" /usr/local /usr /opt; do
 281                                 if test -f "$i/include/event.h"; then
 282                                         EVENT_DIR=$i
 283                                         break
 284                                 fi
 285                         done
 286                         if test -z "$EVENT_DIR"; then
 287                                 AC_MSG_RESULT([not found])
 288                                 AC_MSG_WARN([continuing without libevent support])
 289                         else
 290                                 AC_MSG_RESULT([found in $EVENT_DIR])
 291
 292                                 AC_MSG_CHECKING([for libevent version, roughly])
 293                                 EVENT_VER="1.1b or lower"
 294                                 if test -f "$EVENT_DIR/include/evhttp.h" && test -f "$EVENT_DIR/include/evdns.h"; then
 295                                         if test -f "$EVENT_DIR/include/evrpc.h"; then
 296                                                 EVENT_VER="1.4 or greater"
 297                                         else
 298                                                 EVENT_VER="1.2 or greater"
 299                                         fi
 300                                 fi
 301                                 AC_DEFINE_UNQUOTED([HTTP_EVENT_VERSION], ["$EVENT_VER"], [ ])
 302                                 AC_MSG_RESULT([$EVENT_VER])
 303
 304                                 AC_MSG_CHECKING([for libcurl version >= 7.16.0])
 305                                 AC_MSG_RESULT([$CURL_VERSION])
 306                                 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71600; then
 307                                         AC_MSG_WARN([libcurl version greater or equal to 7.16.0 required; continuing without libevent support])
 308                                 else
 309                                         PHP_ADD_INCLUDE($EVENT_DIR/include)
 310                                         PHP_ADD_LIBRARY_WITH_PATH(event, $EVENT_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 311                                         AC_DEFINE([HTTP_HAVE_EVENT], [1], [Have libevent support for cURL])
 312                                         PHP_CHECK_LIBRARY(curl, curl_multi_socket_action,
 313                                                 [AC_DEFINE([HAVE_CURL_MULTI_SOCKET_ACTION], [1], [ ])], [ ],
 314                                                 [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 315                                         )
 316                                 fi
 317                         fi
 318                 fi
 319         fi
 320
 321 dnl ----
 322 dnl MAGIC
 323 dnl ----
 324         if test "$PHP_HTTP_MAGIC_MIME" != "no"; then
 325                 AC_MSG_CHECKING([for magic.h])
 326                 MAGIC_DIR=
 327                 for i in "$PHP_HTTP_MAGIC_MIME" /usr/local /usr /opt; do
 328                         if test -f "$i/include/magic.h"; then
 329                                 MAGIC_DIR=$i
 330                                 break
 331                         fi
 332                 done
 333                 if test -z "$MAGIC_DIR"; then
 334                         AC_MSG_RESULT([not found])
 335                         AC_MSG_ERROR([could not find magic.h])
 336                 else
 337                         AC_MSG_RESULT([found in $MAGIC_DIR])
 338                 fi
 339
 340                 PHP_ADD_INCLUDE($MAGIC_DIR/include)
 341                 PHP_ADD_LIBRARY_WITH_PATH(magic, $MAGIC_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 342                 AC_DEFINE([HTTP_HAVE_MAGIC], [1], [Have magic mime support])
 343         fi
 344
 345 dnl ----
 346 dnl HASH
 347 dnl ----
 348         HTTP_HAVE_PHP_EXT([hash], [
 349                 AC_MSG_CHECKING([for php_hash.h])
 350                 HTTP_EXT_HASH_INCDIR=
 351                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
 352                         if test -d $i; then
 353                                 if test -f $i/php_hash.h; then
 354                                         HTTP_EXT_HASH_INCDIR=$i
 355                                         break
 356                                 elif test -f $i/ext/hash/php_hash.h; then
 357                                         HTTP_EXT_HASH_INCDIR=$i/ext/hash
 358                                         break
 359                                 fi
 360                         fi
 361                 done
 362                 if test -z "$HTTP_EXT_HASH_INCDIR"; then
 363                         AC_MSG_RESULT([not found])
 364                 else
 365                         AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
 366                         AC_DEFINE([HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
 367                         PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
 368                 fi
 369         ])
 370
 371 dnl ----
 372 dnl ICONV
 373 dnl ----
 374         HTTP_HAVE_PHP_EXT([iconv])
 375
 376 dnl ----
 377 dnl SESSION
 378 dnl ----
 379         HTTP_HAVE_PHP_EXT([session])
 380
 381 dnl ----
 382 dnl DONE
 383 dnl ----
 384         PHP_HTTP_SOURCES="missing.c http.c http_functions.c phpstr/phpstr.c \
 385                 http_util_object.c http_message_object.c http_request_object.c http_request_pool_api.c \
 386                 http_response_object.c http_exception_object.c http_requestpool_object.c \
 387                 http_api.c http_cache_api.c http_request_api.c http_request_info.c http_date_api.c \
 388                 http_headers_api.c http_message_api.c http_send_api.c http_url_api.c \
 389                 http_info_api.c http_request_method_api.c http_encoding_api.c \
 390                 http_filter_api.c http_request_body_api.c http_querystring_object.c \
 391                 http_deflatestream_object.c http_inflatestream_object.c http_cookie_api.c \
 392                 http_querystring_api.c http_request_datashare_api.c http_requestdatashare_object.c \
 393                 http_persistent_handle_api.c"
 394
 395         PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
 396
 397         dnl shared extension deps
 398         HTTP_SHARED_DEP([hash])
 399         HTTP_SHARED_DEP([iconv])
 400         HTTP_SHARED_DEP([session])
 401
 402         PHP_ADD_BUILD_DIR($ext_builddir/phpstr, 1)
 403         PHP_SUBST([HTTP_SHARED_LIBADD])
 404
 405         PHP_HTTP_HEADERS="php_http_std_defs.h php_http.h php_http_api.h php_http_cache_api.h \
 406                 php_http_date_api.h php_http_headers_api.h php_http_info_api.h php_http_message_api.h \
 407                 php_http_request_api.h php_http_request_method_api.h php_http_send_api.h php_http_url_api.h \
 408                 php_http_encoding_api.h phpstr/phpstr.h missing.h php_http_request_body_api.h \
 409                 php_http_exception_object.h php_http_message_object.h php_http_request_object.h \
 410                 php_http_requestpool_object.h php_http_response_object.h php_http_util_object.h \
 411                 php_http_querystring_object.h php_http_deflatestream_object.h php_http_inflatestream_object.h \
 412                 php_http_cookie_api.h php_http_querystring_api.h php_http_request_datashare_api.h php_http_requestdatashare_object.h \
 413                 php_http_persistent_handle_api.h"
 414         ifdef([PHP_INSTALL_HEADERS], [
 415                 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
 416         ], [
 417                 PHP_SUBST([PHP_HTTP_HEADERS])
 418                 PHP_ADD_MAKEFILE_FRAGMENT
 419         ])
 420
 421         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 422 fi