git.m6w6.name Git - m6w6/ext-http/blob - config9.m4

   1
   2 m4_foreach(dir, [., ext/http], [
   3         sinclude(dir/autoconf/pecl/pecl.m4)
   4         sinclude(dir/autoconf/pecl/zlib.m4)
   5         sinclude(dir/autoconf/pecl/libbrotli.m4)
   6         sinclude(dir/autoconf/pecl/libcurl.m4)
   7         sinclude(dir/autoconf/pecl/libevent.m4)
   8 ])
   9
  10 PECL_INIT([http])
  11
  12 PHP_ARG_WITH([http], [whether to enable extended HTTP support],
  13 [  --with-http             Enable extended HTTP support])
  14 if test "$PHP_HTTP" != "no"; then
  15         dnl STDC
  16         AC_TYPE_OFF_T
  17         AC_TYPE_MBSTATE_T
  18         dnl getdomainname() is declared in netdb.h on some platforms: AIX, OSF
  19         AC_CHECK_HEADERS([netdb.h unistd.h wchar.h wctype.h arpa/inet.h])
  20         AC_CHECK_FUNC(gethostname,,[
  21                 AC_CHECK_LIB(nsl, gethostname)
  22         ])
  23         AC_CHECK_FUNC(getdomainname,,[
  24                 AC_CHECK_LIB(nsl, getdomainname)
  25         ])
  26         AC_CHECK_FUNCS(mbrtowc mbtowc iswalnum inet_pton)
  27
  28         CFLAGS="$CFLAGS -Wno-strict-prototypes"
  29
  30         dnl ZLIB
  31         PHP_ARG_WITH([http-zlib-dir], [whether/where to check for zlib],
  32         [  --with-http-zlib-dir[=DIR]         HTTP: where to find zlib], $PHP_HTTP)
  33         PECL_CHECK_ZLIB([$PHP_HTTP_ZLIB_DIR], [1.2.0.4])
  34         PECL_CHECK_DONE(zlib, $PECL_VAR([HAVE_ZLIB]))
  35
  36         dnl BROTLI
  37         PHP_ARG_WITH([http-libbrotli-dir], [whether/where to check for libbrotli],
  38         [  --with-http-libbrotli-dir[=DIR]    HTTP: where to find libbrotli], $PHP_HTTP)
  39         PECL_CHECK_LIBBROTLI([$PHP_HTTP_LIBBROTLI_DIR], [1.0])
  40         PECL_CHECK_DONE(libbrotli, $PECL_VAR([HAVE_LIBBROTLI]))
  41
  42         dnl CURL
  43         PHP_ARG_WITH([http-libcurl-dir], [whether/where to check for libcurl],
  44         [  --with-http-libcurl-dir[=DIR]      HTTP: where to find libcurl], $PHP_HTTP)
  45         if test "$PHP_HTTP_LIBCURL_DIR" != "no"; then
  46                 PECL_CHECK_LIBCURL([$PHP_HTTP_LIBCURL_DIR], [7.18.2])
  47                 PECL_HAVE_LIBCURL_PROTOCOL([HTTP], [
  48                         PECL_HAVE_LIBCURL_FEATURE([HTTP2])
  49                         PECL_HAVE_LIBCURL_FEATURE([ALT-SVC])
  50                         PECL_HAVE_LIBCURL_FEATURE([HSTS])
  51                         PECL_HAVE_LIBCURL_ARES
  52                         PECL_HAVE_LIBCURL_SSL
  53                         PECL_HAVE_LIBCURL_CA
  54                         PECL_DEFINE([HAVE_CLIENT])
  55                 ])
  56                 PECL_CHECK_DONE(libcurl, [$PECL_VAR([HAVE_LIBCURL_PROTOCOL_HTTP])])
  57         fi
  58
  59         dnl EVENT
  60         PHP_ARG_WITH([http-libevent-dir], [whether/where to check for libevent],
  61         [  --with-http-libevent-dir[=DIR]     HTTP: where to find libevent], $PHP_HTTP_LIBCURL_DIR, no)
  62         if test "$PHP_HTTP_LIBEVENT_DIR" != "no"; then
  63                 PECL_CHECK_LIBEVENT([$PHP_HTTP_LIBEVENT_DIR])
  64                 PECL_CHECK_DONE(libevent, [$PECL_VAR([HAVE_LIBEVENT])])
  65         fi
  66
  67         dnl GNU IDNA
  68         PHP_ARG_WITH([http-libidn2-dir], [whether/where to check for libidn2],
  69         [  --with-http-libidn2-dir[=DIR]      HTTP: where to find libidn2], $PHP_HTTP_LIBCURL_DIR, no)
  70         if test "$PHP_HTTP_LIBIDN2_DIR" != "no"; then
  71                 PECL_CHECK_CUSTOM(libidn2, "$PHP_HTTP_LIBIDN2_DIR", idn2.h, idn2,
  72                         [$($EGREP "define IDN2_VERSION " "include/idn2.h" | $SED -e's/^.*VERSION //g' -e 's/@<:@^0-9\.@:>@//g')])
  73                 if $PECL_VAR([HAVE_LIBIDN2]); then
  74                         PECL_DEFINE([HAVE_IDNA2008])
  75                 fi
  76                 PECL_CHECK_DONE(libidn2, $PECL_VAR([HAVE_LIBIDN2]))
  77         fi
  78         PHP_ARG_WITH([http-libidn-dir], [whether/where to check for libidn],
  79         [  --with-http-libidn-dir[=DIR]       HTTP: where to find libidn], $PHP_HTTP_LIBCURL_DIR, no)
  80         if test "$PHP_HTTP_LIBIDN_DIR" != "no"; then
  81                 PECL_CHECK_PKGCONFIG(libidn, [$PHP_HTTP_LIBIDN_DIR])
  82                 if $PECL_VAR([HAVE_LIBIDN]); then
  83                         PECL_DEFINE([HAVE_IDNA2003])
  84                 fi
  85                 PECL_CHECK_DONE(libidn, $PECL_VAR([HAVE_LIBIDN]))
  86         fi
  87
  88         dnl ICU IDNA
  89         PHP_ARG_WITH([http-libicu-dir], [whether/where to check for libicu],
  90         [  --with-http-libicu-dir[=DIR]       HTTP: where to find libicu], $PHP_HTTP_LIBCURL_DIR, no)
  91         if test "$PHP_HTTP_LIBICU_DIR" != "no"; then
  92                 AC_PATH_PROG(ICU_CONFIG, icu-config, false, [$PHP_HTTP_LIBICU_DIR/bin:$PATH:/usr/local/bin])
  93
  94                 if $ICU_CONFIG --exists >/dev/null 2>/dev/null; then
  95                         PECL_CHECK_CONFIG(libicu, [$ICU_CONFIG], [--version], [--cppflags], [--ldflags-searchpath], [--ldflags-libsonly])
  96                 else
  97                         PECL_CHECK_PKGCONFIG(icu-i18n, [$PHP_HTTP_LIBICU_DIR])
  98                 fi
  99                 AC_CACHE_CHECK([for uidna_IDNToASCII], PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII]), [
 100                         if printf "%s" "$CFLAGS" | $EGREP -q "(^|\s)-Werror\b"; then
 101                                 if ! printf "%s" "$CFLAGS" | $EGREP -q "(^|\s)-Wno-error=deprecated-declarations\b"; then
 102                                         CFLAGS="$CFLAGS -Wno-error=deprecated-declarations"
 103                                 fi
 104                         fi
 105                         AC_TRY_LINK([
 106                                 #include <unicode/uidna.h>
 107                         ], [
 108                                 uidna_IDNToASCII(0, 0, 0, 0, 0, 0, 0);
 109                         ], [
 110                                 PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII])=yes
 111                         ], [
 112                                 PECL_CACHE_VAR([HAVE_UIDNA_IDNToASCII])=no
 113                         ])
 114                 ])
 115                 if $PECL_CACHE_VAR([HAVE_UIDNA_IDNTOASCII]); then
 116                         PECL_DEFINE([HAVE_IDNA2003])
 117                         PECL_DEFINE_FN([UIDNA_IDNTOASCII])
 118                 fi
 119
 120                 AC_CACHE_CHECK([for uidna_nameToASCII_UTF8], PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8]), [
 121                         AC_TRY_LINK([
 122                                 #include <unicode/uidna.h>
 123                         ], [
 124                                 uidna_nameToASCII_UTF8(0, 0, 0, 0, 0, 0, 0);
 125                         ], [
 126                                 PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8])=yes
 127                         ], [
 128                                 PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8])=no
 129                         ])
 130                 ])
 131                 if $PECL_CACHE_VAR([HAVE_UIDNA_NAMETOASCII_UTF8]); then
 132                         PECL_DEFINE([HAVE_IDNA2008])
 133                         PECL_DEFINE_FN([uidna_nameToASCII_UTF8])
 134                 fi
 135                 PECL_CHECK_DONE(libicu, [$PECL_VAR([HAVE_LIBICU])])
 136         fi
 137
 138         dnl IDNKIT2
 139         PHP_ARG_WITH([http-libidnkit2-dir], [whether/where to check for libidnkit2],
 140         [  --with-http-libidnkit2-dir[=DIR]   HTTP: where to find libidnkit2], $PHP_HTTP_LIBCURL_DIR, no)
 141         if test "$PHP_HTTP_LIBIDNKIT2_DIR" != "no"; then
 142                 PECL_CHECK_CUSTOM(libidnkit2, "$PHP_HTTP_LIBIDNKIT2_DIR", idn/api.h, idnkit,
 143                         [$($EGREP "define IDNKIT_VERSION_LIBIDN\b" "include/idn/version.h" | $SED -e's/^.*VERSION_LIBIDN//g' -e 's/@<:@^0-9\.@:>@//g')])
 144                 if $PECL_VAR([HAVE_LIBIDNKIT2]); then
 145                         PECL_DEFINE([HAVE_IDNA2008])
 146                 fi
 147                 PECL_CHECK_DONE(libidnkit2, [$PECL_VAR([HAVE_LIBIDNKIT2])])
 148         fi
 149         dnl IDNKIT1
 150         PHP_ARG_WITH([http-libidnkit-dir], [whether/where to check for libidnkit],
 151         [  --with-http-libidnkit-dir[=DIR]    HTTP: where to find libidnkit], $PHP_HTTP_LIBCURL_DIR, no)
 152         if test "$PHP_HTTP_LIBIDNKIT_DIR" != "no"; then
 153                 # libidnkit1 and libidnkit2 have the same API
 154                 if test "$PHP_HTTP_LIBIDNKIT2_DIR" != no && $PECL_VAR([HAVE_LIBIDNKIT2]); then
 155                         AC_MSG_WARN([libidnkit-$PECL_VAR([LIBIDNKIT2_VERSION]) already enabled, skipping libidnkit1])
 156                 else
 157                         PECL_CHECK_CUSTOM(libidnkit, "$PHP_HTTP_LIBIDNKIT_DIR", idn/api.h, idnkit,
 158                                 [$($EGREP "define IDNKIT_VERSION\b" "include/idn/version.h" | $SED -e's/^.*VERSION//g' -e 's/@<:@^0-9\.@:>@//g')])
 159                         if $PECL_VAR([HAVE_LIBIDNKIT]); then
 160                                 PECL_DEFINE([HAVE_IDNA2003])
 161                         fi
 162                         PECL_CHECK_DONE(libidnkit, [$PECL_VAR([HAVE_LIBIDNKIT])])
 163                 fi
 164         fi
 165
 166         dnl EXTENSIONS
 167         PECL_HAVE_PHP_EXT([raphf], [
 168                 PECL_HAVE_PHP_EXT_HEADER([raphf])
 169         ], [
 170                 AC_MSG_ERROR([please install and enable pecl/raphf])
 171         ])
 172         PECL_HAVE_PHP_EXT([iconv])
 173
 174         dnl DONE
 175         PHP_SUBST([HTTP_SHARED_LIBADD])
 176
 177         PECL_VAR([SRCDIR])=PHP_EXT_SRCDIR(http)
 178         PECL_VAR([BUILDDIR])=PHP_EXT_BUILDDIR(http)
 179
 180         PHP_ADD_INCLUDE([$PECL_VAR([SRCDIR])/src])
 181         PHP_ADD_BUILD_DIR([$PECL_VAR([BUILDDIR])/src])
 182
 183         PECL_VAR([HEADERS])=$(cd $PECL_VAR([SRCDIR])/src && echo *.h)
 184         PECL_VAR([SOURCES])=$(cd $PECL_VAR([SRCDIR]) && echo src/*.c)
 185
 186         PHP_NEW_EXTENSION(http, [$PECL_VAR([SOURCES])], [$ext_shared])
 187         PHP_INSTALL_HEADERS(ext/http, [php_http.h $PECL_VAR([HEADERS])])
 188
 189         PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
 190         [  --without-http-shared-deps       HTTP: do not depend on extensions like hash
 191                                          and iconv (when they are built shared)], yes, no)
 192         if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
 193                 if $PECL_VAR([HAVE_EXT_HASH]); then
 194                         PHP_ADD_EXTENSION_DEP([http], [hash], true)
 195                 fi
 196                 if $PECL_VAR([HAVE_EXT_ICONV]); then
 197                         PHP_ADD_EXTENSION_DEP([http], [iconv], true)
 198                 fi
 199         fi
 200         PHP_ADD_EXTENSION_DEP([http], [raphf], true)
 201
 202         PHP_SUBST(PECL_VAR([HEADERS]))
 203         PHP_SUBST(PECL_VAR([SOURCES]))
 204
 205         PHP_SUBST(PECL_VAR([SRCDIR]))
 206         PHP_SUBST(PECL_VAR([BUILDDIR]))
 207
 208         PHP_ADD_MAKEFILE_FRAGMENT
 209
 210         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 211 fi