projects / m6w6 / ext-http / blob
? search:


457e59859d8776f9abc6b03972d4fc9bb7e0a957
[m6w6/ext-http] / config9.m4
1 dnl config.m4 for pecl/http
2 dnl $Id: config9.m4 242664 2007-09-18 19:13:37Z mike $
3 dnl vim: noet ts=4 sw=4
4
5 PHP_ARG_WITH([http], [whether to enable extended HTTP support],
6 [ --with-http Enable extended HTTP support])
7 PHP_ARG_WITH([http-zlib-dir], [],
8 [ --with-http-zlib-dir[=DIR] HTTP: where to find zlib], $PHP_HTTP, $PHP_HTTP)
9 PHP_ARG_WITH([http-libcurl-dir], [],
10 [ --with-http-libcurl-dir[=DIR] HTTP: where to find libcurl], $PHP_HTTP, $PHP_HTTP)
11 PHP_ARG_WITH([http-libevent-dir], [],
12 [ --with-http-libevent-dir[=DIR] HTTP: where to find libevent], $PHP_HTTP_LIBCURL_DIR, "")
13
14 if test "$PHP_HTTP" != "no"; then
15
16 HTTP_HAVE_A_REQUEST_LIB=false
17
18 ifdef([AC_PROG_EGREP], [
19 AC_PROG_EGREP
20 ], [
21 AC_CHECK_PROG(EGREP, egrep, egrep)
22 ])
23 ifdef([AC_PROG_SED], [
24 AC_PROG_SED
25 ], [
26 ifdef([LT_AC_PROG_SED], [
27 LT_AC_PROG_SED
28 ], [
29 AC_CHECK_PROG(SED, sed, sed)
30 ])
31 ])
32
33 AC_PROG_CPP
34
35 if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
36 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [1], [ ])
37 else
38 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [0], [ ])
39 fi
40
41 dnl
42 dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
43 dnl
44 AC_DEFUN([HTTP_SHARED_DEP], [
45 extname=$1
46 haveext=$[PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
47
48 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
49 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
50 AC_MSG_RESULT([no])
51 $3
52 elif test "$haveext"; then
53 AC_MSG_RESULT([yes])
54 AC_DEFINE([PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__), [1], [ ])
55 ifdef([PHP_ADD_EXTENSION_DEP], [
56 PHP_ADD_EXTENSION_DEP([http], $1, true)
57 ])
58 $2
59 else
60 AC_MSG_RESULT([no])
61 $3
62 fi
63 ])
64
65 dnl
66 dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
67 dnl
68 AC_DEFUN([HTTP_HAVE_PHP_EXT], [
69 extname=$1
70 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
71
72 AC_MSG_CHECKING([for ext/$extname support])
73 if test -x "$PHP_EXECUTABLE"; then
74 grepext=`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`
75 if test "$grepext" = "$extname"; then
76 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
77 AC_MSG_RESULT([yes])
78 $2
79 else
80 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
81 AC_MSG_RESULT([no])
82 $3
83 fi
84 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
85 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
86 AC_MSG_RESULT([yes])
87 $2
88 else
89 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
90 AC_MSG_RESULT([no])
91 $3
92 fi
93 ])
94
95
96 dnl ----
97 dnl STDC
98 dnl ----
99 AC_CHECK_HEADERS([netdb.h unistd.h])
100 PHP_CHECK_FUNC(gethostname, nsl)
101 PHP_CHECK_FUNC(getdomainname, nsl)
102 PHP_CHECK_FUNC(getservbyport, nsl)
103 PHP_CHECK_FUNC(getservbyport_r, nsl)
104 PHP_CHECK_FUNC(getservbyname, nsl)
105 PHP_CHECK_FUNC(getservbyname_r, nsl)
106
107 dnl ----
108 dnl ZLIB
109 dnl ----
110 AC_MSG_CHECKING([for zlib.h])
111 ZLIB_DIR=
112 for i in "$PHP_HTTP_ZLIB_DIR" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
113 if test -f "$i/include/zlib.h"; then
114 ZLIB_DIR=$i
115 break;
116 fi
117 done
118 if test "x$ZLIB_DIR" = "x"; then
119 AC_MSG_RESULT([not found])
120 AC_MSG_ERROR([could not find zlib.h])
121 else
122 AC_MSG_RESULT([found in $ZLIB_DIR])
123 AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
124 ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
125 AC_MSG_RESULT([$ZLIB_VERSION])
126 if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
127 AC_MSG_ERROR([zlib version greater or equal to 1.2.0.4 required])
128 else
129 PHP_ADD_INCLUDE($ZLIB_DIR/include)
130 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
131 fi
132 fi
133
134 dnl ----
135 dnl CURL
136 dnl ----
137
138 if test "$PHP_HTTP_LIBCURL_DIR" = "no"; then
139 AC_DEFINE([PHP_HTTP_HAVE_CURL], [0], [ ])
140 else
141 AC_MSG_CHECKING([for curl/curl.h])
142 CURL_DIR=
143 for i in "$PHP_HTTP_LIBCURL_DIR" /usr/local /usr /opt; do
144 if test -f "$i/include/curl/curl.h"; then
145 CURL_DIR=$i
146 break
147 fi
148 done
149 if test "x$CURL_DIR" = "x"; then
150 AC_MSG_RESULT([not found])
151 else
152 AC_MSG_RESULT([found in $CURL_DIR])
153
154 AC_MSG_CHECKING([for curl-config])
155 CURL_CONFIG=
156 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
157 if test -x "$i"; then
158 CURL_CONFIG=$i
159 break
160 fi
161 done
162 if test "x$CURL_CONFIG" = "x"; then
163 AC_MSG_RESULT([not found])
164 AC_MSG_ERROR([could not find curl-config])
165 else
166 AC_MSG_RESULT([found: $CURL_CONFIG])
167 fi
168
169 dnl RHEL6: 7.19.7
170 dnl SUSE11: 7.19.7
171 dnl Debian wheezy: 7.26.0
172 dnl Debian sqeeze: 7.21.0
173 dnl Debian ancient 7.18.2
174 AC_MSG_CHECKING([for curl version >= 7.18.2])
175 CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
176 AC_MSG_RESULT([$CURL_VERSION])
177 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71802; then
178 AC_MSG_ERROR([libcurl version greater or equal to 7.18.2 required])
179 fi
180
181 dnl
182 dnl compile tests
183 dnl
184
185 save_INCLUDES="$INCLUDES"
186 INCLUDES=
187 save_LIBS="$LIBS"
188 LIBS=
189 save_CFLAGS="$CFLAGS"
190 CFLAGS="$CFLAGS `$CURL_CONFIG --cflags`"
191 save_LDFLAGS="$LDFLAGS"
192 LDFLAGS="$LDFLAGS `$CURL_CONFIG --libs` $ld_runpath_switch$CURL_DIR/$PHP_LIBDIR"
193
194 AC_MSG_CHECKING([for SSL support in libcurl])
195 CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
196 CURL_SSL_LIBS=()
197 if test "$CURL_SSL" = "SSL"; then
198 AC_MSG_RESULT([yes])
199 AC_DEFINE([PHP_HTTP_HAVE_SSL], [1], [ ])
200
201 AC_MSG_CHECKING([for openssl support in libcurl])
202 AC_TRY_RUN([
203 #include <curl/curl.h>
204 int main(int argc, char *argv[]) {
205 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
206 if (data && data->ssl_version && *data->ssl_version) {
207 const char *ptr = data->ssl_version;
208 while(*ptr == ' ') ++ptr;
209 return strncasecmp(ptr, "OpenSSL", sizeof("OpenSSL")-1);
210 }
211 return 1;
212 }
213 ], [
214 AC_MSG_RESULT([yes])
215 AC_CHECK_HEADER([openssl/ssl.h], [
216 AC_CHECK_HEADER([openssl/crypto.h], [
217 AC_DEFINE([PHP_HTTP_HAVE_OPENSSL], [1], [ ])
218 CURL_SSL_LIBS=(ssl crypto)
219 ])
220 ])
221 ], [
222 AC_MSG_RESULT([no])
223 ], [
224 AC_MSG_RESULT([no])
225 ])
226
227 AC_MSG_CHECKING([for gnutls support in libcurl])
228 AC_TRY_RUN([
229 #include <curl/curl.h>
230 int main(int argc, char *argv[]) {
231 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
232 if (data && data->ssl_version && *data->ssl_version) {
233 const char *ptr = data->ssl_version;
234 while(*ptr == ' ') ++ptr;
235 return strncasecmp(ptr, "GnuTLS", sizeof("GnuTLS")-1);
236 }
237 return 1;
238 }
239 ], [
240 AC_MSG_RESULT([yes])
241 AC_CHECK_HEADER([gnutls.h], [
242 AC_CHECK_HEADER([gcrypt.h], [
243 AC_DEFINE([PHP_HTTP_HAVE_GNUTLS], [1], [ ])
244 CURL_SSL_LIBS=(gnutls gcrypt)
245 ])
246 ])
247 ], [
248 AC_MSG_RESULT([no])
249 ], [
250 AC_MSG_RESULT([no])
251 ])
252 else
253 AC_MSG_RESULT([no])
254 fi
255
256 INCLUDES="$save_INCLUDES"
257 LIBS="$save_LIBS"
258 CFLAGS="$save_CFLAGS"
259 LDFLAGS="$save_LDFLAGS"
260
261 for CURL_SSL_LIB in "${CURL_SSL_LIBS[[@]]}"; do
262 PHP_ADD_LIBRARY_WITH_PATH([$CURL_SSL_LIB], $CURL_DIR/$PHP_LIBDIR, PHP_HTTP_SHARED_LIBADD)
263 done
264
265 dnl end compile tests
266
267 AC_MSG_CHECKING([for bundled SSL CA info])
268 CURL_CAINFO=
269 for i in `$CURL_CONFIG --ca` "/etc/ssl/certs/ca-certificates.crt" "/etc/ssl/certs/ca-bundle.crt"; do
270 if test -f "$i"; then
271 CURL_CAINFO="$i"
272 break
273 fi
274 done
275 if test "x$CURL_CAINFO" = "x"; then
276 AC_MSG_RESULT([not found])
277 else
278 AC_MSG_RESULT([$CURL_CAINFO])
279 AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAINFO], ["$CURL_CAINFO"], [path to bundled SSL CA info])
280 fi
281
282 PHP_ADD_INCLUDE($CURL_DIR/include)
283 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
284 PHP_EVAL_LIBLINE(`$CURL_CONFIG --libs`, HTTP_SHARED_LIBADD)
285 AC_DEFINE([PHP_HTTP_HAVE_CURL], [1], [Have libcurl support])
286 HTTP_HAVE_A_REQUEST_LIB=true
287 fi
288 fi
289
290 dnl ----
291 dnl EVENT
292 dnl ----
293
294 if test "$PHP_HTTP_LIBEVENT_DIR" = "no"; then
295 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
296 else
297 AC_MSG_CHECKING([for event2/event.h])
298 EVENT_DIR=
299 for i in "$PHP_HTTP_LIBEVENT_DIR" /usr/local /usr /opt; do
300 if test -f "$i/include/event.h"; then
301 EVENT_DIR=$i
302 break
303 fi
304 done
305 if test "x$EVENT_DIR" = "x"; then
306 AC_MSG_RESULT([not found])
307 AC_MSG_WARN([continuing without libevent support])
308 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
309 else
310 AC_MSG_RESULT([found in $EVENT_DIR])
311
312 AC_MSG_CHECKING([for libevent version, roughly])
313
314 if test -f "$EVENT_DIR/include/event2/event.h"; then
315 EVENT_VER="`$EGREP _EVENT_VERSION $EVENT_DIR/include/event2/event-config.h | $AWK '{print $3}'`"
316 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [1], [ ])
317 else
318 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [0], [ ])
319 if test -f "$EVENT_DIR/include/evhttp.h" && test -f "$EVENT_DIR/include/evdns.h"; then
320 if test -f "$EVENT_DIR/include/evrpc.h"; then
321 EVENT_VER="1.4 or greater"
322 else
323 EVENT_VER="1.2 or greater"
324 fi
325 else
326 EVENT_VER="1.1b or lower"
327 fi
328 fi
329 AC_DEFINE_UNQUOTED([PHP_HTTP_EVENT_VERSION], ["$EVENT_VER"], [ ])
330 AC_MSG_RESULT([$EVENT_VER])
331
332 PHP_ADD_INCLUDE($EVENT_DIR/include)
333 PHP_ADD_LIBRARY_WITH_PATH(event, $EVENT_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
334 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [1], [Have libevent support for cURL])
335 fi
336 fi
337
338 dnl ----
339 dnl RAPHF
340 dnl ----
341 HTTP_HAVE_PHP_EXT([raphf], [
342 AC_MSG_CHECKING([for php_raphf.h])
343 HTTP_EXT_RAPHF_INCDIR=
344 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../raphf; do
345 if test -d $i; then
346 if test -f $i/php_raphf.h; then
347 HTTP_EXT_RAPHF_INCDIR=$i
348 break
349 elif test -f $i/ext/raphf/php_raphf.h; then
350 HTTP_EXT_RAPHF_INCDIR=$i/ext/raphf
351 break
352 fi
353 fi
354 done
355 if test "x$HTTP_EXT_RAPHF_INCDIR" = "x"; then
356 AC_MSG_ERROR([not found])
357 else
358 AC_MSG_RESULT([$HTTP_EXT_RAPHF_INCDIR])
359 AC_DEFINE([PHP_HTTP_HAVE_PHP_RAPHF_H], [1], [Have ext/raphf support])
360 PHP_ADD_INCLUDE([$HTTP_EXT_RAPHF_INCDIR])
361 fi
362 ], [
363 AC_MSG_ERROR([Please install pecl/raphf])
364 ])
365
366 dnl ----
367 dnl PROPRO
368 dnl ----
369 HTTP_HAVE_PHP_EXT([propro], [
370 AC_MSG_CHECKING([for php_propro.h])
371 HTTP_EXT_PROPRO_INCDIR=
372 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../propro; do
373 if test -d $i; then
374 if test -f $i/php_propro.h; then
375 HTTP_EXT_PROPRO_INCDIR=$i
376 break
377 elif test -f $i/ext/propro/php_propro.h; then
378 HTTP_EXT_PROPRO_INCDIR=$i/ext/propro
379 break
380 fi
381 fi
382 done
383 if test "x$HTTP_EXT_PROPRO_INCDIR" = "x"; then
384 AC_MSG_ERROR([not found])
385 else
386 AC_MSG_RESULT([$HTTP_EXT_PROPRO_INCDIR])
387 AC_DEFINE([PHP_HTTP_HAVE_PHP_PROPRO_H], [1], [Have ext/propro support])
388 PHP_ADD_INCLUDE([$HTTP_EXT_PROPRO_INCDIR])
389 fi
390 ], [
391 AC_MSG_ERROR([Please install pecl/propro])
392 ])
393
394 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
395 [ --without-http-shared-deps HTTP: do not depend on extensions like hash
396 and iconv (when they are built shared)], $PHP_HTTP, $PHP_HTTP)
397 dnl ----
398 dnl HASH
399 dnl ----
400 HTTP_HAVE_PHP_EXT([hash], [
401 AC_MSG_CHECKING([for php_hash.h])
402 HTTP_EXT_HASH_INCDIR=
403 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
404 if test -d $i; then
405 if test -f $i/php_hash.h; then
406 HTTP_EXT_HASH_INCDIR=$i
407 break
408 elif test -f $i/ext/hash/php_hash.h; then
409 HTTP_EXT_HASH_INCDIR=$i/ext/hash
410 break
411 fi
412 fi
413 done
414 if test "x$HTTP_EXT_HASH_INCDIR" = "x"; then
415 AC_MSG_RESULT([not found])
416 else
417 AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
418 AC_DEFINE([PHP_HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
419 PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
420 fi
421 ])
422
423 dnl ----
424 dnl JSON
425 dnl ----
426 HTTP_HAVE_PHP_EXT([json])
427
428
429 dnl ----
430 dnl ICONV
431 dnl ----
432 HTTP_HAVE_PHP_EXT([iconv])
433
434 dnl ----
435 dnl DONE
436 dnl ----
437 PHP_HTTP_SOURCES="\
438 php_http_buffer.c \
439 php_http.c \
440 php_http_client.c \
441 php_http_client_curl.c \
442 php_http_client_request.c \
443 php_http_client_response.c \
444 php_http_cookie.c \
445 php_http_curl.c \
446 php_http_encoding.c \
447 php_http_env.c \
448 php_http_env_request.c \
449 php_http_env_response.c \
450 php_http_etag.c \
451 php_http_exception.c \
452 php_http_filter.c \
453 php_http_header_parser.c \
454 php_http_header.c \
455 php_http_info.c \
456 php_http_message_body.c \
457 php_http_message.c \
458 php_http_message_parser.c \
459 php_http_misc.c \
460 php_http_negotiate.c \
461 php_http_object.c \
462 php_http_options.c \
463 php_http_params.c \
464 php_http_querystring.c \
465 php_http_strlist.c \
466 php_http_url.c \
467 php_http_version.c \
468 "
469 PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
470
471 dnl shared extension deps
472 HTTP_SHARED_DEP([hash])
473 HTTP_SHARED_DEP([iconv])
474 HTTP_SHARED_DEP([json])
475
476 dnl extension deps
477 PHP_ADD_EXTENSION_DEP([http], [raphf], true)
478 PHP_ADD_EXTENSION_DEP([http], [propo], true)
479
480 PHP_SUBST([HTTP_SHARED_LIBADD])
481
482 PHP_HTTP_HEADERS="
483 php_http_api.h \
484 php_http_buffer.h \
485 php_http_curl_client.h \
486 php_http_curl_client_datashare.h \
487 php_http_client_datashare.h \
488 php_http_client_factory.h \
489 php_http_client.h \
490 php_http_client_interface.h \
491 php_http_curl_client_pool.h \
492 php_http_client_pool.h \
493 php_http_client_request.h \
494 php_http_client_response.h \
495 php_http_cookie.h \
496 php_http_curl.h \
497 php_http_encoding.h \
498 php_http_env.h \
499 php_http_env_request.h \
500 php_http_env_response.h \
501 php_http_etag.h \
502 php_http_exception.h \
503 php_http_filter.h \
504 php_http.h \
505 php_http_header_parser.h \
506 php_http_header.h \
507 php_http_info.h \
508 php_http_message_body.h \
509 php_http_message.h \
510 php_http_message_parser.h \
511 php_http_misc.h \
512 php_http_negotiate.h \
513 php_http_object.h \
514 php_http_options.h \
515 php_http_params.h \
516 php_http_querystring.h \
517 php_http_strlist.h \
518 php_http_url.h \
519 php_http_version.h \
520 "
521 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
522
523 AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
524 fi
Extended HTTP Support