git.m6w6.name Git - m6w6/ext-http/blob - config9.m4

   1 dnl config.m4 for pecl/http
   2 dnl $Id$
   3 dnl vim: noet ts=1 sw=1
   4
   5 PHP_ARG_ENABLE([http], [whether to enable extended HTTP support],
   6 [  --enable-http           Enable extended HTTP support])
   7 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
   8 [  --with-http-shared-deps
   9                            HTTP: disable to not depend on extensions like hash,
  10                                  iconv and session (when built shared)], $PHP_HTTP, $PHP_HTTP)
  11 PHP_ARG_WITH([http-curl-requests], [whether to enable cURL HTTP request support],
  12 [  --with-http-curl-requests[=LIBCURLDIR]
  13                            HTTP: with cURL request support], $PHP_HTTP, $PHP_HTTP)
  14 PHP_ARG_WITH([http-zlib-compression], [whether to enable zlib encodings support],
  15 [  --with-http-zlib-compression[=LIBZDIR]
  16                            HTTP: with zlib encodings support], $PHP_HTTP, $PHP_HTTP)
  17 PHP_ARG_WITH([http-magic-mime], [whether to enable response content type guessing],
  18 [  --with-http-magic-mime[=LIBMAGICDIR]
  19                            HTTP: with magic mime response content type guessing], "no", "no")
  20
  21 if test "$PHP_HTTP" != "no"; then
  22
  23         ifdef([AC_PROG_EGREP], [
  24                 AC_PROG_EGREP
  25         ], [
  26                 AC_CHECK_PROG(EGREP, egrep, egrep)
  27         ])
  28         ifdef([AC_PROG_SED], [
  29                 AC_PROG_SED
  30         ], [
  31                 ifdef([LT_AC_PROG_SED], [
  32                         LT_AC_PROG_SED
  33                 ], [
  34                         AC_CHECK_PROG(SED, sed, sed)
  35                 ])
  36         ])
  37
  38         if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
  39                 AC_DEFINE([HTTP_SHARED_DEPS], [1], [ ])
  40         else
  41                 AC_DEFINE([HTTP_SHARED_DEPS], [0], [ ])
  42         fi
  43
  44         dnl
  45         dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
  46         dnl
  47         AC_DEFUN([HTTP_SHARED_DEP], [
  48                 extname=$1
  49                 haveext=$[HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
  50
  51                 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
  52                 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
  53                         AC_MSG_RESULT([no])
  54                         $3
  55                 elif test "$haveext"; then
  56                         AC_MSG_RESULT([yes])
  57                         ifdef([PHP_ADD_EXTENSION_DEP], [
  58                                 PHP_ADD_EXTENSION_DEP([http], $1, true)
  59                         ])
  60                         $2
  61                 else
  62                         AC_MSG_RESULT([no])
  63                         $3
  64                 fi
  65         ])
  66
  67         dnl
  68         dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
  69         dnl
  70         AC_DEFUN([HTTP_HAVE_PHP_EXT], [
  71                 extname=$1
  72                 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
  73                 ishared=$[PHP_]translit($1,a-z_-,A-Z__)_SHARED
  74
  75                 AC_MSG_CHECKING([for ext/$extname support])
  76                 if test -x "$PHP_EXECUTABLE"; then
  77                         if test "`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`" = "$extname"; then
  78                                 [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  79                                 AC_MSG_RESULT([yes])
  80                                 $2
  81                         else
  82                                 [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  83                                 AC_MSG_RESULT([no])
  84                                 $3
  85                         fi
  86                 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
  87                         [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
  88                         AC_MSG_RESULT([yes])
  89                         $2
  90                 else
  91                         [HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
  92                         AC_MSG_RESULT([no])
  93                         $3
  94                 fi
  95         ])
  96
  97 dnl ----
  98 dnl STDC
  99 dnl ----
 100         AC_CHECK_HEADERS([netdb.h unistd.h])
 101         PHP_CHECK_FUNC(gethostname, nsl)
 102         PHP_CHECK_FUNC(getdomainname, nsl)
 103         PHP_CHECK_FUNC(getservbyport, nsl)
 104         PHP_CHECK_FUNC(getservbyname, nsl)
 105
 106 dnl ----
 107 dnl ZLIB
 108 dnl ----
 109         if test "$PHP_HTTP_ZLIB_COMPRESSION" != "no"; then
 110                 AC_MSG_CHECKING([for zlib.h])
 111                 ZLIB_DIR=
 112                 for i in "$PHP_HTTP_ZLIB_COMPRESSION" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
 113                         if test -f "$i/include/zlib.h"; then
 114                                 ZLIB_DIR=$i
 115                                 break;
 116                         fi
 117                 done
 118                 if test -z "$ZLIB_DIR"; then
 119                         AC_MSG_RESULT([not found])
 120                         AC_MSG_ERROR([could not find zlib.h])
 121                 else
 122                         AC_MSG_RESULT([found in $ZLIB_DIR])
 123                         AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
 124                         ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
 125                         AC_MSG_RESULT([$ZLIB_VERSION])
 126                         if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
 127                                 AC_MSG_ERROR([libz version greater or equal to 1.2.0.4 required])
 128                         else
 129                                 PHP_ADD_INCLUDE($ZLIB_DIR/include)
 130                                 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 131                                 AC_DEFINE([HTTP_HAVE_ZLIB], [1], [Have zlib support])
 132                         fi
 133                 fi
 134         fi
 135
 136 dnl ----
 137 dnl CURL
 138 dnl ----
 139         if test "$PHP_HTTP_CURL_REQUESTS" != "no"; then
 140                 AC_MSG_CHECKING([for curl/curl.h])
 141                 CURL_DIR=
 142                 for i in "$PHP_HTTP_CURL_REQUESTS" /usr/local /usr /opt; do
 143                         if test -f "$i/include/curl/curl.h"; then
 144                                 CURL_DIR=$i
 145                                 break
 146                         fi
 147                 done
 148                 if test -z "$CURL_DIR"; then
 149                         AC_MSG_RESULT([not found])
 150                         AC_MSG_ERROR([could not find curl/curl.h])
 151                 else
 152                         AC_MSG_RESULT([found in $CURL_DIR])
 153                 fi
 154
 155                 AC_MSG_CHECKING([for curl-config])
 156                 CURL_CONFIG=
 157                 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
 158                         if test -x "$i"; then
 159                                 CURL_CONFIG=$i
 160                                 break
 161                         fi
 162                 done
 163                 if test -z "$CURL_CONFIG"; then
 164                         AC_MSG_RESULT([not found])
 165                         AC_MSG_ERROR([could not find curl-config])
 166                 else
 167                         AC_MSG_RESULT([found: $CURL_CONFIG])
 168                 fi
 169
 170                 dnl Debian stable has currently 7.13.2 (this is not a typo)
 171                 AC_MSG_CHECKING([for curl version >= 7.12.3])
 172                 CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
 173                 AC_MSG_RESULT([$CURL_VERSION])
 174                 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71203; then
 175                         AC_MSG_ERROR([libcurl version greater or equal to 7.12.3 required])
 176                 fi
 177
 178                 CURL_LIBS=`$CURL_CONFIG --libs`
 179
 180                 AC_MSG_CHECKING([for SSL support in libcurl])
 181                 CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
 182                 if test "$CURL_SSL" = "SSL"; then
 183                         AC_MSG_RESULT([yes])
 184                         AC_DEFINE([HTTP_HAVE_SSL], [1], [ ])
 185
 186                         AC_MSG_CHECKING([for SSL library used])
 187                         CURL_SSL_FLAVOUR=
 188                         for i in $CURL_LIBS; do
 189                                 case $i in
 190                                         -lssl* | -lyassl*)
 191                                                 CURL_SSL_FLAVOUR="openssl"
 192                                                 AC_MSG_RESULT([openssl])
 193                                                 AC_DEFINE([HTTP_HAVE_OPENSSL], [1], [ ])
 194                                                 AC_CHECK_HEADERS([openssl/crypto.h])
 195                                                 break
 196                                         ;;
 197                                         -lgnutls*)
 198                                                 CURL_SSL_FLAVOUR="gnutls"
 199                                                 AC_MSG_RESULT([gnutls])
 200                                                 AC_DEFINE([HTTP_HAVE_GNUTLS], [1], [ ])
 201                                                 AC_CHECK_HEADERS([gcrypt.h])
 202                                                 break
 203                                         ;;
 204                                 esac
 205                         done
 206                         if test -z "$CURL_SSL_FLAVOUR"; then
 207                                 AC_MSG_RESULT([unknown!])
 208                                 AC_MSG_WARN([Could not determine the type of SSL library used!])
 209                                 AC_MSG_WARN([Building will fail in ZTS mode!])
 210                         fi
 211                 else
 212                         AC_MSG_RESULT([no])
 213                 fi
 214
 215                 AC_MSG_CHECKING([for bundled SSL CA info])
 216                 CURL_CAINFO=
 217                 for i in `$CURL_CONFIG --ca` "/etc/ssl/certs/ca-certificates.crt"; do
 218                         if test -f "$i"; then
 219                                 CURL_CAINFO="$i"
 220                                 break
 221                         fi
 222                 done
 223                 if test -z "$CURL_CAINFO"; then
 224                         AC_MSG_RESULT([not found])
 225                 else
 226                         AC_MSG_RESULT([$CURL_CAINFO])
 227                         AC_DEFINE_UNQUOTED([HTTP_CURL_CAINFO], ["$CURL_CAINFO"], [path to bundled SSL CA info])
 228                 fi
 229
 230                 PHP_ADD_INCLUDE($CURL_DIR/include)
 231                 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 232                 PHP_EVAL_LIBLINE($CURL_LIBS, HTTP_SHARED_LIBADD)
 233                 AC_DEFINE([HTTP_HAVE_CURL], [1], [Have cURL support])
 234
 235                 PHP_CHECK_LIBRARY(curl, curl_share_strerror,
 236                         [AC_DEFINE([HAVE_CURL_SHARE_STRERROR], [1], [ ])], [ ],
 237                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 238                 )
 239                 PHP_CHECK_LIBRARY(curl, curl_multi_strerror,
 240                         [AC_DEFINE([HAVE_CURL_MULTI_STRERROR], [1], [ ])], [ ],
 241                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 242                 )
 243                 PHP_CHECK_LIBRARY(curl, curl_easy_strerror,
 244                         [AC_DEFINE([HAVE_CURL_EASY_STRERROR], [1], [ ])], [ ],
 245                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 246                 )
 247                 PHP_CHECK_LIBRARY(curl, curl_easy_reset,
 248                         [AC_DEFINE([HAVE_CURL_EASY_RESET], [1], [ ])], [ ],
 249                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 250                 )
 251                 dnl Debian suddenly (>=7.14.1-2) hides all symbols not starting with "curl"
 252                 PHP_CHECK_LIBRARY(curl, Curl_getFormData,
 253                         [AC_DEFINE([HAVE_CURL_GETFORMDATA], [1], [ ])], [ ],
 254                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 255                 )
 256                 dnl New API function which obsoletes use of Curl_getFormData (>=7.15.5)
 257                 PHP_CHECK_LIBRARY(curl, curl_formget,
 258                         [AC_DEFINE([HAVE_CURL_FORMGET], [1], [ ])], [ ],
 259                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 260                 )
 261                 PHP_CHECK_LIBRARY(curl, curl_multi_setopt,
 262                         [AC_DEFINE([HAVE_CURL_MULTI_SETOPT], [1], [ ])], [ ],
 263                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 264                 )
 265                 PHP_CHECK_LIBRARY(curl, curl_multi_timeout,
 266                         [AC_DEFINE([HAVE_CURL_MULTI_TIMEOUT], [1], [ ])], [ ],
 267                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 268                 )
 269
 270         fi
 271
 272 dnl ----
 273 dnl MAGIC
 274 dnl ----
 275         if test "$PHP_HTTP_MAGIC_MIME" != "no"; then
 276                 AC_MSG_CHECKING([for magic.h])
 277                 MAGIC_DIR=
 278                 for i in "$PHP_HTTP_MAGIC_MIME" /usr/local /usr /opt; do
 279                         if test -f "$i/include/magic.h"; then
 280                                 MAGIC_DIR=$i
 281                                 break
 282                         fi
 283                 done
 284                 if test -z "$MAGIC_DIR"; then
 285                         AC_MSG_RESULT([not found])
 286                         AC_MSG_ERROR([could not find magic.h])
 287                 else
 288                         AC_MSG_RESULT([found in $MAGIC_DIR])
 289                 fi
 290
 291                 PHP_ADD_INCLUDE($MAGIC_DIR/include)
 292                 PHP_ADD_LIBRARY_WITH_PATH(magic, $MAGIC_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 293                 AC_DEFINE([HTTP_HAVE_MAGIC], [1], [Have magic mime support])
 294         fi
 295
 296 dnl ----
 297 dnl HASH
 298 dnl ----
 299         HTTP_HAVE_PHP_EXT([hash], [
 300                 AC_MSG_CHECKING([for php_hash.h])
 301                 HTTP_EXT_HASH_INCDIR=
 302                 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
 303                         if test -d $i; then
 304                                 if test -f $i/php_hash.h; then
 305                                         HTTP_EXT_HASH_INCDIR=$i
 306                                         break
 307                                 elif test -f $i/ext/hash/php_hash.h; then
 308                                         HTTP_EXT_HASH_INCDIR=$i/ext/hash
 309                                         break
 310                                 fi
 311                         fi
 312                 done
 313                 if test -z "$HTTP_EXT_HASH_INCDIR"; then
 314                         AC_MSG_RESULT([not found])
 315                 else
 316                         AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
 317                         AC_DEFINE([HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
 318                         PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
 319                 fi
 320         ])
 321
 322 dnl ----
 323 dnl ICONV
 324 dnl ----
 325         HTTP_HAVE_PHP_EXT([iconv])
 326
 327 dnl ----
 328 dnl SESSION
 329 dnl ----
 330         HTTP_HAVE_PHP_EXT([session])
 331
 332 dnl ----
 333 dnl DONE
 334 dnl ----
 335         PHP_HTTP_SOURCES="missing.c http.c http_functions.c phpstr/phpstr.c \
 336                 http_util_object.c http_message_object.c http_request_object.c http_request_pool_api.c \
 337                 http_response_object.c http_exception_object.c http_requestpool_object.c \
 338                 http_api.c http_cache_api.c http_request_api.c http_request_info.c http_date_api.c \
 339                 http_headers_api.c http_message_api.c http_send_api.c http_url_api.c \
 340                 http_info_api.c http_request_method_api.c http_encoding_api.c \
 341                 http_filter_api.c http_request_body_api.c http_querystring_object.c \
 342                 http_deflatestream_object.c http_inflatestream_object.c http_cookie_api.c \
 343                 http_querystring_api.c http_request_datashare_api.c http_requestdatashare_object.c \
 344                 http_persistent_handle_api.c"
 345
 346         PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
 347
 348         dnl shared extension deps
 349         HTTP_SHARED_DEP([hash])
 350         HTTP_SHARED_DEP([iconv])
 351         HTTP_SHARED_DEP([session])
 352
 353         PHP_ADD_BUILD_DIR($ext_builddir/phpstr, 1)
 354         PHP_SUBST([HTTP_SHARED_LIBADD])
 355
 356         PHP_HTTP_HEADERS="php_http_std_defs.h php_http.h php_http_api.h php_http_cache_api.h \
 357                 php_http_date_api.h php_http_headers_api.h php_http_info_api.h php_http_message_api.h \
 358                 php_http_request_api.h php_http_request_method_api.h php_http_send_api.h php_http_url_api.h \
 359                 php_http_encoding_api.h phpstr/phpstr.h missing.h php_http_request_body_api.h \
 360                 php_http_exception_object.h php_http_message_object.h php_http_request_object.h \
 361                 php_http_requestpool_object.h php_http_response_object.h php_http_util_object.h \
 362                 php_http_querystring_object.h php_http_deflatestream_object.h php_http_inflatestream_object.h \
 363                 php_http_cookie_api.h php_http_querystring_api.h php_http_request_datashare_api.h php_http_requestdatashare_object.h \
 364                 php_http_persistent_handle_api.h"
 365         ifdef([PHP_INSTALL_HEADERS], [
 366                 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
 367         ], [
 368                 PHP_SUBST([PHP_HTTP_HEADERS])
 369                 PHP_ADD_MAKEFILE_FRAGMENT
 370         ])
 371
 372         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 373 fi