projects / m6w6 / ext-http / blob
? search:


3b1f7015554d1683469836e9548efd85b2eb0a08
[m6w6/ext-http] / config9.m4
1 dnl config.m4 for pecl/http
2 dnl $Id: config9.m4 242664 2007-09-18 19:13:37Z mike $
3 dnl vim: noet ts=4 sw=4
4
5 PHP_ARG_WITH([http], [whether to enable extended HTTP support],
6 [ --with-http Enable extended HTTP support])
7 PHP_ARG_WITH([http-zlib-dir], [],
8 [ --with-http-zlib-dir[=DIR] HTTP: where to find zlib], $PHP_HTTP, $PHP_HTTP)
9 PHP_ARG_WITH([http-libcurl-dir], [],
10 [ --with-http-libcurl-dir[=DIR] HTTP: where to find libcurl], $PHP_HTTP, $PHP_HTTP)
11 PHP_ARG_WITH([http-libevent-dir], [],
12 [ --with-http-libevent-dir[=DIR] HTTP: where to find libevent], $PHP_HTTP_LIBCURL_DIR, "")
13 PHP_ARG_WITH([http-libidn-dir], [],
14 [ --with-http-libidn-dir=[=DIR] HTTP: where to find libidn], $PHP_HTTP_LIBCURL_DIR, "")
15
16 if test "$PHP_HTTP" != "no"; then
17
18 HTTP_HAVE_A_REQUEST_LIB=false
19
20 ifdef([AC_PROG_EGREP], [
21 AC_PROG_EGREP
22 ], [
23 AC_CHECK_PROG(EGREP, egrep, egrep)
24 ])
25 ifdef([AC_PROG_SED], [
26 AC_PROG_SED
27 ], [
28 ifdef([LT_AC_PROG_SED], [
29 LT_AC_PROG_SED
30 ], [
31 AC_CHECK_PROG(SED, sed, sed)
32 ])
33 ])
34
35 AC_PROG_CPP
36
37 if test "$PHP_HTTP_SHARED_DEPS" != "no"; then
38 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [1], [ ])
39 else
40 AC_DEFINE([PHP_HTTP_SHARED_DEPS], [0], [ ])
41 fi
42
43 dnl
44 dnl HTTP_SHARED_DEP(name[, code-if-yes[, code-if-not]])
45 dnl
46 AC_DEFUN([HTTP_SHARED_DEP], [
47 extname=$1
48 haveext=$[PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)
49
50 AC_MSG_CHECKING([whether to add a dependency on ext/$extname])
51 if test "$PHP_HTTP_SHARED_DEPS" = "no"; then
52 AC_MSG_RESULT([no])
53 $3
54 elif test "$haveext"; then
55 AC_MSG_RESULT([yes])
56 AC_DEFINE([PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__), [1], [ ])
57 ifdef([PHP_ADD_EXTENSION_DEP], [
58 PHP_ADD_EXTENSION_DEP([http], $1, true)
59 ])
60 $2
61 else
62 AC_MSG_RESULT([no])
63 $3
64 fi
65 ])
66
67 dnl
68 dnl HTTP_HAVE_PHP_EXT(name[, code-if-yes[, code-if-not]])
69 dnl
70 AC_DEFUN([HTTP_HAVE_PHP_EXT], [
71 extname=$1
72 haveext=$[PHP_]translit($1,a-z_-,A-Z__)
73 AC_MSG_CHECKING([for ext/$extname support])
74 if test -x "$PHP_EXECUTABLE"; then
75 grepext=`$PHP_EXECUTABLE -m | $EGREP ^$extname\$`
76 if test "$grepext" = "$extname"; then
77 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
78 AC_MSG_RESULT([yes])
79 $2
80 else
81 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
82 AC_MSG_RESULT([no])
83 $3
84 fi
85 elif test "$haveext" != "no" && test "x$haveext" != "x"; then
86 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=1
87 AC_MSG_RESULT([yes])
88 $2
89 else
90 [PHP_HTTP_HAVE_EXT_]translit($1,a-z_-,A-Z__)=
91 AC_MSG_RESULT([no])
92 $3
93 fi
94 ])
95
96
97 dnl ----
98 dnl STDC
99 dnl ----
100 AC_TYPE_OFF_T
101 AC_TYPE_MBSTATE_T
102 dnl getdomainname() is declared in netdb.h on some platforms: AIX, OSF
103 AC_CHECK_HEADERS([netdb.h unistd.h wchar.h wctype.h arpa/inet.h])
104 PHP_CHECK_FUNC(gethostname, nsl)
105 PHP_CHECK_FUNC(getdomainname, nsl)
106 PHP_CHECK_FUNC(mbrtowc)
107 PHP_CHECK_FUNC(mbtowc)
108 PHP_CHECK_FUNC(iswalnum)
109 PHP_CHECK_FUNC(inet_pton)
110
111 dnl ----
112 dnl IDN
113 dnl ----
114
115 AC_MSG_CHECKING([for idna.h])
116 IDNA_DIR=
117 for i in "$PHP_HTTP_LIBIDN_DIR" "$IDN_DIR" /usr/local /usr /opt; do
118 if test -f "$i/include/idna.h"; then
119 IDNA_DIR=$i
120 break;
121 fi
122 done
123 if test "x$IDNA_DIR" = "x"; then
124 AC_MSG_RESULT([not found])
125 else
126 AC_MSG_RESULT([found in $IDNA_DIR])
127 AC_DEFINE([PHP_HTTP_HAVE_IDN], [1], [Have libidn support])
128 PHP_ADD_INCLUDE($IDNA_DIR/include)
129 PHP_ADD_LIBRARY_WITH_PATH(idn, $IDNA_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
130 fi
131
132 dnl ----
133 dnl ZLIB
134 dnl ----
135 AC_MSG_CHECKING([for zlib.h])
136 ZLIB_DIR=
137 for i in "$PHP_HTTP_ZLIB_DIR" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /usr/local /usr /opt; do
138 if test -f "$i/include/zlib.h"; then
139 ZLIB_DIR=$i
140 break;
141 fi
142 done
143 if test "x$ZLIB_DIR" = "x"; then
144 AC_MSG_RESULT([not found])
145 AC_MSG_ERROR([could not find zlib.h])
146 else
147 AC_MSG_RESULT([found in $ZLIB_DIR])
148 AC_MSG_CHECKING([for zlib version >= 1.2.0.4])
149 ZLIB_VERSION=`$EGREP "define ZLIB_VERSION" $ZLIB_DIR/include/zlib.h | $SED -e 's/[[^0-9\.]]//g'`
150 AC_MSG_RESULT([$ZLIB_VERSION])
151 if test `echo $ZLIB_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*1000000 + $2*10000 + $3*100 + $4}'` -lt 1020004; then
152 AC_MSG_ERROR([zlib version greater or equal to 1.2.0.4 required])
153 else
154 PHP_ADD_INCLUDE($ZLIB_DIR/include)
155 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
156 fi
157 fi
158
159 dnl ----
160 dnl CURL
161 dnl ----
162
163 if test "$PHP_HTTP_LIBCURL_DIR" = "no"; then
164 AC_DEFINE([PHP_HTTP_HAVE_CURL], [0], [ ])
165 else
166 AC_MSG_CHECKING([for curl/curl.h])
167 CURL_DIR=
168 for i in "$PHP_HTTP_LIBCURL_DIR" /usr/local /usr /opt; do
169 if test -f "$i/include/curl/curl.h"; then
170 CURL_DIR=$i
171 break
172 fi
173 done
174 if test "x$CURL_DIR" = "x"; then
175 AC_MSG_RESULT([not found])
176 else
177 AC_MSG_RESULT([found in $CURL_DIR])
178
179 AC_MSG_CHECKING([for curl-config])
180 CURL_CONFIG=
181 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
182 if test -x "$i"; then
183 CURL_CONFIG=$i
184 break
185 fi
186 done
187 if test "x$CURL_CONFIG" = "x"; then
188 AC_MSG_RESULT([not found])
189 AC_MSG_ERROR([could not find curl-config])
190 else
191 AC_MSG_RESULT([found: $CURL_CONFIG])
192 fi
193
194 dnl RHEL6: 7.19.7
195 dnl SUSE11: 7.19.7
196 dnl Debian wheezy: 7.26.0
197 dnl Debian sqeeze: 7.21.0
198 dnl Debian ancient 7.18.2
199 AC_MSG_CHECKING([for curl version >= 7.18.2])
200 CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
201 AC_MSG_RESULT([$CURL_VERSION])
202 if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71802; then
203 AC_MSG_ERROR([libcurl version greater or equal to 7.18.2 required])
204 fi
205
206 dnl
207 dnl compile tests
208 dnl
209
210 save_INCLUDES="$INCLUDES"
211 INCLUDES=
212 save_LIBS="$LIBS"
213 LIBS=
214 save_CFLAGS="$CFLAGS"
215 CFLAGS="$CFLAGS `$CURL_CONFIG --cflags`"
216 save_LDFLAGS="$LDFLAGS"
217 LDFLAGS="$LDFLAGS `$CURL_CONFIG --libs` $ld_runpath_switch$CURL_DIR/$PHP_LIBDIR"
218
219 AC_MSG_CHECKING([for SSL support in libcurl])
220 CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
221 CURL_SSL_LIBS=""
222 if test "$CURL_SSL" = "SSL"; then
223 AC_MSG_RESULT([yes])
224 AC_DEFINE([PHP_HTTP_HAVE_SSL], [1], [ ])
225
226 AC_MSG_CHECKING([for openssl support in libcurl])
227 AC_TRY_RUN([
228 #include <curl/curl.h>
229 int main(int argc, char *argv[]) {
230 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
231 if (data && data->ssl_version && *data->ssl_version) {
232 const char *ptr = data->ssl_version;
233 while(*ptr == ' ') ++ptr;
234 return strncasecmp(ptr, "OpenSSL", sizeof("OpenSSL")-1);
235 }
236 return 1;
237 }
238 ], [
239 AC_MSG_RESULT([yes])
240 AC_CHECK_HEADER([openssl/ssl.h], [
241 AC_CHECK_HEADER([openssl/crypto.h], [
242 AC_DEFINE([PHP_HTTP_HAVE_OPENSSL], [1], [ ])
243 CURL_SSL_LIBS="ssl crypto"
244 ])
245 ])
246 ], [
247 AC_MSG_RESULT([no])
248 ], [
249 AC_MSG_RESULT([no])
250 ])
251
252 AC_MSG_CHECKING([for gnutls support in libcurl])
253 AC_TRY_RUN([
254 #include <curl/curl.h>
255 int main(int argc, char *argv[]) {
256 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
257 if (data && data->ssl_version && *data->ssl_version) {
258 const char *ptr = data->ssl_version;
259 while(*ptr == ' ') ++ptr;
260 return strncasecmp(ptr, "GnuTLS", sizeof("GnuTLS")-1);
261 }
262 return 1;
263 }
264 ], [
265 AC_MSG_RESULT([yes])
266 AC_CHECK_HEADER([gnutls.h], [
267 AC_CHECK_HEADER([gcrypt.h], [
268 AC_DEFINE([PHP_HTTP_HAVE_GNUTLS], [1], [ ])
269 CURL_SSL_LIBS="gnutls gcrypt"
270 ])
271 ])
272 ], [
273 AC_MSG_RESULT([no])
274 ], [
275 AC_MSG_RESULT([no])
276 ])
277 else
278 AC_MSG_RESULT([no])
279 fi
280
281 AC_MSG_CHECKING([for ares support in libcurl])
282 AC_TRY_RUN([
283 #include <curl/curl.h>
284 int main(int argc, char *argv[]) {
285 curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
286 if (data && data->ares && data->ares_num0) {
287 return 0;
288 }
289 return 1;
290 }
291 ], [
292 AC_MSG_RESULT([yes])
293 AC_DEFINE([PHP_HTTP_HAVE_ARES], [1], [ ])
294 ], [
295 AC_MSG_RESULT([no])
296 ], [
297 AC_MSG_RESULT([no])
298 ])
299
300 INCLUDES="$save_INCLUDES"
301 LIBS="$save_LIBS"
302 CFLAGS="$save_CFLAGS"
303 LDFLAGS="$save_LDFLAGS"
304
305 if test -n "$CURL_SSL_LIBS"; then
306 for CURL_SSL_LIB in $CURL_SSL_LIBS; do
307 PHP_ADD_LIBRARY_WITH_PATH([$CURL_SSL_LIB], $CURL_DIR/$PHP_LIBDIR, PHP_HTTP_SHARED_LIBADD)
308 done
309 fi
310
311 dnl end compile tests
312
313 AC_MSG_CHECKING([for bundled SSL CA info])
314 CURL_CAINFO=
315 for i in `$CURL_CONFIG --ca` "/etc/ssl/certs/ca-certificates.crt" "/etc/ssl/certs/ca-bundle.crt"; do
316 if test -f "$i"; then
317 CURL_CAINFO="$i"
318 break
319 fi
320 done
321 if test "x$CURL_CAINFO" = "x"; then
322 AC_MSG_RESULT([not found])
323 else
324 AC_MSG_RESULT([$CURL_CAINFO])
325 AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAINFO], ["$CURL_CAINFO"], [path to bundled SSL CA info])
326 fi
327
328 PHP_ADD_INCLUDE($CURL_DIR/include)
329 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
330 PHP_EVAL_LIBLINE(`$CURL_CONFIG --libs`, HTTP_SHARED_LIBADD)
331 AC_DEFINE([PHP_HTTP_HAVE_CURL], [1], [Have libcurl support])
332 HTTP_HAVE_A_REQUEST_LIB=true
333 fi
334 fi
335
336 dnl ----
337 dnl EVENT
338 dnl ----
339
340 if test "$PHP_HTTP_LIBEVENT_DIR" = "no"; then
341 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
342 else
343 AC_MSG_CHECKING([for event2/event.h])
344 EVENT_DIR=
345 for i in "$PHP_HTTP_LIBEVENT_DIR" /usr/local /usr /opt; do
346 if test -f "$i/include/event.h"; then
347 EVENT_DIR=$i
348 break
349 fi
350 done
351 if test "x$EVENT_DIR" = "x"; then
352 AC_MSG_RESULT([not found])
353 AC_MSG_WARN([continuing without libevent support])
354 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [0], [ ])
355 else
356 AC_MSG_RESULT([found in $EVENT_DIR])
357
358 AC_MSG_CHECKING([for libevent version, roughly])
359
360 if test -f "$EVENT_DIR/include/event2/event.h"; then
361 EVENT_VER="`$AWK '/_EVENT_VERSION/ {gsub(/\"/,\"\",$3); print $3}' < $EVENT_DIR/include/event2/event-config.h`"
362 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [1], [ ])
363 else
364 AC_DEFINE([PHP_HTTP_HAVE_EVENT2], [0], [ ])
365 if test -f "$EVENT_DIR/include/evhttp.h" && test -f "$EVENT_DIR/include/evdns.h"; then
366 if test -f "$EVENT_DIR/include/evrpc.h"; then
367 EVENT_VER="1.4 or greater"
368 else
369 EVENT_VER="1.2 or greater"
370 fi
371 else
372 EVENT_VER="1.1b or lower"
373 fi
374 fi
375 AC_DEFINE_UNQUOTED([PHP_HTTP_EVENT_VERSION], ["$EVENT_VER"], [ ])
376 AC_MSG_RESULT([$EVENT_VER])
377
378 PHP_ADD_INCLUDE($EVENT_DIR/include)
379 PHP_ADD_LIBRARY_WITH_PATH(event, $EVENT_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
380 AC_DEFINE([PHP_HTTP_HAVE_EVENT], [1], [Have libevent support for cURL])
381 fi
382 fi
383
384 dnl ----
385 dnl RAPHF
386 dnl ----
387 HTTP_HAVE_PHP_EXT([raphf], [
388 AC_MSG_CHECKING([for php_raphf.h])
389 HTTP_EXT_RAPHF_INCDIR=
390 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../raphf; do
391 if test -d $i; then
392 if test -f $i/php_raphf.h; then
393 HTTP_EXT_RAPHF_INCDIR=$i
394 break
395 elif test -f $i/ext/raphf/php_raphf.h; then
396 HTTP_EXT_RAPHF_INCDIR=$i/ext/raphf
397 break
398 fi
399 fi
400 done
401 if test "x$HTTP_EXT_RAPHF_INCDIR" = "x"; then
402 AC_MSG_ERROR([not found])
403 else
404 AC_MSG_RESULT([$HTTP_EXT_RAPHF_INCDIR])
405 AC_DEFINE([PHP_HTTP_HAVE_PHP_RAPHF_H], [1], [Have ext/raphf support])
406 PHP_ADD_INCLUDE([$HTTP_EXT_RAPHF_INCDIR])
407 fi
408 ], [
409 AC_MSG_ERROR([Please install pecl/raphf and activate extension=raphf.$SHLIB_DL_SUFFIX_NAME in your php.ini])
410 ])
411
412 dnl ----
413 dnl PROPRO
414 dnl ----
415 HTTP_HAVE_PHP_EXT([propro], [
416 AC_MSG_CHECKING([for php_propro.h])
417 HTTP_EXT_PROPRO_INCDIR=
418 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../propro; do
419 if test -d $i; then
420 if test -f $i/php_propro.h; then
421 HTTP_EXT_PROPRO_INCDIR=$i
422 break
423 elif test -f $i/ext/propro/php_propro.h; then
424 HTTP_EXT_PROPRO_INCDIR=$i/ext/propro
425 break
426 fi
427 fi
428 done
429 if test "x$HTTP_EXT_PROPRO_INCDIR" = "x"; then
430 AC_MSG_ERROR([not found])
431 else
432 AC_MSG_RESULT([$HTTP_EXT_PROPRO_INCDIR])
433 AC_DEFINE([PHP_HTTP_HAVE_PHP_PROPRO_H], [1], [Have ext/propro support])
434 PHP_ADD_INCLUDE([$HTTP_EXT_PROPRO_INCDIR])
435 fi
436 ], [
437 AC_MSG_ERROR([Please install pecl/propro and activate extension=propro.$SHLIB_DL_SUFFIX_NAME in your php.ini])
438 ])
439
440 PHP_ARG_WITH([http-shared-deps], [whether to depend on extensions which have been built shared],
441 [ --without-http-shared-deps HTTP: do not depend on extensions like hash
442 and iconv (when they are built shared)], $PHP_HTTP, $PHP_HTTP)
443 dnl ----
444 dnl HASH
445 dnl ----
446 HTTP_HAVE_PHP_EXT([hash], [
447 AC_MSG_CHECKING([for php_hash.h])
448 HTTP_EXT_HASH_INCDIR=
449 for i in `echo $INCLUDES | $SED -e's/-I//g'` $abs_srcdir ../hash; do
450 if test -d $i; then
451 if test -f $i/php_hash.h; then
452 HTTP_EXT_HASH_INCDIR=$i
453 break
454 elif test -f $i/ext/hash/php_hash.h; then
455 HTTP_EXT_HASH_INCDIR=$i/ext/hash
456 break
457 fi
458 fi
459 done
460 if test "x$HTTP_EXT_HASH_INCDIR" = "x"; then
461 AC_MSG_RESULT([not found])
462 else
463 AC_MSG_RESULT([$HTTP_EXT_HASH_INCDIR])
464 AC_DEFINE([PHP_HTTP_HAVE_PHP_HASH_H], [1], [Have ext/hash support])
465 PHP_ADD_INCLUDE([$HTTP_EXT_HASH_INCDIR])
466 fi
467 ])
468
469 dnl ----
470 dnl JSON
471 dnl ----
472 HTTP_HAVE_PHP_EXT([json])
473
474
475 dnl ----
476 dnl ICONV
477 dnl ----
478 HTTP_HAVE_PHP_EXT([iconv])
479
480 dnl ----
481 dnl DONE
482 dnl ----
483 PHP_HTTP_SOURCES="\
484 php_http_buffer.c \
485 php_http.c \
486 php_http_client.c \
487 php_http_client_curl.c \
488 php_http_client_request.c \
489 php_http_client_response.c \
490 php_http_cookie.c \
491 php_http_curl.c \
492 php_http_encoding.c \
493 php_http_env.c \
494 php_http_env_request.c \
495 php_http_env_response.c \
496 php_http_etag.c \
497 php_http_exception.c \
498 php_http_filter.c \
499 php_http_header_parser.c \
500 php_http_header.c \
501 php_http_info.c \
502 php_http_message_body.c \
503 php_http_message.c \
504 php_http_message_parser.c \
505 php_http_misc.c \
506 php_http_negotiate.c \
507 php_http_object.c \
508 php_http_options.c \
509 php_http_params.c \
510 php_http_querystring.c \
511 php_http_strlist.c \
512 php_http_url.c \
513 php_http_version.c \
514 "
515 PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
516
517 dnl shared extension deps
518 HTTP_SHARED_DEP([hash])
519 HTTP_SHARED_DEP([iconv])
520 HTTP_SHARED_DEP([json])
521
522 dnl extension deps
523 PHP_ADD_EXTENSION_DEP([http], [raphf], true)
524 PHP_ADD_EXTENSION_DEP([http], [propo], true)
525
526 PHP_SUBST([HTTP_SHARED_LIBADD])
527
528 PHP_HTTP_HEADERS="
529 php_http_api.h \
530 php_http_buffer.h \
531 php_http_curl_client.h \
532 php_http_curl_client_datashare.h \
533 php_http_client_datashare.h \
534 php_http_client_factory.h \
535 php_http_client.h \
536 php_http_client_interface.h \
537 php_http_curl_client_pool.h \
538 php_http_client_pool.h \
539 php_http_client_request.h \
540 php_http_client_response.h \
541 php_http_cookie.h \
542 php_http_curl.h \
543 php_http_encoding.h \
544 php_http_env.h \
545 php_http_env_request.h \
546 php_http_env_response.h \
547 php_http_etag.h \
548 php_http_exception.h \
549 php_http_filter.h \
550 php_http.h \
551 php_http_header_parser.h \
552 php_http_header.h \
553 php_http_info.h \
554 php_http_message_body.h \
555 php_http_message.h \
556 php_http_message_parser.h \
557 php_http_misc.h \
558 php_http_negotiate.h \
559 php_http_object.h \
560 php_http_options.h \
561 php_http_params.h \
562 php_http_querystring.h \
563 php_http_strlist.h \
564 php_http_url.h \
565 php_http_version.h \
566 "
567 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
568
569 AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
570 fi
Extended HTTP Support