git.m6w6.name Git - m6w6/ext-http/blob - config.m4

   1 dnl config.m4 for pecl/http
   2 dnl $Id$
   3 dnl vim: noet ts=1 sw=1
   4
   5 PHP_ARG_ENABLE([http], [whether to enable extended HTTP support],
   6 [  --enable-http           Enable extended HTTP support])
   7 PHP_ARG_WITH([http-curl-requests], [whether to enable cURL HTTP requests],
   8 [  --with-http-curl-requests[=CURLDIR]
   9                            With cURL HTTP request support])
  10 PHP_ARG_WITH([http-magic-mime], [whether to enable response content type guessing],
  11 [  --with-http-magic-mime[=MAGICDIR]
  12                            With magic mime response content type guessing])
  13 PHP_ARG_WITH([http-zlib-compression], [whether to enable support for gzencoded/deflated message bodies],
  14 [  --with-http-zlib-compression[=ZLIBDIR]
  15                            With zlib gzdecode and inflate support])
  16
  17 if test "$PHP_HTTP" != "no"; then
  18
  19 dnl -------
  20 dnl NETDB.H
  21 dnl -------
  22         AC_CHECK_HEADERS([netdb.h])
  23
  24 dnl ----
  25 dnl ZLIB
  26 dnl ----
  27         AC_MSG_CHECKING([for zlib.h])
  28         ZLIB_DIR=
  29         for i in "$PHP_HTTP_ZLIB_COMPRESSION" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /user/local /usr /opt; do
  30                 if test -f "$i/include/zlib.h"; then
  31                         ZLIB_DIR=$i
  32                         break;
  33                 fi
  34         done
  35         if test -z "$ZLIB_DIR"; then
  36                 AC_MSG_RESULT([not found])
  37                 AC_MSG_WARN([gzip support not enabled; zlib.h not found])
  38         else
  39                 AC_MSG_RESULT([found in $ZLIB_DIR])
  40                 PHP_ADD_INCLUDE($ZLIB_DIR/include)
  41                 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
  42                 AC_DEFINE([HTTP_HAVE_ZLIB], [1], [Have zlib support])
  43         fi
  44
  45 dnl ----
  46 dnl CURL
  47 dnl ----
  48         if test "$PHP_HTTP_CURL_REQUESTS" != "no"; then
  49
  50                 AC_MSG_CHECKING([for curl/curl.h])
  51                 CURL_DIR=
  52                 for i in "$PHP_HTTP_CURL_REQUESTS" /usr/local /usr /opt; do
  53                         if test -f "$i/include/curl/curl.h"; then
  54                                 CURL_DIR=$i
  55                                 break
  56                         fi
  57                 done
  58                 if test -z "$CURL_DIR"; then
  59                         AC_MSG_RESULT([not found])
  60                         AC_MSG_ERROR([could not find curl/curl.h])
  61                 else
  62                         AC_MSG_RESULT([found in $CURL_DIR])
  63                 fi
  64
  65                 AC_MSG_CHECKING([for curl-config])
  66                 CURL_CONFIG=
  67                 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
  68                         if test -x "$i"; then
  69                                 CURL_CONFIG=$i
  70                                 break
  71                         fi
  72                 done
  73                 if test -z "$CURL_CONFIG"; then
  74                         AC_MSG_RESULT([not found])
  75                         AC_MSG_ERROR([could not find curl-config])
  76                 else
  77                         AC_MSG_RESULT([found: $CURL_CONFIG])
  78                 fi
  79
  80                 CURL_LIBS=`$CURL_CONFIG --libs`
  81
  82                 CURL_ZLIB=`$CURL_CONFIG --features | $EGREP libz`
  83                 if test "$CURL_ZLIB" = "libz"; then
  84                         AC_DEFINE([HTTP_HAVE_CURL_ZLIB], [1], [ ])
  85                 fi
  86
  87                 AC_MSG_CHECKING([for SSL support in libcurl])
  88                 CURL_SSL=`$CURL_CONFIG --features | $EGREP SSL`
  89                 if test "$CURL_SSL" = "SSL"; then
  90                         AC_MSG_RESULT([yes])
  91                         AC_DEFINE([HTTP_HAVE_SSL], [1], [ ])
  92
  93                         AC_MSG_CHECKING([for SSL library used])
  94                         CURL_SSL_FLAVOUR=
  95                         for i in $CURL_LIBS; do
  96                                 if test "$i" = "-lssl"; then
  97                                         CURL_SSL_FLAVOUR="openssl"
  98                                         AC_MSG_RESULT([openssl])
  99                                         AC_DEFINE([HTTP_HAVE_OPENSSL], [1], [ ])
 100                                         AC_CHECK_HEADERS([openssl/crypto.h])
 101                                         break
 102                                 elif test "$i" = "-lgnutls"; then
 103                                         CURL_SSL_FLAVOUR="gnutls"
 104                                         AC_MSG_RESULT([gnutls])
 105                                         AC_DEFINE([HTTP_HAVE_GNUTLS], [1], [ ])
 106                                         AC_CHECK_HEADERS([gcrypt.h])
 107                                         break
 108                                 fi
 109                         done
 110                         if test -z "$CURL_SSL_FLAVOUR"; then
 111                                 AC_MSG_RESULT([unknown!])
 112                                 AC_MSG_WARN([Could not determine the type of SSL library used!])
 113                                 AC_MSG_WARN([Building will fail in ZTS mode!])
 114                         fi
 115                 else
 116                         AC_MSG_RESULT([no])
 117                 fi
 118
 119                 PHP_ADD_INCLUDE($CURL_DIR/include)
 120                 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 121                 PHP_EVAL_LIBLINE($CURL_LIBS, HTTP_SHARED_LIBADD)
 122                 AC_DEFINE([HTTP_HAVE_CURL], [1], [Have cURL support])
 123
 124                 PHP_CHECK_LIBRARY(curl, curl_multi_strerror,
 125                         [AC_DEFINE([HAVE_CURL_MULTI_STRERROR], [1], [ ])], [ ],
 126                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 127                 )
 128                 PHP_CHECK_LIBRARY(curl, curl_easy_strerror,
 129                         [AC_DEFINE([HAVE_CURL_EASY_STRERROR], [1], [ ])], [ ],
 130                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 131                 )
 132                 PHP_CHECK_LIBRARY(curl, curl_easy_reset,
 133                         [AC_DEFINE([HAVE_CURL_EASY_RESET], [1], [ ])], [ ],
 134                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 135                 )
 136         fi
 137
 138 dnl ----
 139 dnl MAGIC
 140 dnl ----
 141         if test "$PHP_HTTP_MAGIC_MIME" != "no"; then
 142
 143                 AC_MSG_CHECKING([for magic.h])
 144                 MAGIC_DIR=
 145                 for i in "$PHP_HTTP_MAGIC_MIME" /usr/local /usr /opt; do
 146                         if test -f "$i/include/magic.h"; then
 147                                 MAGIC_DIR=$i
 148                                 break
 149                         fi
 150                 done
 151                 if test -z "$MAGIC_DIR"; then
 152                         AC_MSG_RESULT([not found])
 153                         AC_MSG_ERROR([could not find magic.h])
 154                 else
 155                         AC_MSG_RESULT([found in $MAGIC_DIR])
 156                 fi
 157
 158                 PHP_ADD_INCLUDE($MAGIC_DIR/include)
 159                 PHP_ADD_LIBRARY_WITH_PATH(magic, $MAGIC_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 160                 AC_DEFINE([HTTP_HAVE_MAGIC], [1], [Have magic mime support])
 161         fi
 162
 163 dnl ----
 164 dnl HASH
 165 dnl ----
 166
 167         AC_MSG_CHECKING(for ext/hash support)
 168         if test -x "$PHP_EXECUTABLE"; then
 169                 if test "`$PHP_EXECUTABLE -m | $EGREP '^hash$'`" = "hash"; then
 170                         if test -d ../hash; then
 171                                 PHP_ADD_INCLUDE([../hash])
 172                         fi
 173                         old_CPPFLAGS=$CPPFLAGS
 174                         CPPFLAGS=$INCLUDES
 175                         AC_MSG_RESULT([looking for php_hash.h])
 176                         AC_CHECK_HEADER([ext/hash/php_hash.h], [
 177                                 AC_DEFINE([HTTP_HAVE_EXT_HASH_EXT_HASH], [1], [Have ext/hash support])
 178                         ], [
 179                                 AC_CHECK_HEADER([hash/php_hash.h], [
 180                                         AC_DEFINE([HTTP_HAVE_HASH_EXT_HASH], [1], [Have ext/hash support])
 181                                 ], [
 182                         AC_CHECK_HEADER([php_hash.h], [
 183                                 AC_DEFINE([HTTP_HAVE_EXT_HASH], [1], [Have ext/hash support])
 184                                         ])
 185                                 ])
 186                         ])
 187                         CPPFLAGS=$old_CPPFLAGS;
 188                 else
 189                         AC_MSG_RESULT(disabled)
 190                 fi
 191         elif test "$PHP_HASH" != "no" && test "x$PHP_HASH" != "x"; then
 192                 AC_MSG_RESULT(enabled)
 193                 ifdef([PHP_ADD_EXTENSION_DEP], [
 194                         PHP_ADD_EXTENSION_DEP([http], [hash], 0)
 195                         AC_DEFINE([HTTP_HAVE_EXT_HASH_EXT_HASH], [1], [Have ext/hash support])
 196                 ])
 197         else
 198                 AC_MSG_RESULT(disabled)
 199         fi
 200
 201 dnl ----
 202 dnl DONE
 203 dnl ----
 204         PHP_HTTP_SOURCES="missing.c http.c http_functions.c phpstr/phpstr.c \
 205                 http_util_object.c http_message_object.c http_request_object.c http_request_pool_api.c \
 206                 http_response_object.c http_exception_object.c http_requestpool_object.c \
 207                 http_api.c http_cache_api.c http_request_api.c http_date_api.c \
 208                 http_headers_api.c http_message_api.c http_send_api.c http_url_api.c \
 209                 http_info_api.c http_request_method_api.c http_encoding_api.c \
 210                 http_filter_api.c"
 211         PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
 212         PHP_ADD_BUILD_DIR($ext_builddir/phpstr, 1)
 213         PHP_SUBST([HTTP_SHARED_LIBADD])
 214
 215         PHP_HTTP_HEADERS="php_http_std_defs.h php_http.h php_http_api.h php_http_cache_api.h \
 216                 php_http_date_api.h php_http_headers_api.h php_http_info_api.h php_http_message_api.h \
 217                 php_http_request_api.h php_http_request_method_api.h php_http_send_api.h php_http_url_api.h \
 218                 php_http_encoding_api.h phpstr/phpstr.h missing.h"
 219
 220         ifdef([PHP_INSTALL_HEADERS], [
 221                 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
 222         ], [
 223                 PHP_SUBST([PHP_HTTP_HEADERS])
 224                 PHP_ADD_MAKEFILE_FRAGMENT
 225         ])
 226
 227         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 228 fi