git.m6w6.name Git - m6w6/ext-http/blob - config.m4

   1 dnl config.m4 for pecl/http
   2 dnl $Id$
   3 dnl vim: noet ts=1 sw=1
   4
   5 PHP_ARG_ENABLE([http], [whether to enable extended HTTP support],
   6 [  --enable-http           Enable extended HTTP support])
   7 PHP_ARG_WITH([http-curl-requests], [whether to enable cURL HTTP requests],
   8 [  --with-http-curl-requests[=CURLDIR]
   9                            With cURL HTTP request support])
  10 PHP_ARG_WITH([http-magic-mime], [whether to enable response content type guessing],
  11 [  --with-http-magic-mime[=MAGICDIR]
  12                            With magic mime response content type guessing])
  13 PHP_ARG_WITH([http-zlib-compression], [whether to enable support for gzencoded/deflated message bodies],
  14 [  --with-http-zlib-compression[=ZLIBDIR]
  15                            With zlib gzdecode and inflate support])
  16
  17 if test "$PHP_HTTP" != "no"; then
  18
  19 dnl -------
  20 dnl NETDB.H
  21 dnl -------
  22         AC_CHECK_HEADERS([netdb.h])
  23
  24 dnl ----
  25 dnl ZLIB
  26 dnl ----
  27         AC_MSG_CHECKING([for zlib.h])
  28         ZLIB_DIR=
  29         for i in "$PHP_HTTP_ZLIB_COMPRESSION" "$PHP_ZLIB_DIR" "$PHP_ZLIB" /user/local /usr /opt; do
  30                 if test -f "$i/include/zlib.h"; then
  31                         ZLIB_DIR=$i
  32                         break;
  33                 fi
  34         done
  35         if test -z "$ZLIB_DIR"; then
  36                 AC_MSG_RESULT([not found])
  37                 AC_MSG_WARN([gzip support not enabled; zlib.h not found])
  38         else
  39                 AC_MSG_RESULT([found in $ZLIB_DIR])
  40                 PHP_ADD_INCLUDE($ZLIB_DIR/include)
  41                 PHP_ADD_LIBRARY_WITH_PATH(z, $ZLIB_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
  42                 AC_DEFINE([HTTP_HAVE_ZLIB], [1], [Have zlib support])
  43         fi
  44
  45 dnl ----
  46 dnl CURL
  47 dnl ----
  48         if test "$PHP_HTTP_CURL_REQUESTS" != "no"; then
  49
  50                 AC_MSG_CHECKING([for curl/curl.h])
  51                 CURL_DIR=
  52                 for i in "$PHP_HTTP_CURL_REQUESTS" /usr/local /usr /opt; do
  53                         if test -f "$i/include/curl/curl.h"; then
  54                                 CURL_DIR=$i
  55                                 break
  56                         fi
  57                 done
  58                 if test -z "$CURL_DIR"; then
  59                         AC_MSG_RESULT([not found])
  60                         AC_MSG_ERROR([could not find curl/curl.h])
  61                 else
  62                         AC_MSG_RESULT([found in $CURL_DIR])
  63                 fi
  64
  65                 AC_MSG_CHECKING([for curl-config])
  66                 CURL_CONFIG=
  67                 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
  68                         if test -x "$i"; then
  69                                 CURL_CONFIG=$i
  70                                 break
  71                         fi
  72                 done
  73                 if test -z "$CURL_CONFIG"; then
  74                         AC_MSG_RESULT([not found])
  75                         AC_MSG_ERROR([could not find curl-config])
  76                 else
  77                         AC_MSG_RESULT([found: $CURL_CONFIG])
  78                 fi
  79
  80                 CURL_LIBS=`$CURL_CONFIG --libs`
  81
  82                 AC_MSG_CHECKING([for SSL support in libcurl])
  83                 CURL_SSL=`$CURL_CONFIG --features | $EGREP SSL`
  84                 if test "$CURL_SSL" = "SSL"; then
  85                         AC_MSG_RESULT([yes])
  86                         AC_DEFINE([HTTP_HAVE_SSL], [1], [ ])
  87
  88                         AC_MSG_CHECKING([for SSL library used])
  89                         CURL_SSL_FLAVOUR=
  90                         for i in $CURL_LIBS; do
  91                                 if test "$i" = "-lssl"; then
  92                                         CURL_SSL_FLAVOUR="openssl"
  93                                         AC_MSG_RESULT([openssl])
  94                                         AC_DEFINE([HTTP_HAVE_OPENSSL], [1], [ ])
  95                                         AC_CHECK_HEADERS([openssl/crypto.h])
  96                                         break
  97                                 elif test "$i" = "-lgnutls"; then
  98                                         CURL_SSL_FLAVOUR="gnutls"
  99                                         AC_MSG_RESULT([gnutls])
 100                                         AC_DEFINE([HTTP_HAVE_GNUTLS], [1], [ ])
 101                                         AC_CHECK_HEADERS([gcrypt.h])
 102                                         break
 103                                 fi
 104                         done
 105                         if test -z "$CURL_SSL_FLAVOUR"; then
 106                                 AC_MSG_RESULT([unknown!])
 107                                 AC_MSG_WARN([Could not determine the type of SSL library used!])
 108                                 AC_MSG_WARN([Building will fail in ZTS mode!])
 109                         fi
 110                 else
 111                         AC_MSG_RESULT([no])
 112                 fi
 113
 114                 PHP_ADD_INCLUDE($CURL_DIR/include)
 115                 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 116                 PHP_EVAL_LIBLINE($CURL_LIBS, HTTP_SHARED_LIBADD)
 117                 AC_DEFINE([HTTP_HAVE_CURL], [1], [Have cURL support])
 118
 119                 PHP_CHECK_LIBRARY(curl, curl_multi_strerror,
 120                         [AC_DEFINE([HAVE_CURL_MULTI_STRERROR], [1], [ ])], [ ],
 121                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 122                 )
 123                 PHP_CHECK_LIBRARY(curl, curl_easy_strerror,
 124                         [AC_DEFINE([HAVE_CURL_EASY_STRERROR], [1], [ ])], [ ],
 125                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 126                 )
 127                 PHP_CHECK_LIBRARY(curl, curl_easy_reset,
 128                         [AC_DEFINE([HAVE_CURL_EASY_RESET], [1], [ ])], [ ],
 129                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
 130                 )
 131         fi
 132
 133 dnl ----
 134 dnl MAGIC
 135 dnl ----
 136         if test "$PHP_HTTP_MAGIC_MIME" != "no"; then
 137
 138                 AC_MSG_CHECKING([for magic.h])
 139                 MAGIC_DIR=
 140                 for i in "$PHP_HTTP_MAGIC_MIME" /usr/local /usr /opt; do
 141                         if test -f "$i/include/magic.h"; then
 142                                 MAGIC_DIR=$i
 143                                 break
 144                         fi
 145                 done
 146                 if test -z "$MAGIC_DIR"; then
 147                         AC_MSG_RESULT([not found])
 148                         AC_MSG_ERROR([could not find magic.h])
 149                 else
 150                         AC_MSG_RESULT([found in $MAGIC_DIR])
 151                 fi
 152
 153                 PHP_ADD_INCLUDE($MAGIC_DIR/include)
 154                 PHP_ADD_LIBRARY_WITH_PATH(magic, $MAGIC_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 155                 AC_DEFINE([HTTP_HAVE_MAGIC], [1], [Have magic mime support])
 156         fi
 157
 158 dnl ----
 159 dnl HASH
 160 dnl ----
 161
 162         AC_MSG_CHECKING(for ext/hash support)
 163         if test -x "$PHP_EXECUTABLE"; then
 164                 if test "`$PHP_EXECUTABLE -m | $EGREP '^hash$'`" = "hash"; then
 165                         if test -d ../hash; then
 166                                 PHP_ADD_INCLUDE([../hash])
 167                         fi
 168                         old_CPPFLAGS=$CPPFLAGS
 169                         CPPFLAGS=$INCLUDES
 170                         AC_CHECK_HEADER([php_hash.h], [
 171                                 AC_MSG_RESULT(enabled)
 172                                 AC_DEFINE([HTTP_HAVE_EXT_HASH], [1], [Have ext/hash support])
 173                         ], [
 174                                 AC_CHECK_HEADER([hash/php_hash.h], [
 175                                         AC_MSG_RESULT(enabled)
 176                                         AC_DEFINE([HTTP_HAVE_HASH_EXT_HASH], [1], [Have ext/hash support])
 177                                 ], [
 178                                         AC_CHECK_HEADER([ext/hash/php_hash.h], [
 179                                          AC_MSG_RESULT(enabled)
 180                                                 AC_DEFINE([HTTP_HAVE_EXT_HASH_EXT_HASH], [1], [Have ext/hash support])
 181                                         ], [
 182                                                 AC_MSG_RESULT(disabled)
 183                                         ])
 184                                 ])
 185                         ])
 186                         CPPFLAGS=$old_CPPFLAGS;
 187                 fi
 188         elif test "$PHP_HASH" != "no" && test "x$PHP_HASH" != "x"; then
 189                 AC_MSG_RESULT(enabled)
 190                 ifdef([PHP_ADD_EXTENSION_DEP], [
 191                         PHP_ADD_EXTENSION_DEP([http], [hash], 0)
 192                         AC_DEFINE([HTTP_HAVE_EXT_HASH_EXT_HASH], [1], [Have ext/hash support])
 193                 ])
 194         else
 195                 AC_MSG_RESULT(disabled)
 196         fi
 197
 198 dnl ----
 199 dnl DONE
 200 dnl ----
 201         PHP_HTTP_SOURCES="missing.c http.c http_functions.c phpstr/phpstr.c \
 202                 http_util_object.c http_message_object.c http_request_object.c http_request_pool_api.c \
 203                 http_response_object.c http_exception_object.c http_requestpool_object.c \
 204                 http_api.c http_cache_api.c http_request_api.c http_date_api.c \
 205                 http_headers_api.c http_message_api.c http_send_api.c http_url_api.c \
 206                 http_info_api.c http_request_method_api.c http_encoding_api.c \
 207                 http_filter_api.c"
 208         PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, $ext_shared)
 209         PHP_ADD_BUILD_DIR($ext_builddir/phpstr, 1)
 210         PHP_SUBST([HTTP_SHARED_LIBADD])
 211
 212         PHP_HTTP_HEADERS="php_http_std_defs.h php_http.h php_http_api.h php_http_cache_api.h \
 213                 php_http_date_api.h php_http_headers_api.h php_http_info_api.h php_http_message_api.h \
 214                 php_http_request_api.h php_http_request_method_api.h php_http_send_api.h php_http_url_api.h \
 215                 php_http_encoding_api.h phpstr/phpstr.h missing.h"
 216
 217         ifdef([PHP_INSTALL_HEADERS], [
 218                 PHP_INSTALL_HEADERS(ext/http, $PHP_HTTP_HEADERS)
 219         ], [
 220                 PHP_SUBST([PHP_HTTP_HEADERS])
 221                 PHP_ADD_MAKEFILE_FRAGMENT
 222         ])
 223
 224         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 225 fi