git.m6w6.name Git - m6w6/ext-http/blob - config.m4

   1 dnl config.m4 for pecl/http
   2 dnl $Id$
   3
   4 PHP_ARG_ENABLE([http], [whether to enable extended HTTP support],
   5 [  --enable-http           Enable extended HTTP support])
   6 PHP_ARG_WITH([http-curl-requests], [wheter to enable cURL HTTP requests],
   7 [  --with-http-curl-requests[=CURLDIR]
   8                            With cURL HTTP request support])
   9 PHP_ARG_WITH([http-mhash-etags], [whether to enable mhash ETag generator],
  10 [  --with-http-mhash-etags[=MHASHDIR]
  11                            With mhash ETag generator support])
  12 PHP_ARG_WITH([http-magic-mime], [whether to enable response content type guessing],
  13 [  --with-http-magic-mime[=MAGICDIR]
  14                            With magic mime response content type guessing])
  15
  16 if test "$PHP_HTTP" != "no"; then
  17
  18 dnl -------
  19 dnl NETDB.H
  20 dnl -------
  21         AC_MSG_CHECKING(for netdb.h)
  22         if test -r /usr/include/netdb.h -o -r /usr/local/include/netdb.h; then
  23                 AC_DEFINE(HAVE_NETDB_H, 1, [Have netdb.h])
  24                 AC_MSG_RESULT(found in default path)
  25         else
  26                 AC_MSG_RESULT(not found in default path)
  27         fi
  28
  29 dnl ----
  30 dnl CURL
  31 dnl ----
  32         if test "$PHP_HTTP_CURL_REQUESTS" != "no"; then
  33
  34                 AC_MSG_CHECKING([for curl/curl.h])
  35                 CURL_DIR=
  36                 for i in "$PHP_HTTP_CURL_REQUESTS" /usr/local /usr /opt; do
  37                         if test -r "$i/include/curl/curl.h"; then
  38                                 CURL_DIR=$i
  39                                 break
  40                         fi
  41                 done
  42                 if test -z "$CURL_DIR"; then
  43                         AC_MSG_RESULT([not found])
  44                         AC_MSG_ERROR([could not find curl/curl.h])
  45                 else
  46                         AC_MSG_RESULT([found in $CURL_DIR])
  47                 fi
  48
  49                 AC_MSG_CHECKING([for curl-config])
  50                 CURL_CONFIG=
  51                 for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
  52                         if test -x "$i"; then
  53                                 CURL_CONFIG=$i
  54                                 break
  55                         fi
  56                 done
  57                 if test -z "$CURL_CONFIG"; then
  58                         AC_MSG_RESULT([not found])
  59                         AC_MSG_ERROR([could not find curl-config])
  60                 else
  61                         AC_MSG_RESULT([found: $CURL_CONFIG])
  62                 fi
  63
  64                 CURL_SSL=`$CURL_CONFIG --features | $EGREP SSL`
  65                 if test "$CURL_SSL" == "SSL"; then
  66                         AC_DEFINE([HTTP_HAVE_SSL], [1], [ ])
  67                 fi
  68                 AC_CHECK_HEADERS([openssl/crypto.h])
  69
  70                 CURL_LIBS=`$CURL_CONFIG --libs`
  71
  72                 PHP_ADD_INCLUDE($CURL_DIR/include)
  73                 PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
  74                 PHP_EVAL_LIBLINE($CURL_LIBS, HTTP_SHARED_LIBADD)
  75                 AC_DEFINE([HTTP_HAVE_CURL], [1], [Have cURL support])
  76
  77                 PHP_CHECK_LIBRARY(curl, curl_multi_strerror,
  78                         [AC_DEFINE([HAVE_CURL_MULTI_STRERROR], [1], [ ])], [ ],
  79                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
  80                 )
  81                 PHP_CHECK_LIBRARY(curl, curl_easy_strerror,
  82                         [AC_DEFINE([HAVE_CURL_EASY_STRERROR], [1], [ ])], [ ],
  83                         [$CURL_LIBS -L$CURL_DIR/$PHP_LIBDIR]
  84                 )
  85         fi
  86
  87 dnl ----
  88 dnl MHASH
  89 dnl ----
  90         if test "$PHP_HTTP_MHASH_ETAGS" != "no"; then
  91
  92                 AC_MSG_CHECKING([for mhash.h])
  93                 MHASH_DIR=
  94                 for i in "$PHP_HTTP_MHASH_ETAGS" /usr/local /usr /opt; do
  95                         if test -f "$i/include/mhash.h"; then
  96                                 MHASH_DIR=$i
  97                                 break
  98                         fi
  99                 done
 100                 if test -z "$MHASH_DIR"; then
 101                         AC_MSG_RESULT([not found])
 102                         AC_MSG_ERROR([could not find mhash.h])
 103                 else
 104                         AC_MSG_RESULT([found in $MHASH_DIR])
 105                 fi
 106
 107                 PHP_ADD_INCLUDE($MHASH_DIR/include)
 108                 PHP_ADD_LIBRARY_WITH_PATH(mhash, $MHASH_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 109                 AC_DEFINE([HTTP_HAVE_MHASH], [1], [Have mhash support])
 110         fi
 111
 112 dnl ----
 113 dnl MAGIC
 114 dnl ----
 115         if test "$PHP_HTTP_MAGIC_MIME" != "no"; then
 116
 117                 AC_MSG_CHECKING([for magic.h])
 118                 MAGIC_DIR=
 119                 for i in "$PHP_HTTP_MAGIC_MIME" /usr/local /usr /opt; do
 120                         if test -f "$i/include/magic.h"; then
 121                                 MAGIC_DIR=$i
 122                                 break
 123                         fi
 124                 done
 125                 if test -z "$MAGIC_DIR"; then
 126                         AC_MSG_RESULT([not found])
 127                         AC_MSG_ERROR([could not find magic.h])
 128                 else
 129                         AC_MSG_RESULT([found in $MAGIC_DIR])
 130                 fi
 131
 132                 PHP_ADD_INCLUDE($MAGIC_DIR/include)
 133                 PHP_ADD_LIBRARY_WITH_PATH(magic, $MAGIC_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
 134                 AC_DEFINE([HTTP_HAVE_MAGIC], [1], [Have magic mime support])
 135         fi
 136
 137 dnl ----
 138 dnl DONE
 139 dnl ----
 140         PHP_HTTP_SOURCES="missing.c http.c http_functions.c phpstr/phpstr.c \
 141                 http_util_object.c http_message_object.c http_request_object.c http_request_pool_api.c \
 142                 http_response_object.c http_exception_object.c http_requestpool_object.c \
 143                 http_api.c http_cache_api.c http_request_api.c http_date_api.c \
 144                 http_headers_api.c http_message_api.c http_send_api.c http_url_api.c \
 145                 http_info_api.c http_request_method_api.c"
 146         PHP_NEW_EXTENSION([http], $PHP_HTTP_SOURCES, [$ext_shared])
 147         PHP_ADD_BUILD_DIR($ext_builddir/phpstr, 1)
 148         PHP_SUBST([HTTP_SHARED_LIBADD])
 149
 150         HTTP_HEADER_FILES="php_http_std_defs.h php_http.h php_http_api.h php_http_cache_api.h \
 151                 php_http_date_api.h php_http_headers_api.h php_http_info_api.h php_http_message_api.h \
 152                 php_http_request_api.h php_http_request_method_api.h php_http_send_api.h php_http_url_api.h"
 153         PHP_SUBST([HTTP_HEADER_FILES])
 154
 155         ifdef([PHP_INSTALL_HEADERS],
 156         [
 157                 PHP_INSTALL_HEADERS(ext/http, $HTTP_HEADER_FILES)
 158                 PHP_INSTALL_HEADERS(ext/http/phpstr, [phpstr/phpstr.h])
 159         ], [
 160                 PHP_ADD_MAKEFILE_FRAGMENT
 161         ])
 162
 163         AC_DEFINE([HAVE_HTTP], [1], [Have extended HTTP support])
 164 fi