git.m6w6.name Git - m6w6/ext-ares/blob - config.m4

   1 dnl $Id$
   2 dnl config.m4 for extension ares
   3
   4 PHP_ARG_WITH(ares, for asynchronous resolver support,
   5 [  --with-ares             Include asynchronous resolver support])
   6
   7 if test "$PHP_ARES" != "no"; then
   8         PHP_ARES_DIR=
   9         AC_MSG_CHECKING(for ares.h)
  10         for i in "$PHP_ARES" /usr/local /usr; do
  11                 if test -r "$i/include/ares.h"; then
  12                         PHP_ARES_DIR=$i
  13                         AC_MSG_RESULT(found in $i)
  14                         break;
  15                 fi
  16         done
  17         if test -z "$PHP_ARES_DIR"; then
  18                 AC_MSG_ERROR(could not find ares.h)
  19         fi
  20
  21         PHP_ADD_LIBRARY(rt, ARES_SHARED_LIBADD)
  22         PHP_ARES_LIB=
  23         PHP_CHECK_LIBRARY(cares, ares_init, [
  24                         PHP_ARES_LIB=cares
  25                 ], [
  26                         PHP_CHECK_LIBRARY(ares, ares_init, [
  27                                         PHP_ARES_LIB=ares
  28                                 ], [
  29                                         PHP_ARES_LIB=unknown
  30                                 ], [
  31                                         -L$PHP_ARES_DIR/$PHP_LIBDIR
  32                                 ]
  33                         )
  34                 ], [
  35                         -L$PHP_ARES_DIR/$PHP_LIBDIR
  36                 ]
  37         )
  38         AC_MSG_CHECKING(for libares/libcares)
  39         AC_MSG_RESULT($PHP_ARES_LIB)
  40
  41         if test $PHP_ARES_LIB = "unknown"; then
  42                 AC_MSG_ERROR(could neither find libares nor libcares)
  43         elif test $PHP_ARES_LIB = "cares"; then
  44                 AC_DEFINE_UNQUOTED([PHP_ARES_LIBNAME], "c-ares (CURL)", [ ])
  45                 AC_DEFINE([PHP_ARES_EXPAND_LEN_TYPE], [long], [ ])
  46         else
  47                 AC_DEFINE_UNQUOTED([PHP_ARES_LIBNAME], "ares (MIT)", [ ])
  48                 AC_DEFINE([PHP_ARES_EXPAND_LEN_TYPE], [int], [ ])
  49                 AC_DEFINE([HAVE_OLD_ARES_STRERROR], [1], [ ])
  50         fi
  51
  52         PHP_CHECK_LIBRARY($PHP_ARES_LIB, ares_cancel,
  53                 [AC_DEFINE([HAVE_ARES_CANCEL], [1], [ ])], [ ],
  54                 [-L$PHP_ARES_DIR/$PHP_LIBDIR]
  55         )
  56         PHP_CHECK_LIBRARY($PHP_ARES_LIB, ares_getnameinfo,
  57                 [AC_DEFINE([HAVE_ARES_GETNAMEINFO], [1], [ ])], [ ],
  58                 [-L$PHP_ARES_DIR/$PHP_LIBDIR]
  59         )
  60         PHP_CHECK_LIBRARY($PHP_ARES_LIB, ares_getsock,
  61                 [AC_DEFINE([HAVE_ARES_GETSOCK], [1], [ ])], [ ],
  62                 [-L$PHP_ARES_DIR/$PHP_LIBDIR]
  63         )
  64         PHP_CHECK_LIBRARY($PHP_ARES_LIB, ares_version,
  65                 [AC_DEFINE([HAVE_ARES_VERSION], [1], [ ])], [ ],
  66                 [-L$PHP_ARES_DIR/$PHP_LIBDIR]
  67         )
  68
  69
  70         dnl check new c-ares API
  71
  72         save_LIBS=$LIBS
  73         save_CFLAGS=$CFLAGS
  74         LIBS="-L $PHP_ARES_DIR/$PHP_LIBDIR -l $PHP_ARES_LIB"
  75         CFLAGS="-I$PHP_ARES_DIR/include -pedantic-errors"
  76
  77         AC_MSG_CHECKING(for new c-ares callback API)
  78         AC_TRY_COMPILE(
  79                 [#include <ares.h>
  80                 ], [
  81                         ares_search(0, 0, 0, 0, (void (*)(void *, int, int, unsigned char *, int)) 0, 0);
  82                 ], [
  83                         AC_MSG_RESULT(yes)
  84                         AC_DEFINE([PHP_ARES_NEW_CALLBACK_API], [1], [ ])
  85                 ], [
  86                         AC_MSG_RESULT(no)
  87                         AC_DEFINE([PHP_ARES_NEW_CALLBACK_API], [0], [ ])
  88                 ]
  89         )
  90
  91         LIBS=$save_LIBS
  92         CFLAGS=$save_CFLAGS
  93
  94         AC_CHECK_HEADERS([netdb.h unistd.h arpa/inet.h arpa/nameser.h])
  95
  96         PHP_ADD_INCLUDE($PHP_ARES_DIR/include)
  97         PHP_ADD_LIBRARY_WITH_PATH($PHP_ARES_LIB, $PHP_ARES_DIR/$PHP_LIBDIR, ARES_SHARED_LIBADD)
  98
  99         PHP_SUBST(ARES_SHARED_LIBADD)
 100         PHP_NEW_EXTENSION(ares, ares.c, $ext_shared)
 101 fi