+
+ AC_MSG_CHECKING([for curl-config])
+ CURL_CONFIG=
+ for i in "$CURL_DIR/bin/curl-config" "$CURL_DIR/curl-config" `which curl-config`; do
+ if test -x "$i"; then
+ CURL_CONFIG=$i
+ break
+ fi
+ done
+ if test "x$CURL_CONFIG" = "x"; then
+ AC_MSG_RESULT([not found])
+ AC_MSG_ERROR([could not find curl-config])
+ else
+ AC_MSG_RESULT([found: $CURL_CONFIG])
+ fi
+
+ dnl RHEL6: 7.19.7
+ dnl SUSE11: 7.19.7
+ dnl Debian wheezy: 7.26.0
+ dnl Debian sqeeze: 7.21.0
+ dnl Debian ancient 7.18.2
+ AC_MSG_CHECKING([for curl version >= 7.18.2])
+ CURL_VERSION=`$CURL_CONFIG --version | $SED -e 's/[[^0-9\.]]//g'`
+ AC_MSG_RESULT([$CURL_VERSION])
+ if test `echo $CURL_VERSION | $SED -e 's/[[^0-9]]/ /g' | $AWK '{print $1*10000 + $2*100 + $3}'` -lt 71802; then
+ AC_MSG_ERROR([libcurl version greater or equal to 7.18.2 required])
+ fi
+
+ AC_MSG_CHECKING([for HTTP2 support in libcurl])
+ if $CURL_CONFIG --features | $EGREP -q HTTP2; then
+ AC_MSG_RESULT([yes])
+ AC_DEFINE([PHP_HTTP_HAVE_HTTP2], [1], [ ])
+ else
+ AC_MSG_RESULT([no])
+ fi
+
+ dnl
+ dnl compile tests
+ dnl
+
+ save_INCLUDES="$INCLUDES"
+ INCLUDES=
+ save_LIBS="$LIBS"
+ LIBS=-lcurl
+ save_CFLAGS="$CFLAGS"
+ CFLAGS="$CFLAGS `$CURL_CONFIG --cflags`"
+ save_LDFLAGS="$LDFLAGS"
+ LDFLAGS="$ld_runpath_switch$CURL_DIR/$PHP_LIBDIR"
+
+ AC_MSG_CHECKING([for SSL support in libcurl])
+ CURL_SSL=`$CURL_CONFIG --feature | $EGREP SSL`
+ CURL_SSL_LIBS=""
+ if test "$CURL_SSL" = "SSL"; then
+ AC_MSG_RESULT([yes])
+ AC_DEFINE([PHP_HTTP_HAVE_SSL], [1], [ ])
+
+ HTTP_CURL_SSL_LIB_CHECK(OpenSSL, [
+ AC_CHECK_HEADER([openssl/ssl.h], [
+ AC_CHECK_HEADER([openssl/crypto.h], [
+ AC_DEFINE([PHP_HTTP_HAVE_OPENSSL], [1], [ ])
+ CURL_SSL_LIBS="ssl crypto"
+ ])
+ ])
+ ])
+ HTTP_CURL_SSL_LIB_CHECK(GnuTLS, [
+ AC_CHECK_HEADER([gnutls.h], [
+ AC_CHECK_HEADER([gcrypt.h], [
+ AC_DEFINE([PHP_HTTP_HAVE_GNUTLS], [1], [ ])
+ CURL_SSL_LIBS="gnutls gcrypt"
+ ])
+ ])
+ ])
+ HTTP_CURL_SSL_LIB_CHECK(NSS, [
+ AC_DEFINE([PHP_HTTP_HAVE_NSS], [1], [ ])
+ ])
+ HTTP_CURL_SSL_LIB_CHECK(SecureTransport, [
+ AC_DEFINE([PHP_HTTP_HAVE_DARWINSSL], [1], [ ])
+ ])
+ HTTP_CURL_SSL_LIB_CHECK(GSKit, [
+ AC_DEFINE([PHP_HTTP_HAVE_GSKIT], [1], [ ])
+ ])
+ else
+ dnl no CURL_SSL
+ AC_MSG_RESULT([no])
+ fi
+
+ AC_MSG_CHECKING([for ares support in libcurl])
+ AC_TRY_RUN([
+ #include <curl/curl.h>
+ int main(int argc, char *argv[]) {
+ curl_version_info_data *data = curl_version_info(CURLVERSION_NOW);
+ if (data && data->ares && data->ares_num0) {
+ return 0;
+ }
+ return 1;
+ }
+ ], [
+ AC_MSG_RESULT([yes])
+ AC_DEFINE([PHP_HTTP_HAVE_ARES], [1], [ ])
+ ], [
+ AC_MSG_RESULT([no])
+ ], [
+ AC_MSG_RESULT([no])
+ ])
+
+ AC_MSG_CHECKING([whether CURLOPT_TLSAUTH_TYPE expects CURL_TLSAUTH_SRP or literal "SRP"])
+ AC_TRY_RUN([
+ #include <curl/curl.h>
+ int main(int argc, char *argv[]) {
+ CURL *ch = curl_easy_init();
+ return curl_easy_setopt(ch, CURLOPT_TLSAUTH_TYPE, CURL_TLSAUTH_SRP);
+ }
+ ], [
+ AC_MSG_RESULT([CURL_TLSAUTH_SRP])
+ AC_DEFINE([PHP_HTTP_CURL_TLSAUTH_SRP], [CURL_TLSAUTH_SRP], [ ])
+ AC_DEFINE([PHP_HTTP_CURL_TLSAUTH_DEF], [CURL_TLSAUTH_NONE], [ ])
+ ], [
+ AC_TRY_RUN([
+ #include <curl/curl.h>
+ int main(int argc, char *argv[]) {
+ CURL *ch = curl_easy_init();
+ return curl_easy_setopt(ch, CURLOPT_TLSAUTH_TYPE, "SRP");
+ }
+ ], [
+ AC_MSG_RESULT(["SRP"])
+ AC_DEFINE([PHP_HTTP_CURL_TLSAUTH_SRP], ["SRP"], [ ])
+ AC_DEFINE([PHP_HTTP_CURL_TLSAUTH_DEF], [""], [ ])
+ ], [
+ AC_MSG_RESULT([neither])
+ ], [
+ AC_MSG_RESULT([neither])
+ ])
+ ], [
+ AC_MSG_RESULT([neither])
+ ])
+
+ INCLUDES="$save_INCLUDES"
+ LIBS="$save_LIBS"
+ CFLAGS="$save_CFLAGS"
+ LDFLAGS="$save_LDFLAGS"
+
+ if test -n "$CURL_SSL_LIBS"; then
+ for CURL_SSL_LIB in $CURL_SSL_LIBS; do
+ PHP_ADD_LIBRARY_WITH_PATH([$CURL_SSL_LIB], $CURL_DIR/$PHP_LIBDIR, PHP_HTTP_SHARED_LIBADD)
+ done
+ fi
+
+ dnl end compile tests
+
+ AC_MSG_CHECKING([for default SSL CA info/path])
+ CURL_CA_PATH=
+ CURL_CA_INFO=
+ CURL_CONFIG_CA=$($CURL_CONFIG --ca)
+ if test -z "$CURL_CONFIG_CA"; then
+ CURL_CONFIG_CA=$($CURL_CONFIG --configure | $EGREP -o -- "--with-ca@<:@^'@:>@*" | $SED 's/.*=//')
+ fi
+ for i in \
+ "$CURL_CONFIG_CA" \
+ /etc/ssl/certs \
+ /etc/ssl/certs/ca-bundle.crt \
+ /etc/ssl/certs/ca-certificates.crt \
+ /etc/pki/tls/certs/ca-bundle.crt \
+ /etc/pki/tls/certs/ca-bundle.trust.crt \
+ /etc/pki/ca-trust/extracted/pem/tls-ca-bundle.pem \
+ /System/Library/OpenSSL
+ do
+ if test -z "$CURL_CA_PATH" && test -d "$i"; then
+ # check if it's actually a hashed directory
+ if ls "$i"/@<:@0-9a-f@:>@@<:@0-9a-f@:>@@<:@0-9a-f@:>@@<:@0-9a-f@:>@@<:@0-9a-f@:>@@<:@0-9a-f@:>@@<:@0-9a-f@:>@@<:@0-9a-f@:>@.0 >/dev/null 2>&1; then
+ CURL_CA_PATH="$i"
+ fi
+ elif test -z "$CURL_CA_INFO" && test -f "$i"; then
+ CURL_CA_INFO="$i"
+ fi
+ done
+ if test -n "$CURL_CA_PATH" && test -n "$CURL_CA_INFO"; then
+ AC_MSG_RESULT([path:$CURL_CA_PATH, info:$CURL_CA_INFO])
+ AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAPATH], ["$CURL_CA_PATH"], [path to default SSL CA path])
+ AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAINFO], ["$CURL_CA_INFO"], [path to default SSL CA info])
+ elif test -n "$CURL_CA_INFO"; then
+ AC_MSG_RESULT([info:$CURL_CA_INFO])
+ AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAINFO], ["$CURL_CA_INFO"], [path to default SSL CA info])
+ elif test -n "$CURL_CA_PATH"; then
+ AC_MSG_RESULT([path:$CURL_CA_PATH])
+ AC_DEFINE_UNQUOTED([PHP_HTTP_CURL_CAPATH], ["$CURL_CA_PATH"], [path to default SSL CA path])
+ else
+ AC_MSG_RESULT([none])
+ fi
+
+ PHP_ADD_INCLUDE($CURL_DIR/include)
+ PHP_ADD_LIBRARY_WITH_PATH(curl, $CURL_DIR/$PHP_LIBDIR, HTTP_SHARED_LIBADD)
+ PHP_EVAL_LIBLINE(`$CURL_CONFIG --libs`, HTTP_SHARED_LIBADD)
+ AC_DEFINE([PHP_HTTP_HAVE_CURL], [1], [Have libcurl support])
+ HTTP_HAVE_A_REQUEST_LIB=true