git.m6w6.name Git - awesomized/libmemcached/blob - libmemcached/options/scanner.l

   1 /*  vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
   2  *
   3  *  Libmemcached Scanner and Parser
   4  *
   5  *  Copyright (C) 2011 DataDifferental, http://datadifferential.com
   6  *
   7  *  This program is free software: you can redistribute it and/or modify
   8  *  it under the terms of the GNU Affero General Public License as
   9  *  published by the Free Software Foundation, either version 3 of the
  10  *  License, or (at your option) any later version.
  11  *
  12  *  This program is distributed in the hope that it will be useful,
  13  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  *  GNU Affero General Public License for more details.
  16  *
  17  *  You should have received a copy of the GNU Affero General Public License
  18  *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 %top{
  22
  23 #pragma GCC diagnostic ignored "-Wold-style-cast"
  24 #pragma GCC diagnostic ignored "-Wunused-parameter"
  25 #pragma GCC diagnostic ignored "-fpermissive"
  26
  27 #include <libmemcached/options/context.h>
  28 #include <libmemcached/options/parser.h>
  29 #include <libmemcached/options/string.h>
  30 #include <libmemcached/options/symbol.h>
  31
  32 #define YY_EXTRA_TYPE Context*
  33 #define YY_USER_ACTION yylloc->first_line = yylineno;
  34
  35 }
  36
  37
  38 %{
  39 #include <cstdlib>
  40 #include <cstring>
  41
  42 #define PARAM yyget_extra(yyscanner)
  43
  44 static void get_lex_chars(char* buffer, int& result, int max_size, Context *context)
  45 {
  46   if (context->pos >= context->length)
  47   {
  48     result= YY_NULL;
  49   }
  50   else
  51   {
  52     result= context->length - context->pos;
  53     result > (int)max_size ? result = max_size : 0;
  54     memcpy(buffer, context->buf + context->pos, result);
  55     context->pos += result;
  56   }
  57 }
  58
  59
  60 #define YY_INPUT(buffer, result, max_size) get_lex_chars(buffer, result, max_size, PARAM)
  61
  62 %}
  63
  64 %option bison-bridge
  65 %option bison-locations
  66 %option case-insensitive
  67 %option debug
  68 %option nounput
  69 %option noyywrap
  70 %option yylineno
  71 %option outfile="libmemcached/options/scanner.cc" header-file="libmemcached/options/scanner.h"
  72 %option perf-report
  73 %option prefix="libmemcached_"
  74 %option reentrant
  75
  76 %%
  77
  78
  79 =|,|[ ]       { return yytext[0];}
  80
  81
  82 [[:digit:]]+ { yylval->number = atoi(yytext); return (NUMBER); }
  83
  84 [\t\r\n] ; /* skip whitespace */
  85
  86 ^#.*$ {
  87       return COMMENT;
  88     }
  89
  90 "--SERVER"                          { yyextra->begin= yytext; return SERVER; }
  91 "--SERVERS"                        { yyextra->begin= yytext; return SERVERS_OPTION; }
  92
  93 "--VERIFY_KEY"                      { yyextra->begin= yytext; return VERIFY_KEY; }
  94 "--VERIFY-KEY"                      { yyextra->begin= yytext; return VERIFY_KEY; }
  95 "--AUTO_EJECT_HOSTS"            { yyextra->begin= yytext; return AUTO_EJECT_HOSTS; }
  96 "--AUTO-EJECT_HOSTS"            { yyextra->begin= yytext; return AUTO_EJECT_HOSTS; }
  97 "--BINARY_PROTOCOL"                     { yyextra->begin= yytext; return BINARY_PROTOCOL; }
  98 "--BINARY-PROTOCOL"                     { yyextra->begin= yytext; return BINARY_PROTOCOL; }
  99 "--BUFFER_REQUESTS"                     { yyextra->begin= yytext; return BUFFER_REQUESTS; }
 100 "--BUFFER-REQUESTS"                     { yyextra->begin= yytext; return BUFFER_REQUESTS; }
 101 "--CACHE_LOOKUPS"                       { yyextra->begin= yytext; return CACHE_LOOKUPS; }
 102 "--CACHE-LOOKUPS"                       { yyextra->begin= yytext; return CACHE_LOOKUPS; }
 103 "--CONFIGURE_FILE"                      { yyextra->begin= yytext; return CONFIGURE_FILE; }
 104 "--CONFIGURE-FILE"                      { yyextra->begin= yytext; return CONFIGURE_FILE; }
 105 "--CONNECT_TIMEOUT"                     { yyextra->begin= yytext; return CONNECT_TIMEOUT; }
 106 "--CONNECT-TIMEOUT"                     { yyextra->begin= yytext; return CONNECT_TIMEOUT; }
 107 "--CORK"                                { yyextra->begin= yytext; return _CORK; }
 108 "--DISTRIBUTION"                        { yyextra->begin= yytext; return DISTRIBUTION; }
 109 "--HASH"                                { yyextra->begin= yytext; return HASH; }
 110 "--HASH_WITH_PREFIX_KEY"                { yyextra->begin= yytext; return HASH_WITH_PREFIX_KEY; }
 111 "--HASH-WITH-PREFIX_KEY"                { yyextra->begin= yytext; return HASH_WITH_PREFIX_KEY; }
 112 "--IO_BYTES_WATERMARK"          { yyextra->begin= yytext; return IO_BYTES_WATERMARK; }
 113 "--IO-BYTES-WATERMARK"          { yyextra->begin= yytext; return IO_BYTES_WATERMARK; }
 114 "--IO_KEY_PREFETCH"                     { yyextra->begin= yytext; return IO_KEY_PREFETCH; }
 115 "--IO-KEY-PREFETCH"                     { yyextra->begin= yytext; return IO_KEY_PREFETCH; }
 116 "--IO_MSG_WATERMARK"            { yyextra->begin= yytext; return IO_MSG_WATERMARK; }
 117 "--IO-MSG-WATERMARK"            { yyextra->begin= yytext; return IO_MSG_WATERMARK; }
 118 "--KETAMA"                              { yyextra->begin= yytext; return KETAMA; }
 119 "--KETAMA_HASH"                 { yyextra->begin= yytext; return KETAMA_HASH; }
 120 "--KETAMA-HASH"                 { yyextra->begin= yytext; return KETAMA_HASH; }
 121 "--KETAMA_WEIGHTED"                     { yyextra->begin= yytext; return KETAMA_WEIGHTED; }
 122 "--KETAMA-WEIGHTED"                     { yyextra->begin= yytext; return KETAMA_WEIGHTED; }
 123 "--NOREPLY"                         { yyextra->begin= yytext; return NOREPLY; }
 124 "--NUMBER_OF_REPLICAS"          { yyextra->begin= yytext; return NUMBER_OF_REPLICAS; }
 125 "--NUMBER-OF-REPLICAS"          { yyextra->begin= yytext; return NUMBER_OF_REPLICAS; }
 126 "--POLL_TIMEOUT"                        { yyextra->begin= yytext; return POLL_TIMEOUT; }
 127 "--POLL-TIMEOUT"                        { yyextra->begin= yytext; return POLL_TIMEOUT; }
 128 "--RANDOMIZE_REPLICA_READ"              { yyextra->begin= yytext; return RANDOMIZE_REPLICA_READ; }
 129 "--RANDOMIZE-REPLICA-READ"              { yyextra->begin= yytext; return RANDOMIZE_REPLICA_READ; }
 130 "--RCV_TIMEOUT"                 { yyextra->begin= yytext; return RCV_TIMEOUT; }
 131 "--RCV-TIMEOUT"                 { yyextra->begin= yytext; return RCV_TIMEOUT; }
 132 "--RETRY_TIMEOUT"                       { yyextra->begin= yytext; return RETRY_TIMEOUT; }
 133 "--RETRY-TIMEOUT"                       { yyextra->begin= yytext; return RETRY_TIMEOUT; }
 134 "--SERVER_FAILURE_LIMIT"                { yyextra->begin= yytext; return SERVER_FAILURE_LIMIT; }
 135 "--SERVER-FAILURE-LIMIT"                { yyextra->begin= yytext; return SERVER_FAILURE_LIMIT; }
 136 "--SND_TIMEOUT"                 { yyextra->begin= yytext; return SND_TIMEOUT; }
 137 "--SND-TIMEOUT"                 { yyextra->begin= yytext; return SND_TIMEOUT; }
 138 "--SOCKET_RECV_SIZE"            { yyextra->begin= yytext; return SOCKET_RECV_SIZE; }
 139 "--SOCKET-RECV-SIZE"            { yyextra->begin= yytext; return SOCKET_RECV_SIZE; }
 140 "--SOCKET_SEND_SIZE"            { yyextra->begin= yytext; return SOCKET_SEND_SIZE; }
 141 "--SOCKET-SEND-SIZE"            { yyextra->begin= yytext; return SOCKET_SEND_SIZE; }
 142 "--SORT_HOSTS"                  { yyextra->begin= yytext; return SORT_HOSTS; }
 143 "--SORT-HOSTS"                  { yyextra->begin= yytext; return SORT_HOSTS; }
 144 "--SUPPORT_CAS"                 { yyextra->begin= yytext; return SUPPORT_CAS; }
 145 "--SUPPORT-CAS"                 { yyextra->begin= yytext; return SUPPORT_CAS; }
 146 "--TCP_NODELAY"                 { yyextra->begin= yytext; return _TCP_NODELAY; }
 147 "--TCP-NODELAY"                 { yyextra->begin= yytext; return _TCP_NODELAY; }
 148 "--TCP_KEEPALIVE"                       { yyextra->begin= yytext; return _TCP_KEEPALIVE; }
 149 "--TCP-KEEPALIVE"                       { yyextra->begin= yytext; return _TCP_KEEPALIVE; }
 150 "--TCP_KEEPIDLE"                        { yyextra->begin= yytext; return _TCP_KEEPIDLE; }
 151 "--TCP-KEEPIDLE"                        { yyextra->begin= yytext; return _TCP_KEEPIDLE; }
 152 "--USER_DATA"                   { yyextra->begin= yytext; return USER_DATA; }
 153 "--USER-DATA"                   { yyextra->begin= yytext; return USER_DATA; }
 154 "--USE_UDP"                             { yyextra->begin= yytext; return USE_UDP; }
 155 "--USE-UDP"                             { yyextra->begin= yytext; return USE_UDP; }
 156
 157 "--PREFIX-KEY"                          { yyextra->begin= yytext; return PREFIX_KEY; }
 158 "--PREFIX_KEY"                          { yyextra->begin= yytext; return PREFIX_KEY; }
 159
 160 INCLUDE           { yyextra->begin= yytext; return INCLUDE; }
 161 RESET           { yyextra->begin= yytext; return RESET; }
 162 DEBUG           { yyextra->begin= yytext; return PARSER_DEBUG; }
 163 SERVERS           { yyextra->begin= yytext; return SERVERS; }
 164 END           { yyextra->begin= yytext; return END; }
 165 ERROR           { yyextra->begin= yytext; return ERROR; }
 166
 167 TRUE           { return TRUE; }
 168 FALSE           { return FALSE; }
 169
 170
 171 "--"[[:alnum:]]*   {
 172       yyextra->begin= yytext;
 173       return UNKNOWN_OPTION;
 174     }
 175
 176 CONSISTENT      { return CONSISTENT; }
 177 MODULA          { return MODULA; }
 178 RANDOM          { return RANDOM; }
 179
 180 MD5                     { return MD5; }
 181 CRC                     { return CRC; }
 182 FNV1_64                 { return FNV1_64; }
 183 FNV1A_64                        { return FNV1A_64; }
 184 FNV1_32                 { return FNV1_32; }
 185 FNV1A_32                        { return FNV1A_32; }
 186 HSIEH                   { return HSIEH; }
 187 MURMUR                  { return MURMUR; }
 188 JENKINS                 { return JENKINS; }
 189
 190 [[:alnum:]][[:alnum:].]*[[:alpha:]]: {
 191       yylval->string.c_str = yytext;
 192       yylval->string.length = yyleng;
 193       return HOSTNAME_WITH_PORT;
 194     }
 195
 196 [[:alnum:]]+"."[[:alpha:].]+[[:alnum:]] {
 197       yylval->string.c_str = yytext;
 198       yylval->string.length = yyleng;
 199       return HOSTNAME;
 200     }
 201
 202 (([[:digit:]]{1,3}"."){3}([[:digit:]]{1,3})): {
 203       yylval->string.c_str = yytext;
 204       yylval->string.length = yyleng;
 205       return IPADDRESS_WITH_PORT;
 206     }
 207
 208 (([[:digit:]]{1,3}"."){3}([[:digit:]]{1,3})) {
 209       yylval->string.c_str = yytext;
 210       yylval->string.length = yyleng;
 211       return IPADDRESS;
 212     }
 213
 214 [[:alnum:]]+ {
 215       yylval->string.c_str = yytext;
 216       yylval->string.length = yyleng;
 217       return STRING;
 218     }
 219
 220 (\".*\") {
 221       yylval->string.c_str = yytext;
 222       yylval->string.length = yyleng;
 223       return QUOTED_STRING;
 224     }
 225
 226 .   {
 227       yyextra->begin= yytext;
 228       return UNKNOWN;
 229     }
 230
 231 %%
 232
 233 void Context::init_scanner()
 234 {
 235   yylex_init(&scanner);
 236   yyset_extra(this, scanner);
 237 }
 238
 239 void Context::destroy_scanner()
 240 {
 241   yylex_destroy(scanner);
 242 }
 243